SCENE 16, trees, SCENE, "Great Forest- Crossroads", 0, 0, 0
	IF T30, @exit
	ACTOR 1, "Bandit", "josh56", 1, -20, 95
	ACTOR 2, "Bandit", "josh57", 1, -20, 90
	ACTOR 3, "Bandit", "josh58", 1, -20, 85
	WAIT 3
		N: You feel like you're being watched.
		H: I've got a bad feeling about this...
	WAIT 5
	MOVE H, 50, 90
	WAIT 3
		N: As you continue down the road, three bandits jump out of the underbrush.
	WAIT 2
	MOVE 1, 20, 95
	MOVE 2, 25, 90
	MOVE 3, 20, 85
		2: Stand and deliver! 500 GP to go through.
		1: Yeah, kid, give us your money or we'll gut you like a fish!
		3: And don't you even think about telling the guards! We've got eyes all over Oakhurst.
	WAIT 4
		N: How would you like to proceed?
	IF C6, @roguemenu
	MENU "(WIS/STR)(INTRIGUE) Try to intimidate them into leaving.=@intimidate", "(AGI)(ATHLETICISM) Try to outrun them.=@outrun", "(FIGHT) Prepare for a brawl.=@startfight", "Pay the toll.=@pay"
	GOTO @pay
@roguemenu
	MENU "(ROGUE)(WIS)(INTRIGUE) Talk to them like you're one of them.=@roguepersuade", "(WIS/STR)(INTRIGUE) Try to intimidate them into leaving.=@intimidate", "(AGI)(ATHLETICISM) Try to outrun them.=@outrun", "(FIGHT) Prepare for a brawl.=@startfight", "Pay the toll.=@pay"
	GOTO @pay
@roguepersuade
		N: You attempt to recall what this bandit gang's code phrase is.
	WAIT 2
		H: Let's not be so hasty, boys!
	CALL 9990@skillcheck, intrigue, #<num.hostWIS>, 1, 12
	COMPARE #<finalResult>, "2"
	IF= @roguecritsucceeded
	COMPARE #<finalResult>, "1"
	IF= @roguesucceeded
	COMPARE #<finalResult>, "0"
	IF= @roguefailed
	END
@roguecritsucceeded
	HOST_GIVE T30
		N: (SUCCESS) You recall that the gang controlling this territory goes by Fenrir's Wolves. 
		H: After all, the werewolf doesn't bite his own pack.
		2: Ah, sorry. Didn't realize you were one of us. Any good takes lately?
		H: Nah, the place is lousy with Eilika's men. Every merchant caravan that's come through has had at least a couple of them.
		2: You can say that again. Alright, boys, back to the hideout.
	MOVE 1, -20, 95
	MOVE 2, -25, 90
	MOVE 3, -20, 85
	WAIT 5
	GOTO LINK
	END
@roguesucceeded
	HOST_GIVE T30
		N: (SUCCESS) You recall that the gang controlling this territory uses werewolf-related terms. 
		H: After all, the werewolf doesn't bite his own pack.
		2: Ah, sorry. Didn't realize you were one of us. Any good takes lately?
		H: Nah, the place is lousy with Eilika's men. Every merchant caravan that's come through has had at least a couple of them.
		2: You can say that again. Alright, boys, back to the hideout.
	MOVE 1, -20, 95
	MOVE 2, -25, 90
	MOVE 3, -20, 85
	WAIT 5
	GOTO LINK
	END
@roguefailed
		N: (FAILED) You don't remember the code phrase correctly.
		H: After all, the vampire doesn't bite its own spawn.
		2: Wait a minute, this chump isn't one of ours! Get #<g.him>!
	MOVE 1, -20, 95, 1
	MOVE 2, -25, 90, 1
	MOVE 3, -20, 85, 1
	GOTO @fight
	END
@intimidate
	COMPARE #<num.hostWIS>, #<num.hostSTR>
	IF> @wishigher
	IF= @wishigher
	IF< @strhigher
