;------------------------------------------------------------------------------------------------------------------
SCENE 12, beachCabin, SCENE, "Fisherwoman's Cabin", 0, 0, 0
	IF T14, @barondefeated
		N: There doesn't seem to be anyone here.
	END
@barondefeated
	IF T21, @mermaid
	MUSIC "maisy.mid"
	ACTOR 1, "Crazy Maisy", "joshTownsfolk", 6, 10, 95
		N: A woman with red hair and a twitchy eyelid stands before you, knee deep in seawater.
	WAIT 2
		N: Though you've never met before now, you know this woman by reputation.
	WAIT 2
		N: This is Maisy, the town fisherwoman. 
	WAIT 2
		N: Though she is known for her eccentricity, she provides much of the town's food.
	WAIT 2
		1: Mighty fine job ye did, takin' care of those sahuagin. Watched the whole thing from me window, I did!
		1: Ye wouldn't happen tae've seen any mermaids while ye was in that cave, would ye?
		H: Nope, just sahuagin and the occasional lizard.
		1: They say mermaid hair makes the strongest fishing line and nets known tae man! Ye could even catch a dragon with it!
	WAIT 4
		N: Maisy rambles for several minutes, singing the praises of mermaid hair as a fishing implement.
	WAIT 2
		1: What was I talkin' about again? Oh yeah, the mermaid.
		1: If ye find one, try tae get some of her hair for me, would ye? I'll pay ye good.
		1: I'll even throw in me old fishing rod. Who knows, maybe ye'll land the big one!
	HOST_GIVE T21
	END
@mermaid
	IF T24, @finished
	ACTOR 1, "Crazy Maisy", "joshTownsfolk", 6, 10, 95
		1: Any luck finding that mermaid yet?
	END
@finished
	IF T25, @rewarded
	MUSIC "maisy.mid"
	ACTOR 1, "Crazy Maisy", "joshTownsfolk", 6, 10, 95
	ACTOR 2, "Aerwyna", "joshMiscellaneous", 12, 110, 95
	POSE 12, 13, 12
		1: Ye got that hair yet? There's fish tae catch!
		H: I'll do you one better. I brought you the whole mermaid.
	WAIT 2
	MOVE 2, 90, 95
		1: Well, I'll be damned! Let's take a look at ye.
	MOVE 1, 80, 95
		1: ...
		1: Wow, yer really pretty.
		1: What's yer name, lass?
		2: It's Aerwyna. And you?
		1: Name's Maisy.
		2: You wouldn't happen to know somewhere I can stay, would you? Our mutual friend here said you might.
		1: Well, ye could stay in a spot I know near my cabin. 
		1: I was tryin' tae get a fish hatchery goin', but that project kinda fell through.
		1: The pool I dug out and filled for it is still there, though.
		2: That sounds lovely! I'll head over there as soon as I can.
	FACE 1, 2
		1: I suppose ye'll be wantin' yer pay, then. Here ye go!
		1: These potions will let ye haul up even the most stubborn fish, or ye could just use them tae hit stuff harder.
		1: Oh, and before I forget, here's that fishin' rod. Maybe ye'll be the one tae catch the legendary Cthulla of Lake Relye!
		2: And please, take this pearl as thanks for helping me.
		N: You received 3 Potions of Hill Giant Strength!
	HOST_GIVE I117
	HOST_GIVE I9
	HOST_GIVE I9
	HOST_GIVE I9
	HOST_GIVE I29
	HOST_GIVE T25

		H: You know, Maisy, you're really not as crazy as people in the village say. I could introduce you to the townsfolk and help them get to know you.
		1: Eh, I don't pay it no mind. They can think what they want. Besides, bein' a hermit has its perks.
		1: It's nice and quiet out here. It gets lonely, but hey, with Aerwyna around, that might not be the case for much longer.
	END
@rewarded
	IF T26, @cave
	ACTOR 1, "Crazy Maisy", "joshTownsfolk", 6, 10, 95
	MUSIC "maisy.mid"
		1: Catch any good fish lately?
		H: About that...
		1: Ah, havin' trouble figurin' out how tae work the fishin' rod?
		1: Don't ye worry yer wee head about it. Meet me over by the sea cave and I'll show ye."
	HOST_GIVE T26
	END
@cave
	IF T20, @learned
		N: Maisy has gone to the sea cave. You should go catch up with her.
	END
@learned
	CALL 9994@updatefishrecords
	ACTOR 3, "Crazy Maisy", "joshTownsfolk", 6, 10, 95
		3: Havin' fun fishin'?
	END
@eventActorClick3
		3: Something I can help ya with?
	MENU "How do lures work?=@lure", "How am I stacking up?=@reward"
