
SCENE 270,staroom2, SCENE, "Druid's Monument"
	ACTOR	1,	"The Healer", joshAnimals, 8, 25, 90
	SEL		1
	MOVE	1,	15, 80
	
	IF -V50, @end
	IF T271+C10, @heal
	IF T270+C10, @return
	IF C10, @druid


@heal
	IF ALIVE, @skip1
	' Wait one moment, you shall live again.
	WAIT    1.0
	SOUND	"thunder1.wav"
	WAIT	1.0
@skip1
	MOVE	1,	10, 75
	GIVE	L1
	GIVE	H3000
	GIVE	M3000 
	OFFER	1,2,4,5,6,7,8,13,15,16,17
	' Greetings, hero.
	' Stay awhile and relax. 
	' All your healing needs will be taken care of. 	
	
@end
END


@druid
	1: Welcome young Druid.
	1: I have a quest for you!
	1: At this very moment the stars are in the correct alignment to generate maximum power from our monuments.
	1: Go visit the monuments and return here before the stars stray out of alignment!
	1: Quickly now! You only have four minutes to visit the four Glades and return here!
	GIVE T270
	COUNTDOWN 240
	END

@return
	1: Welcome back young Druid.
	IF -XP+T272+T273+T274+T275, @complete
	COUNTDOWN 0
	TAKE T270
	1: I see you have not completed my quest.
	1: You'll have to wait until the stars align correctly to try again.
	END
@complete
	COUNTDOWN 0
		1: Congratulations, young one! You succeeded!
	HOST_GIVE I175
	1: Take this staff charged with the power of the heavens! You'll find it most useful.
	GIVE T271
	END

SCENE 271,cedars, SCENE, ""

	IF DEAD, @go
	IF -V15, @go
	IF T279, @go

	ACTOR	1,	"Bandit Leader", Pic055a, 1, 25, 90
	
	1: Well, another traveller, eh?
	1: Unfortunately for you, the Forest of Palteas now has a toll.
	1: The fee will be 100 GP.
	N: Will you pay the toll?
	ASK 9999999
	IF YES, @pay
	1: What do you mean, you won't pay?? I didn't say you had a choice!!
	1: Get #<g.him>, boys!!!
	FIGHT 339,341
	IF LOSE, @lost
	FIGHT 339, 340, 342
	IF LOSE, @lost
	1: Er... Um... Heh heh...
	1: Whoa! Quick, look behind you!!
	WAIT 1
	MOVE 1, -20, -20, 1
	N: The bandit retreats and drops 500 GP, which you grab.
	GIVE G500
	GIVE T279
	WAIT 3
	GOTO @go
	END
@lost
	1: Hah!! Next time I tell you something, you'd better listen!
	N: He steals the 100 GP from your dead form.
	MOVE 	1, -20, -20
	TAKE G100
	END
@go
	GOTO LINK 3, 0
	END


@pay
	TAKE G100
	1: Very good. You may pass.
	GOTO @go
	END

; end comment