@wishigher
CALL @classdialogue
CALL 9990@skillcheck, intrigue, #<num.hostWIS>, 0, 12
COMPARE #<finalResult>, "2"
IF= @intimcritsucceeded
COMPARE #<finalResult>, "1"
IF= @intimsucceeded
COMPARE #<finalResult>, "0"
IF= @intimfailed
END
@strhigher
CALL @classdialogue
CALL 9990@skillcheck, intrigue, #<num.hostSTR>, 0, 12
COMPARE #<finalResult>, "2"
IF= @intimcritsucceeded
COMPARE #<finalResult>, "1"
IF= @intimsucceeded
COMPARE #<finalResult>, "0"
IF= @intimfailed
END
@intimcritsucceeded
	HOST_GIVE T30
		N: (SUCCESS) The bandits recoil in fear at your words.
		2: To the hells with this, it's not worth it. Fall back!
	MOVE 1, -20, 95
	MOVE 2, -25, 90
	MOVE 3, -20, 85
	WAIT 5
		N: It seems the way is clear.
	WAIT 5
	GOTO LINK
END
@intimsucceeded
	HOST_GIVE T30
		N: (SUCCESS) The bandits recoil in fear at your words.
		2: To the hells with this, it's not worth it. Fall back!
	MOVE 1, -20, 95
	MOVE 2, -25, 90
	MOVE 3, -20, 85
	WAIT 5
		N: It seems the way is clear.
	WAIT 5
	GOTO LINK
END
@intimfailed
		N: (FAILED) The bandits seem unimpressed.
	GOTO @startfight
END
@outrun
		N: You wait for an opening and then make a run for it through the forest.
	CALL 9990@skillcheck, athleticism, #<num.hostWIS>, 0, 10
	COMPARE #<finalResult>, "2"
	IF= @outruncritsucceeded
	COMPARE #<finalResult>, "1"
	IF= @outrunsucceeded
	COMPARE #<finalResult>, "0"
	IF= @outrunfailed
END
@outruncritsucceeded
	HOST_GIVE T30
	MOVE 1, -20, 95, 1
	MOVE 2, -25, 90, 1
	MOVE 3, -20, 85, 1
		N: (SUCCESS) You slip past the bandits and manage to lose them in the forest.
	WAIT 5
	GOTO LINK 10, 0
END
@outrunsucceeded
	HOST_GIVE T30
	MOVE 1, -20, 95, 1
	MOVE 2, -25, 90, 1
	MOVE 3, -20, 85, 1
		N: (SUCCESS) You slip past the bandits and manage to lose them in the forest.
	WAIT 5
	GOTO LINK 10, 0
END
@outrunfailed
	MOVE H, 20, 90, 3
		N: As you run past, one of the bandits trips you with his leg, sending you tumbling to the ground.
		2: Thought you could slip away, did you? Get #<g.him>, boys!
	MOVE 1, -20, 95, 1
	MOVE 2, -25, 90, 1
	MOVE 3, -20, 85, 1
	GOTO @fight
END
@startfight
		2: Looks like this one wants to do this the hard way! Get #<g.him>!
	MOVE 1, -20, 95, 1
	MOVE 2, -25, 90, 1
	MOVE 3, -20, 85, 1
	GOTO @fight
@fight
	MUSIC "MQIntermediateBoss.mid"
	FIGHT2 11, 12, 13
	IF ALIVE, @won
	MOVE 1, 20, 95, 1
	MOVE 2, 25, 90, 1
	MOVE 3, 20, 85, 1
		2: Better luck next time, whelp. I'll be taking this now.
	HOST_TAKE G500
	CALL 9990@deathwarp
	END
@pay
	HOST_GIVE T30
	HOST_TAKE G500
		2: Smart of you, whelp. Now be on your way before I change my mind about killing you.
	WAIT 5
	GOTO LINK 10, 0