@lure
		3: Lures are better at catchin' certain things than others. Fer example, the Fly Lure attracts fish, but it makes it less likely ye'll get a treasure or a monster. 
		3: Ye equip it in the same slot yer ring would usually go in. Just make sure tae take it off if ya get intae a fight, it ain't no good at protectin' ya.
END
@reward
	SET numRecords, "0"
	COMPARE #<shadRecord>, "5"
	IF> @shadrecord
	GOTO @cod
@shadrecord
	ADD numRecords, "1"
	GOTO @cod
@cod
	COMPARE #<codRecord>, "9"
	IF> @codrecord
	GOTO @salmon
@codrecord
	ADD numRecords, "1"
	GOTO @salmon
@salmon
	COMPARE #<salmonRecord>, "10"
	IF> @salmonrecord
	GOTO @herring
@salmonrecord
	ADD numRecords, "1"
	GOTO @herring
@herring
	COMPARE #<herringRecord>, "9"
	IF> @herringrecord
	GOTO @carp
@herringrecord
	ADD numRecords, "1"
	GOTO @carp
@carp
	COMPARE #<carpRecord>, "11"
	IF> @carprecord
	GOTO @goldfish
@carprecord
	ADD numRecords, "1"
	GOTO @goldfish
@goldfish
	COMPARE #<goldfishRecord>, "5"
	IF> @goldfishrecord
	GOTO @trout
@goldfishrecord
	ADD numRecords, "1"
	GOTO @trout
@trout
	COMPARE #<troutRecord>, "10"
	IF> @troutrecord
	GOTO @perch
@troutrecord
	ADD numRecords, "1"
	GOTO @perch
@perch
	COMPARE #<perchRecord>, "6"
	IF> @perchrecord
	GOTO @rewardtally
@perchrecord
	ADD numRecords, "1"
	GOTO @rewardtally
@rewardtally
		3: Looks like ye beat #<numRecords> of me records.
	COMPARE #<numRecords>, "1"
	IF> @reward1
	IF= @reward1
	IF< @goodluck
@reward1
	IF T3080, @reward2
		3: Hey, looks like ye beat enough of me records tae earn a prize!
		3: Here ye go, a Flawed Tourmaline!
	HOST_GIVE I20
	HOST_GIVE T3080
	GOTO @reward2
@reward2
	COMPARE #<numRecords>, "3"
	IF> @reward2give
	IF= @reward2give
	IF< @goodluck
@reward2give
	IF T3081, @reward3
		3: Looks like ye beat enough of me records tae earn another prize!
		3: Here ye go, a Braided Fishin' Line! This ought tae make catching them stronger fish easier.
	HOST_GIVE I121
	HOST_GIVE T3081
@reward3
	COMPARE #<numRecords>, "5"
	IF> @reward3give
	IF= @reward3give
	IF< @goodluck
@reward3give
	IF T3082, @reward4
		3: Looks like ye beat enough of me records tae earn another prize!
		3: Here ye go, a Flawed Turquoise.
	HOST_GIVE I25
	HOST_GIVE T3082
@reward4
	COMPARE #<numRecords>, "7"
	IF> @reward4give
	IF= @reward4give
	IF< @goodluck
@reward4give
	IF T3083, @goodluck
		3: Looks like ye beat enough of me records tae earn another prize!
		3: Here ye go, a Fly Lure! This'll make it easier tae hook a fish when ye cast a line.
	HOST_GIVE I125
	HOST_GIVE T3083
	GOTO @goodluck
@goodluck
		3: Good luck beating the rest!
	END
;------------------------------------------------------------------------------------------
SCENE 13, MermaidGrotto, SCENE, "Mermaid's Grotto", 0, 0, 0
	MUSIC "mermaid.mid"
	ACTOR 1, "Aerwyna", "joshMiscellaneous", 12, 50, 95
	POSE 12, 13, 12
	FACE 1, 2
	CALL @curiochecker
	CALL @curio1
	CALL @curio2
	IF T28, @offered
		1: Ah, hello, %1!
		1: This grotto is lovely, but it's a bit plain.
		1: Now that Maisy has taught you how to fish, I have a request for you.
		1: Word is among the other merfolk that the various fishing holes around Aurea have rare curios in their depths.
		1: Such treasures hold little value to humans, but I'd love to have a few of them. 
		1: If you liked that pearl, there's more gems in it for you if you bring me some of those treasures.
		1: You'll know when you've found one.
	SET curiosObtained, "0"
	HOST_GIVE T28
	END
@offered
		1: How are you, %1?
	END
@eventActorClick1
	MENU "I have a curio for you.=@curio", "How many curios have I found?=@progress", "Can you tell me anything about these curios?=@info", "Never mind.=@done"
	END
@curio
	IF I1024, @trident
	IF I1025, @cauldron
		1: It doesn't look like you do, friend.