@won
	HOST_GIVE T30
		N: The bandits turn tail and run off towards the northeast. 
		N: It seems the way is clear.
	WAIT 5
	GOTO LINK 10, 0
	END
@exit
	GOTO LINK 10, 0
	END
@classdialogue
	IF C1, @fighter
	IF C2, @wizard
	IF C3, @ranger
	IF C4, @bard
	IF C5, @monk
	IF C6, @rogue
	IF C7, @druid
	IF C8, @cleric
@fighter
		H: If you don't want to end up with your insides outside, you'll leave. Now.
	RETURN
@wizard
		H: Bold words for someone within Fireball range.
	RETURN
@ranger
		H: Come wide at me and you'll go back to your boss with more holes than an old blanket.
	RETURN
@bard
		H: Don't be stupid. I won't hesitate to rupture your eardrums.
	RETURN
@rogue
		H: You'll regret this. I know all the places to hit to make this hurt as much as possible.
	RETURN
@druid
		H: Do you hear the Wild Hunt's horn? Leave now, lest you be its next quarry.
	RETURN
@cleric
		H: Leave now, villains, or suffer the wrath of the gods!
	RETURN
;----------------------------------------------------------------------------------------------------------------------------
SCENE 17, oakhurstEntrance, SCENE, "Entrance to Oakhurst", 0, 0, 0
	IF T2125, @oakhurst
	HOST_GIVE T2125
		N: Before you lays the logging village of Oakhurst.
	WAIT 3
		N: Perhaps here you can meet up with the Queen's army.
	WAIT 3
	GOTO @oakhurst
END
@oakhurst
	GOTO LINK 17, 0
END
;-----------------------------------------------------------------------------------------------------------------------------
SCENE 18, forestShoreTower, SCENE, "Forest Fishing Hole", 0, 0, 0
	ACTOR 1, "Ripples", "fishingspot", 1, 25, 50
END
@eventActorAttack1
	CALL 9990@cast, 07, 1
END
;-----------------------------------------------------------------------------------------------------------------------------
SCENE 19, oakhurstSquare, SCENE, "Oakhurst Town Square", 0, 0, 0
	ACTOR 1, "Town Crier", joshTownsfolk, 13, 20, 95
	SEL 1
	POSE 13, 15, 13
	IF T31, @trophy
	ACTOR 2, "Garg", josh98, 1, -20, 95, 5
	SEL 2
	POSE 1, 4, 1
	IF T31, @news
		1: Hear ye, hear ye! Blackscabbard villagers rejoice at the death of the Sahuagin Baron!
		H: Hey there, I'm looking for the Queen's Army forest outpost.
		1: Aye, it's in this town, but you picked a bad time to show up.
		H: How come?
		1: Garg's visiting today to collect tribute. He expects everyone to give him something, and he kills anyone who refuses.
		H: And the army doesn't do anything to stop him?
		1: They've got their hands too full keeping Dagon's army at bay to deal with one troll.
		H: Alright, I'll see what I can do to stop him. I killed the Baron, after all.
		1: Well, it's your funeral.
	WAIT 3
		N: You hear a heavy stomping coming towards the town square.
	WAIT 3
		1: Oh gods, he's here! Run for your lives!
	MOVE 1, 120, 95
	WAIT 5
		2: GARG HUNGRY! GIVE GARG FOOD!
	MOVE 2, 20, 95
	WAIT 2
		N: A hulking troll approaches you. 
		N: The smell of old sweat and rotting meat assaults your nostrils.
	WAIT 2
	CALL @classdialogue
		2: THEN GARG EAT TINY HUMAN!
	MUSIC "MQIntermediateBoss.mid"
	MOVE 1, -20, 95, 1
	FIGHT2 22
	IF ALIVE, @gargdead
	CALL 9990@deathwarp
END
@gargdead
	HOST_GIVE T31
	HOST_GIVE Z19
		N: With a mighty crash, Garg falls at your feet.
		N: You take his Troll Ear as a trophy.
	WAIT 2
		H: Good riddance. 
		H: Now, to the outpost.
END
@trophy
	IF T4001|Z19, @trophyskip
		N: You pick up the Troll Ear you left behind earlier.
	GIVE Z19
END
@trophyskip
	CALL 9989@picknews
END	
@classdialogue
	IF C1, @fighter
	IF C2, @wizard
	IF C3, @ranger
	IF C4, @bard
	IF C5, @monk
	IF C6, @rogue
	IF C7, @druid
	IF C8, @cleric
	RETURN
@fighter
		H: Time to die, troll! Your pillaging ends today!
	RETURN
@wizard
		H: I'd try to warn you about what you're getting into, but I doubt you'd have the brains to understand it.
	RETURN
@ranger
		H: Oh, you'll be stuffed by the end of this, but not with food, I'm afraid.
	RETURN
@bard
		H: Ah, how unsightly. Not to worry, I'll spare you the misery of your own existence in short order.
	RETURN
@monk
		H: Finally, a strong opponent. Try not to die too quickly, alright?
	RETURN
@rogue
		H: You kind of remind me of some of the guys I used to run into in prison. You'll be just as dead as them soon, too.
	RETURN
@druid
		H: A troll's hunger knows no end, and will surely threaten the forest if not dealt with.
	RETURN
@cleric
		H: I will strike you down, vile troll!
	RETURN
;----------------------------------------------------------------------------------------------------------------------------
SCENE 20, interiorSmithy, SCENE, "Oakhurst Smithy", 4, 0, 0
	THEME 6
	MUSIC "blacksmith.mid"
	ACTOR 1, "Bjorn", josh96, 1, 20, 95
	SEL 1
	POSE 1, 4, 4
	IF T34, @paid1
		1: Greetin's! You 'ere fer some upgrades?
		H: Wouldn't be coming to a blacksmith shop for much else.
		1: Fer a set a tier 2 equipment, the grand total comes out to 7000 GP. Interested?
	MENU "Yes.=@yes", "No.=@no"
END
@yes
	IF J1+J2+J3+J4+J5+J6+T4000, @tier2
		1: Doesn't look like ye 'ave a full set a the tier 1 equipment yet. Go upgrade yer stuff and come back.
END
@tier2
	IF G7000, @pay1
		1: Doesn't look like ye 'ave enough money. My shop ain't a charity.
END
@pay1
	HOST_GIVE T34
	HOST_TAKE G7000
		1: Pleasure doin' business. 'ere's wha' I need.
	MISSIONS 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28
END
@no
		1: Well, if ye change yer mind, ye know where to find me.
END
@paid1
		1: Get yer weapon and armor upgrades 'ere!
	MISSIONS 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28
END
;-----------------------------------------------------------------------------------------------------------------------------
SCENE 21, interiorHouse, SCENE, "Royal Army Outpost", 0, 0, 0
	MUSIC "RoyalMessenger.mid"
	ACTOR 1, "Royal Messenger", "joshRoyalty", 4, 20, 90
	ACTOR 2, "Bodyguard", "josh55", 1, 30, 85
	ACTOR 3, "Bodyguard", "josh55", 1, 10, 95
	IF T32, @told
	WAIT 3
		N: As you enter the outpost, you see the royal messenger and his bodyguards.
		1: Ah, %1, good to see you here.
		1: As you may have seen before coming here, the mountain pass has been closed on order of Her Majesty.
		1: This poses a problem. 
		1: It seems Her Majesty's Army has too much on its hands to also vet travelers attempting to cross through the mountains.
		1: Even we were refused entry despite carrying the proper insignia.
		H: So what do I do? I can't just desert.
		1: Perhaps if you deal with some of the local issues, it would lighten the load on the detachment stationed here.
		H: Alright, I'll ask around.
	HOST_GIVE T32
END
@told
		1: Please do make haste, I have official duties to attend to.