END
@trident
	IF T3007, @cauldron
	HOST_TAKE I1024
	HOST_GIVE I20
	HOST_GIVE I20
	HOST_GIVE I20
	HOST_GIVE T3007
	ADD curiosObtained, "1"
		1: Ah, the Sahuagin Baron's prized Jewelled Trident. This will look lovely hanging on the grotto wall over there.
		1: And here, three Flawed Tourmalines as payment.
	IF I1025, @cauldron
	GOTO @foundall
@cauldron
	IF T3009, @foundall
	HOST_TAKE I1025
	HOST_GIVE I25
	HOST_GIVE I25
	HOST_GIVE I25
	HOST_GIVE T3009
	ADD curiosObtained, "1"
		1: Seems you've found the Sea Hag's Cauldron. Gods only know what the hag was brewing in this.
		1: Three Flawed Turquoises ought to be sufficient payment.
	GOTO @foundall	
@foundall
		1: Looks like you've already brought me everything you can so far. Check back later.
END
@progress
		1: To my knowledge, there are 32 curios to find in Aurea, and you've found #<curiosObtained> of them.
		1: Best of luck finding the others!
END
@info
		1: Certainly! Just right click on a curio and I'll tell you what I know about it.
END
@done
END
@curio1
	IF T3007, @gotcurio1
RETURN
@gotcurio1
	ACTOR 2, "Jewelled Trident", "curios", 1, 80, 40
RETURN
@curio2
	IF T3009, @gotcurio2
RETURN
@gotcurio2
	ACTOR 3, "Hag's Cauldron", "curios", 2, 10, 90
RETURN
@eventActorClick2
		1: That's the Jewelled Trident. It's a ceremonial weapon used by us merfolk.
		1: They say that one belonged to a merfolk nobleman before that nasty Baron killed him and took it.
END
@eventActorClick3
		1: That's the Sea Hag's Cauldron. Hags are evil, witch-like fey that entrap people using magical contracts.
		1: They use cauldrons like that one to brew magical reagents into powerful potions.
END
@curiochecker
	SET curiosObtained, "0"
	IF T3007, @curiocount1
RETURN
@curiocount1
	ADD curiosObtained, "1"
	IF T3009, @curiocount2
RETURN
@curiocount2
	ADD curiosObtained, "1"
RETURN
;------------------------------------------------------------------------------------------
SCENE 14, seacaveHole, SCENE, "Sea Cave- Pool", 0, 0, 0
	IF T21, @mermaid
	IF T2122, @mermaidchecked
		N: You feel like you're being watched.
	WAIT 2
		N: Look into the pool?
	WAIT 2
	MENU "Yes=@yes", "No=@no"
	END
@yes
	CALL 9990@skillcheck, perception, #<num.hostWIS>, 0, 15
	COMPARE #<finalResult>, "2"
	IF= @critsucceeded
	COMPARE #<finalResult>, "1"
	IF= @succeeded
	COMPARE #<finalResult>, "0"
	IF= @failed
	END
	@critsucceeded
	HOST_GIVE T2122
		N: (PERCEPTION) You see a mermaid staring at you from below the water's surface.
	END
	@succeeded
	HOST_GIVE T2122
		N: (PERCEPTION) You catch sight of what looks to be blonde hair as something below the surface swims out of sight.
	END
	@failed
	HOST_GIVE T2122
		N: (PERCEPTION FAILED) The water is too dark for you to see anything.
	END
@no
		N: You decide not to look.
	END
@mermaidchecked
		N: The pool seems empty.
	END
@mermaid
	IF T22, @empty
	ACTOR 1, "Aerwyna", "joshMiscellaneous", 12, 50, 45
	POSE 12, 13, 12
		1: Hello there.
		H: Uh, hello.
	WAIT 2
		H: Wait, are you a mermaid?
		1: Last I checked, I was. 
		1: Were you the one who killed the Baron?
		H: That I am.
		1: You've done me a great kindness, ridding me of him. My name is Aerwyna. Is there any way I can repay you?
		H: Now that you mention it, there is. A friend of mine wants some of your hair for something.
		1: I beg your pardon?
		H: Yeah, she said something about it making for strong fishing line.
		1: It is true our hair has some latent magic. It's how it stays so silky underwater.
		1: But is that truly all you want?
		H: I can't really think of anything else.
		1: Hmm...
		N: Aerwyna ponders your request for a moment.
	WAIT 1
		1: Very well. There is a small problem, though. Once removed from my head, my hair loses its magic if it dries out.
		1: The water in this pool has become stale and hard to breathe, and it interferes with my magic.
		1: If you can find me a new place to stay, I can fashion a magic water bubble that can keep the hair hydrated until it's ready for use.
		H: Alright, that shouldn't be too hard.
		N: Aerwyna is now traveling with you!
	HOST_GIVE T22
	END
@empty
		N: There's no one here.
	END
;-------------------------------------------------------------------------------------------------------------------------------------------------------