END
;-----------------------------------------------------------------------------------------------------------------------------
SCENE 22, interiorShop, SCENE, "The Harp and Hippogriff Inn", 0, 0, 0
	ACTOR 1, "Gertrud", joshTownsfolk, 32, 20, 90
	ACTOR 2, "Drunkard", joshTownsfolk, 18, 60, 95
	ACTOR 3, "Notice Board", journalui, 3, 90, 40
	IF T33, @accepted
		1: Just come talk to me if you need anything!
		2: Yeah, I need another beer.
		1: You've had way too much to drink already, I'm gonna have to cut you off.
		2: I shwear to the drunk I'm not godsh!
	FACE 2, 2
		2: You wanna help me out? Got shome gold in it for you. Just lemme know.
END
@accepted
		1: Let me know if you need anything!
END
@eventActorClick1
		1: What can I do for you?
	MENU "I'd like to stay the night.=@rest", "What do you have for sale?=@shop", "What's that notice board over there?=@mercs", "Set warp point.=@save"
END		
@rest
		1: It's 75 GP per night. Interested?
	MENU "Yes.=@restyes", "No.=@restno"
@restyes
	IF G75, @sleep
		1: Looks like you don't have enough GP.
END
@sleep
	ACTOR 1, "Gertrud", joshTownsfolk, 32, 120, 90
	ACTOR 2, "Drunkard", joshTownsfolk, 18, 160, 95
	ACTOR 3, "Notice Board", journalui, 3, 190, 40
	BKGND "interiorBedroom"
	WAIT 3
		N: You quickly fall asleep.
	WAIT 3
	SET shortRests, "2"
	TAKE G75
	GIVE L1
	GIVE H5000
	GIVE M5000
	WAIT 3
		N: You awaken the next morning feeling rested.
END
@restno
		1: Alright then, let me know if you need anything else."
END
@shop
		1: We have some basic supplies.
	OFFER 1, 5, 14, 15
END
@mercs
		1: You can use that to recruit hirelings to assist you in your adventure.
		1: Each hireling has different abilities at their disposal.
		1: Once hired, you can view them and interact with them.
		1: Just go to your EQUIP menu and click "Train Pet".
END
@save
	CALL 9990@savepoint
		N: Oakhurst set as save point.
END
@eventActorClick2
IF T33, @alreadystarted
		2: Zzzzzz...
		H: Um, hello?
		2: Wha? Oh, you're about the ugliesht barmaid I've ever sheen. *hic*
		H: (Well, THAT was uncalled for.)
		H: You mentioned something you needed done?
		2: Zzzzzz...
		H: Wake up!
		2: Wha? Oh, yeah, the thing.
		2: *hic* You know that big tower in the corner of the foresht?
		H: Yeah, kind of hard to miss it.
		2: *burp* They shay a wizard lived in it back before the war. Bet he's got shomefing in there that could knock you into next week.
	CALL @wizard
		2: Wizardsh, they're the shame as the resht of ush if you ashk me.
		2: *hic*
		2: Probably enjoyed their wine shame ash ush too. But they've probably got magic wine.
		2: Get me a bottle and I'll pay you.
		H: How am I supposed to get there, though?
		2: Zzzzzzz...
		H: Dammit, you drunken lout, pay attention!
		2: *hic* Jusht go to the shipyard down by the river and tell them I shent you. Guy there owesh me a favor.
	HOST_GIVE T33
		N: (Note from Chomp: This is as far as the quest goes for now. Stay tuned for updates.)
END		
@wizard
	IF C2, @wizarddia
		N: A wizard's tower is probably full of magical treasure ripe for the picking.
RETURN
@wizarddia
		N: A wizard's old home sounds like a prime place to find new spells to learn.
RETURN
@alreadystarted
		2: Zzzzzzz...
END
@eventActorClick3
		N: You look over the list of available hirelings.
	OFFER 1000, 1001, 1002
END