;
; Copyright 1999-2000 (c) Synthetic Reality Co.
; http://www.synthetic-reality.com
; All Rights Reserved
;
; This is an example Well of Souls Script File
;
; The format is not very forgiving, and the documentation is what you see here, so my
; very best of luck to you getting it to work!
;
; For a more detailed bit of documentation, please visit the web site at http://www.synthetic-reality.com/wosDev0.htm
; and check out the QUEST DICTIONARY.
;
; Comment lines must BEGIN with a semi-colon
; Most non-comment lines start with a KEYWORD, which might have some ARGUMENTS
; Some keywords announce the beginning of a new section.  A plus sign marks
; the beginning of a section, a minus sign marks the end, as in:
;
; +SECTIONNAME
; <obj#1>
; <obj#2>
; -SECTIONNAME
;
; Sections can appear in any order, but here are the current section names:
;
;  CREDITS			// documentation of the world's authors
;  STORY			// Background story which scrolls by at start
;  TERRAINS			// your names for the terrain possibilities (water, lava, etc)
;  MAPS				// descriptions (file names) of the available maps
;  TOKENS			// tokens which keep track of player achievements
;  ELEMENTS			// your definitions of the 8 elements
;  HANDS			// your definition of the 'right-hand-weapons' classes
;  ITEMS			// stuff (equipment, potions, bonus items, etc.)
;  SPELLS			// spells that can be cast, and their effects and appearance
;  MONSTERS			// Monsters you can encounter, their skills and appearance
;  GROUPS			// monster groupings (which are found together in which combo)
;  LEVELS			// Hero experience level switch points and names
;  SCENES			// scripted dialog to advance plot
;  EQUIP			// Names of the non-hand Equipment items, in case your world needs them
;  THEMES			// Ambient background sound themes for your world
;
; The #include "filename" command lets you break everything up into pieces, so you will
; see that many of the above sections are actually presented in separate files, such
; as "items.txt", "spells.txt", "levels.txt" etc.  This file ("quest.txt") then uses
; "#include" to make it appear as it the other file's contents were actually part of
; quest.txt itself.
;
; Note to players:  Don't read this until you have finished playing the world, as this
; cannot possibly enhance your experience and will no doubt rob you of small pleasures.
;
;
;
;
;----------------
; CREDITS section
; This is the script file for the world 'Evergreen'
; Here is where you should make an effort to compliment anyone who
; contributed to your world.  These credits are not yet automatically
; shown, but will be someday...

+CREDITS
Da Hood

Story by Piss Ant & Italian Ice
Skins by Piss Ant
Other Art by Piss Ant & Josh Worts
Most music by Piss Ant, with the help of MMDE(r)
	
Programming by Synthetic Reality
Contact us on the web at:
http://www.synthetic-reality.com
-CREDITS


;
;--------------
; STORY Section
; This has the 'back story' which scrolls by at the very beginning.  Most people will
; skip over this.  
; a line of text beginning with | will be centered, otherwise text is left-justified.
; Each line of text will be its own paragraph, which will word-wrap nicely (we hope)
; within paragraphs.
; don't be TOO long-winded here or people will get irritated.
; note that leading spaces in a paragraph are significant and would cause the first line
; to be indented.
;
; Special commands, one per line, control text which follows
;
; :C red,green,blue			set text color (as in ":C 255,0,0" for bright red)
; :S size					set text size  (200 is 'normal')
; :F fontName				set text font name  (use ":F  " to restore default font
;
; Note: There is a long pause just after the world is selected and before the scrolling back-story
; appears.  Normally the screen would just be black at this time.  However, you can add a file to
; your world's ART folder called "splash.jpg"
;
; If "worlds\myworldname\art\splash.jpg" exists, then that image will be displayed statickly during
; the lengthy map-loading delay.  You can't control how long the splash will be seen, however.  It
; will be seen longer on slower computers.

+STORY
:MUSIC <dahood.mid>
:S 200
:C 255,100,100
:F Times New Roman
|Da Hood
:S 75
:C 255,255,255
|~~~
|by Piss Ant & Italian Ice
|Skins by Piss Ant
|Music by Piss Ant
|~~~ 
:S 100
:C 255,153,45
Many people live their lives unable to leave behind the very thing that holds them back. 
Perhaps it is a matter of pride needed to survive the conditions one is born into, but at what point does pride blind one to the truth?
Its a hard life to lead in Da Hood where gangs will fight out of this blinding pride and politicians lie to the poor in order to further thier own ambitions.
There are those who seek salvation in religion, or drugs, or music and then that too blinds them. Then there are those who give up entirely.
And then there are those who know that your life is determined by the choices you make.
:F Courier New
:C 255,0,0
Who will you be?...
-STORY

;---------------------
; TERRAINS Section
; Up to 10 terrains (0-9) may be defined and then 'painted' onto maps.  Characters must
; possess the correct equipment to cross certain terrains.  Terrain 0 is always cross-able
; by all characters.
;
;	arg0	the terrain ID  0-9
;   	arg1	the name of the terrain (keep it short, it shows up on the terrain editor palette)
;	arg2	the damage inflicted on a character when walking on this terrain (negative heals)
;			NOTE: terrain damage not yet implemented.
;	arg3	(optional), a token number (0 not allowed) which allows travel over that terrain
;
+TERRAINS
;	arg0	arg1				arg2	arg3
;
	0,		"No Hindrance",		0,	0
	1,		"Lava",			10,	0
	2,		"Electricity",		10,	0
	3,		"",			0,	0
	4,		"Deep Water",		0,	0
	5,		"Clouds",		0,	0
	6,		"",			0,	0
	7,		"",			0,	0
	8,		"Healing",		-10,	0
	9,		"Impassable",		0,	0
-TERRAINS



;---------------------
; EQUIP names section
;
; This section is completely optional.  You only need it if you want to have different
; names for the standard equipment classes.
;
;  arg 0 	the equip ID (must be one of the following numbers):
;
;  				0	// "Helmet"
;  				1	// "Armor"
;  				10	// "Boots"
;  				11	// "Shield"
;  				12	// "Ring"
;  				13	// "Amulet
;
;  arg1		the name for that class of item.  (Keep it short as it gets used in a lot of cramped places.)
;

+EQUIP
;	arg0	arg1
;	ID		Name

  	0,		"Hat"
 	1,		"Clothes"
 	10,		"Shoes"
 	11,		"Watch"
 	12,		"Ring"
 	13,		"Bling"
-EQUIP



;--------------------
; THEMES section
;
; This section allows you to extend the sound themes available within your scenes.	A sound theme
; consists of a single looped sound (played over and over for as long as the theme is in progress)
; and one or more one-shot sounds (played at random intervals).
;
; arg0 ID (1-255)	(note that these override the built-in themes, so avoid using the lowe numbered
;					themes if you want to keep the built-in themes available
;
; arg1 name			this is just your friendly name for the theme
;
; arg2 loopSound	The name of the .wav file to be looped.  Do not include the .wav extension here, as
;					it is assumed.  The sound effect file is expected to be in your world's SFX folder, and
;					if not found there, the WoS/SFX folder is checked next.  This sound is optional, but
;					if you leave it out, don't forget to leave the comma where it would have been.
;
; argN oneshots		One or more single-shot sounds may be defined.  These are defined with the format
;					"seconds=sound" as in: "10=splash" meaning: play the splash sound about every 10 seconds
;					on average, but randomly.  You should adjust the seconds field until you get the sound
;					you like.  You will need to adjust the timing, volume, and number of single-shots until
;					you get a sound you like.

+THEMES
;	arg0	arg1		arg2			arg3 - N
;	ID		name		loopSound		seconds=sound
;
;	note: reserve first 20 for the hard-coded themes (also note that 0 means 'silence')
;
	20,		cavedrip,	campfire1,		10=drip1,10=bird1,10=splash1
;
-THEMES

;--------------------
; MAPS section
;
; Each map in the world (world, city, cave, etc.) needs an entry in this table
; Map 0 is always the main world map.
;
; As of release A77, you may now have 1000 maps (0-999)
;
;  Each map needs the following arguments:
;
;	arg0	the map ID (0-999)  0 is main world map  Link points are via map numbers
;
;	arg1	the image file name of the map (a JPG usually, but RLE BMP is OK)
;
;	arg2	the OBL file name for the map (which places link point objects on that map
;			Note: if a terrain file exists, it must share the same name, so do NOT
;			put an extension on the file name.  "iceland" would indicate both
;			"iceland.OBL" and "iceland.TER" (and possibly other files as development
;			continues.  The OBL and TER files are created when you use the map editor.
;			You are primarily responsible for generating the image file (JPG).
;			This is also the root name of the MIDI music file played when wandering
;			That map. (music files should be in the world or root MIDI folder)
;
;	arg3	The map name.  This appears briefly as the user changes maps.
;
;   arg4	The Map FLAGS. This is a number, containing several flags, which controls
;			specific behaviours of players while on a map.  Add together the values
;			of each flag you want and then set the map flags to that value.  For example,
;			if you want both flag 2 and flag 4, then set the map flags to "6"
;
;		As of release A77, you can use hexadecimal values for the map flags (start the number with 0x)
;               If you don't know what this means, just add the decimal values together for the combo you want
;
;           	The flag values are:
;
;		DECIMAL		HEX		MEANING, WHEN INCLUDED
;
;		1		0x00000001	// enables pet vs pet battles (but protects players from pets)
;		2		0x00000002	// enables pets to be used against other players or pets (if pkers or no safehaven)
;		4		0x00000004	// enables "no protection from PKer"
;		8		0x00000008	// enables "no PKing allowed here at all"
;		16		0x00000010	// enables "LADDER" reporting. (PK kills on this map are reported to ladder server)
;		32		0x00000020	// enables "show all link names." 
;							// Normally link names are hidden until after first use of link.
;		64		0x00000040	// disables "Shadows" under heroes (and monsters) on map and in scenes of that map.
;		128		0x00000080	// disables the use of pets (cannot summon them) on this map.
;		256		0x00000100	// disables eavesdropping to and from players on this map.  
;							// (you can still whisper, shout, etc.)
;		512		0x00000200	// designates the map a GUILD HALL map.  (not sure what this means yet...)
;		1024	0x00000400	// Prevents Humans from being able to damage monsters or pets
;		2048	0x00000800	// NO_REWARD.  After a fight, no GP, XP or items are found to reward the survivors
;							// Pets still get rewarded, coz I am a big softy
;		4096	0x00001000	// NO_HEAL.  Heal spells and items provide only 1HP of sustenance.
;		8192	0x00002000	// NO_TICKETS.  Tickets won't work here
;		16384	0x00004000	// NO_MINI_MAP. upper right minimap is uninformative here
;		32768	0x00008000	// NO_STUN.  the non-buff disease spells will not work here 
;							// (stun, sleep, paralyze, etc.)
;		65536	0x00010000	// NO_BUFF.	the buff/debuff disease spells will not work here.
;		131072	0x00020000	// NO_PKREZ. PKers cannot use resurrection spells on others
;       262144	0x00040000	// MAP_FLAG_HIDE_LINKS. don't show white link boxes on minimap until visited
;	    524288  0x00080000	// MAP_FLAG_NO_WAYPOINTS disable automatic waypoint calculations (good for mazes)
;
;	arg5	The map Sound Theme 0 (none) - 255 (see THEME table for making your own themes)
;			If you provide this argument, it picks a sound theme which will be played while the player is walking
;			on the map (not inside a scene of that map, though you might want a common theme.)  Note that you 
;			cannot have multiple themes on one map.

;
; FOR EXAMPLE:
;
;	arg0	arg1				arg2				arg3						arg4			arg5
;	ID		image file			OBL/TER/MID	root	Map Name (seen by player)	Map FLAGS		Map Theme
;
;	0,		wormCave.jpg,		wormCave,			"Wyrm Cavern",				0,			0
;	5,		town2.jpg,			westin,				"Westin",					0,			3
;	6,		town3.jpg,			stonetree,			"Stonetree",				0,			0

+MAPS

;
; The actual map definitions are in this file, which is created by the New World Wizard:
;
#include maps.txt

-MAPS


;--------------------
; Tokens are used by the script engine to keep track of what the player has accomplished.
; Each token is just a number, in the range 1-4095
;
; When you design your quest, assign a token to each major phase of the quest.  For
; example, at the start of the game, the player has no tokens.  But after you have
; told them the nature of a puzzle, you would give the player the token which
; represents that puzzle.  That way, when the player returns to the same scene, the
; script engine sees that he already has the token and hence doesn't repeat the
; explanation (but perhaps gives a short recap reminder instead).  Once the player
; has completed the quest (killed the dragon, etc.) you give him a different token.
; If the player already has the final token for a quest, then the script engine
; can simply skip the whole thing, or just deliver a 'thank you' message.
;
; This example uses the least significant digit to identify the tokens (up to 10) 
; which belong to a single quest, and the higher digits as a 'quest #' (for
; example, token 47 would be token #7 of quest #4).  This is completely arbitrary
; and you are allowed to use token numbers in any order you like.
;
; For example, let's pretend there is a minor quest which requires killing a dragon.
; The tokens might be:
;
;  token 1  - the king has told me to kill the dragon
;  token 2  - I have killed the dragon
;  token 3  - I have returned to the king and gotten my reward
;
; Then the script file for the king's throne room might look like this:
;
;  IF T1  @alreadyToldHim
;    'Hello young man, please kill the dragon for me
;    GIVE T1
;  END
;
;@alreadyToldHim
;  IF T3  @alreadyRewardedHim
;    'Thank you for killing the dragon, here is some gold
;    GIVE G100
;    'And here is my silver ring of dependability
;    GIVE I43
;    GIVE T3
;  END
;
;@alreadyRewardedHim
;  'Hey, I already GAVE you the ring of dependability!  Get out of here!
;  END
;
;------------------------------------------------------------------------------------
; You don't have to have a token defined in this section to use it in the script,
; But you will probably find it easier to keep track of things if you do.  Also,
; I use the decriptions you give here to create a 'log book' the player can read
; to review what they have done so far.
;
; You may find it easiest to write the outline of your quests in this section first,
; and not flesh out the actual scenes until the entire structure of the world has
; been defined.

+TOKENS
	1,"You got yo pops child support money."
	2,"momma gave you a west side doo rag."
    3,"You can use the subway."
	4,"You saved a kid from getting mugged and got tickets."
	5,"You saved 25 Cent from his crazy fans and got his Bluker Shoes."
	6,"You killed Willie and now control the Nite Hood prostitute ring."
	8,"You save the prostitutes from Willie, and received The Sexy Watch as your reward."
; Quest 1, Gettin Respect
	10,"25 Cents lawyer told you to get some photos for his pending lawsuit."
	11,"You fought the mysterious man who wanted the photos and denied him the pictures."
	12,"You chose to give the photos to the mysterious man instead of the lawyer and received money as a reward."
	13,"You chose to support your homie 25 cent by giving his lawyer the evidence for the lawsuit."
	14,"Biff in Airport wants you to pick up his package from Da Burbs Pawn Shop."
	15,"Da Burbs Pawn Shop owner gave you a package for Biff."
	16,"You got the REAL package Biff wanted."
	17,"You discovered that the package that the Pawn Shop owner gave you was fake."
	18,"You got Biff his package and now he will spread the word in Da Hood about you."
	19,"You have the respect of the 14th Street Crew."
	20,"You have the respect of the flip side gang."
	21,"You are expected to execute a shoplifter at the jail."
	22,"You executed a convict who was trying to feed her starving children."
	23,"You freed a wrongfully imprisoned woman and beat down the police."
	24,"You have earned the respect of Da Hood Law Practitioners Organization."
	25,"You have reunited a mother with her children."
	26,"You have the respect of EVERYONE in DaHood."
	27,"You have defeated Sho Nuff and beaten the game. Good Job."
	28,"25 Cent Rewarded you for helping his lawyer."

-TOKENS


;---------------------
; ELEMENTS Section
; 
; Every world has exactly 8 'elements' which you must define (or terrible things will happen..
; woe is you!)  The 8 elements form a circle which describes their effectiveness against
; each other.  The opposing element is most effective against an element.
;
; Visualize the IDs like this (many thanks to Janne Jaula for this):
;
;         0
;      7  |  1
;       \ | /
;    6 ---+--- 2
;       / | \
;      5  |  3
;         4
;
; With ID 0 at the NORTH position.  This must be your 'healing' spell. and will apply healing
; equally to all characters, independent of their element affinities.
;
; The rest of the elements wield pain according to their position on the chart with element 1, 
; for example, delivering the most damage to element 5, somewhat less to 4 and 6, and a little to 7 and 3
; while hardly any to 0 1 and 2.
;
; It is likely that element 4 (the opposite of 0) will also be singled out for some special
; effect in the future... the element table is new :-)
;
;	arg0	the element ID  0-7
;   arg1	the name of the Element (keep it short, it shows up on the element affinity chart)
;									(also if the first letter could be unique, it would help)
;
; Note: you can actually use element IDs from 8-255 as well, with Spells and Monsters.  But you cannot
; name those elements (they all show up as "chaos" elements)(as of A78, you can)
;
+ELEMENTS
;	arg0	arg1				
;
	0,		"Citizen"		
	1,		"Law"			
	2,		"Money"			
	3,		"Sex"			
	4,		"Crime"		
	5,		"Politics"		
	6,		"Drugs"		
	7,		"Rap"	
;
; As of A78, you may optionally give names to the 'chaos' elements (#8-#255), though it will make no 
; difference to the behaviour of the element itself.
;
-ELEMENTS

;-----------------------
; HANDS section
;
; Similar to elements, the 'hand' classes represent the different styles of
; weapons which can be held in the 'right-hand.' The EQUIP screen allows the
; player to train themselves in these 8 categories.  Only after they reach
; level 5 in a category are they able to wield weapons of
; that category.  
;
;	arg0	The ID of the 'hand' which strangely enough is numbered 0-7 even though
;			elsewhere it is referred to as 1-8, so I expect to needlessly confuse
;			you about this.
;	arg1	The name of the weapon class.  
;	arg2	The 'range' of the weapons class.  This should be a number in the range
;			0-100 which represents the distance at which EQUIP attacks WILL NOT MISS. A
;			small range circle will be drawn at your feet when you have the EQUIP
;			list selected and it is your turn to fight.
;   arg3    The sound effect to be played when this hand attacks, unless the equipped item
;			has its own sound effect.  If neither the hand nor the weapon has a specified
;			sound effect, one is selected at random each time you load the world.
;
; 	arg0	arg1
;	ID		Name

+HANDS
;  
; arg0		arg1		arg2		arg3
;  ID		Name		Range		SoundFX
;
	0,		"Pimp",	50,			"fist.wav"
	1,		"Choice",	90,			"staff.wav"
	2,		"Drugs",		100,		"ah.wav"
	3,		"Audio", 	80,			"zap.wav"
	4,		"Weapons",		60,			"fist.wav"
	5,		"Cop Gear",		90,			"dart.wav"
	6,		"Strategy",		90,			"dart.wav"
	7,		"STDs",	90,			"gasp.wav"
-HANDS


+ITEMS

; The actual item definitions, and documentation, are in this file:
#include items.txt

-ITEMS


+TROPHIES
; The actual trophy definitions, and documentation, are in this file:
#include trophies.txt
-TROPHIES


+SPELLS

; actual spell definitions, and documentation, are in this file:
#include spells.txt

-SPELLS


+MONSTERS

; actual monster definitions, and documentation, are in this file:
#include monsters.txt

-MONSTERS


+GROUPS

; actual groups, and documentation, are in this file
#include groups.txt

-GROUPS


+LEVELS

; actual character classes, levels, and documentation are in this file
#include levels.txt

-LEVELS



;-------------------
; Individual Scenes (each needs a unique scene number)
;
; Reserved Scene numbers are:
;
;   0	Well of Souls (primary well for your main map)
;   1   General CAMP scene (inherits jpeg, theme from closest link)
;   2   General FIGHT scene (inherits jpeg, theme, and monster level from closest link)

; For a more detailed bit of documentation, please visit the web site at http://www.synthetic-reality.com/wosDev0.htm
; and check out the QUEST DICTIONARY.

; Scene Command Overview
;
; A scene consists of a series of scene commands.  The first command of a scene must be the
; "SCENE" command which assigns it a unique id number and some initial settings.  The final
; command must be an "END" command which terminates the scene (otherwise, the first command
; of the following scene would be executed and that would probably be a bad thing)
;
; For example:
;
;	SCENE	<scene number><jpg><type><title>
;     a command
;     another command
;     and the command after that
;	END		<end of scene, personal magic and item use may begin>
;
; While a scene is executing, the player cannot do normal fighting actions, nor use
; items or spells in general.  Link points on the map can be bound to specific scene
; (by ID number) and that starts execution of the scene.  After the first "END" command
; is executed, the scene is over, but the player is left in the scene viewing it in its
; final state.  At that point the player may use items, magic, and possibly fight other
; players.
;
; Please see example scenes in this file for a more intuitive understanding of how scenes
; work.
;
; The following is a list of available scene commands and their usage
;
;-----------
;	THEME	<sound Theme> (if no number given, or 0,  then use theme from link point)
;                      -1:                      // stop ambient sounds
;			0:			// stop ambient sounds, or use closest map link theme
;			1:			// near a bubbling brook
;			2:			// rain storm
;			3:			// windy aerie
;			4:			// light wind
;			5:			// waterFall
;			6:			// campfire
;			7:			// Raging Fire
;			8:			// Birds
;
; This command turns on and off the background ambient sound effects in the scene. (the initial
; theme can be started automatically as part of the SCENE command)
;
; Use THEME -1 to stop a theme
; Use THEME 0  to play the theme associated with the closest map link
;			
;-----------
;	MUSIC	<midi file>
;
; This command changes the currently-playing background MIDI music file.  The game  looks first
; in the current world's MIDI folder for a file of the name given.  If not found, it looks in the
; root WoS\MIDI folder for the file.
;
; To turn music off, try to play a file whose name does not exist.
;
;-----------
;	SOUND	<WAV file>
;			as in:  SOUND "mySound.wav"
;
; This command causes the WAV file in the current world's SFX folder to be played (one time)
;
;-----------
;	BKGND	<JPEG file>
;			as in:  BKGND "myBackground"
;
; This command causes the scene's background jpeg to switch. Note that the background
; specified in the SCENE command will be shown first, so if you need to avoid a flash
; of the default background before you determine (via tokens) which background is
; appropriate, be sure to set the default background to something like all black, or 
; whatever works for your world.
;
; New to A76 - WIDE SCENES.  In either the SCENE command or the BKGND command, you can now specify
; an optional WIDTH and HORIZON setting.  For example, if you said the jpeg name was "cave.300.25" that
; would mean "use the file cave.jpg for the background, but it is actually 3x normal width, and the horizon is
; at 25% from the top"  This would limit characters from walking above the bottom 75% of the screen (use 0
; for unrestricted motion).  Since the background was 300% of normal, it could not all be seen at the same
; time.. you would have to walk a long time to cross it all.  And you won't be able to see everyone in the
; scene at the same time.  Hence there is the concept of the CAMERA which attempts to focus the display on
; the most important thing happening.  These rules are complicated and vary with fighting and chatting.
;
;-----------
;	WEATHER	<Weather ID#>
;			as in:  WEATHER 9
;
; This command causes the scene's weather to change
;
;-----------
;	FX	<FX ID #>
;			as in:  FX 2
;
; This command causes the scene's FX to change
;
;-----------
; @labelName
;
; Starting a line of a scene with an @ symbol makes that line a 'label.'  Several commands
; allow you to jump to a labeled line of a scene in an effort to loop, or perform different
; actions based upon the player's circumstances.
;
; Note: the label must be on a line by itself - do not place other scene commands on the same
; line

;-----------
;	GOTO	<labelName>
;
; This command immediately jumps to the specified label and then executes the script command
; on the following line.  Be careful about unintentionally creating infinite loops. Spaces are
; not allowed in label names.  Just use letters and numbers with a single @ in front
;
; For example:
;
;     SCENE <arguments not shown>
;       command1
;       command2
;     @thisIsALabel
;       command3
;       command4
;       GOTO @thisIsALabel
;     END 
;
; This scene will execute commands 1 and 2, then repeat infintely executing commands 3 and 4
;
;-----------
;  GOTO EXIT
;
; This command causes the players to be booted from the scene and back to the map, as if the
; scene host pressed their (camp) EXIT button.
;
;-----------
;  GOTO SCENE <scene number>
;
; This command lets you jump the player from the current scene into a new scene (which then starts
; at its beginning.)
;
; However, when you exit the scene, you will be at your original location (the place where you
; dropped into the original scene). This command never changes your current map.
;
; Jumping to a non-existent scene number may not fail gracefully.
;
;-----------
;  GOTO LINK <map number>, <link number>, <dropin code>
;
; This command actually moves the character to a position just above the specified link on the specified map.
; For example:
;
;     GOTO LINK 0,0
;
; On evergreen, this would take you on top of the gateway link on the main map.
;
; The third argument (dropin code), if present and non-zero, causes the player to drop 'into' the link
; after arriving.  What happens after that is a function of the link in question (might do nothing, might
; go into a scene, might link to a whole different map)
;
; So:
;
;     GOTO LINK 0,0,1
;
; On evergreen, this would move the player to just above the gateway link on the main map, and then drop the
; player INTO the gateway (scene).  When the player exited that scene, they would be on the main map just
; above the gateway.
;
;-----------
;	IF		<id list>   <label>
;			Tnn+Snn-Inn+Gnn+WIN-LOSE+ALIVE-DEAD+YES-NO
;           Token, Spell, Item, Gold, Won last fight, lost last fight, still alive, dead, answered YES or NO to recent ASK
;           all tokens measured against scene SERVER only
;			all specified terms must be TRUE (or FALSE if preceded by minus sign)
;
; This command checks to see if the condition given is TRUE and if so, it jumps to the specified
; label.  Otherwise it just continues with the next scene command.
;
; The condition is specified as a list of IDs separated by plus and minus signs.  The IDs each start
; with a unique letter possibly followed by a number.  For example "I34" means "Item 34" It is TRUE 
; if the player hosting the scene has item 34 in his or her pocket.  "T12" means "Token 12" and
; usually you will check the presence of tokens to decide which path to take through your scene.
;
; If you need two conditions to both be true in order to jump to the label, then list both IDs and
; separate them by a plus sign.  If you use a minus sign in front of an ID, then it is true if
; the player does NOT have that ID.  For example "T12+I15-S22" means: "If the player has Token 12
; AND item 15, BUT NOT spell 22, then the condition is true and the jump to label will occur"
;
; For example:
;
;     SCENE <arguments not shown>
;       command1
;     @label1
;       command2
;       IF  T3-T4+T5, @label2
;       GOTO label1
;     @label2
;       command3
;     END
;
; In this case, the scene starts by executing command1, and then gets stuck in a loop, executing
; command2 over and over until the condition is true, allowing it to jump to label2 and execute
; command3 then leave.  
;
; The condition we are looking for is "Player has token3 and token 5, but NOT token 4" (and
; again, only the player who is hosting the scene is checked. tokens and items in the possession
; of other players in the scene are not important)
;
; The condition IDs supported are:
;
;     ALIVE		player is alive
;	  Cn		true if player is of character class 'n'
;     DEAD		player is dead
;	  Enn		Player is EQUIPPED with item nn (not just in possession of one)
;     Fnn		true if player is on a map with this 'map flag' set. (nn = 1, 2, 4, 8, 16, 32, etc.)
;     Gnn		Player has at least nn gold pieces
;     GS		True if scene host is a 'golden soul'
;     Hnn		true if this CHARACTER is nn hours old (or older)
;     Inn		player has item nn (from ITEMS table)
;     LOSE		player lost last fight in this scene
;     KBn		player has been killed at least once, by monster ID = n
;     KBn.x     player has been killed at least x times by monster ID = n
;     KMn		player has killed at least one monster 'n' (monster ID = n)
;     KMn.x     player has killed at least 'x' monsters of type 'n'
;     M0		true if player is a CHEATER character  (m-zero)
;	  M2		true if player character has played in a modified world before.
;	  M4		true if player has ever turned off the "avoid modified quest files" option.
;     NO		player answered NO to last ASK scene comman
;	  P0    	true if player is a PLAYER KILLER (p-zero)
;     Pnn     	true if player is a PLAYER KILLER *and* has killed other players at least nn times.
;     Qword		player answered 'word' to last ASK scene command (use ^ if your word has spaces.. "Qbutter^fly" matches "butter fly")
;	  Rnn		Random Number (nn = 00-99, represents percent chance of TRUE)
;     Snn		player has spell nn (from SPELLS table)
;	  Tnn		player has token nn (from TOKENS table)
;     Vnn  		true if player's level is greater than or equal to nn
;     WIN		Player won last fight in this scene (after FIGHT scene command)
;     XP		true if the COUNTDOWN TIMER has EXPIRED (use the COUNTDOWN opcode to start the timer)
;     YES		player answered YES to last ASK scene command
;	  #nn		true if player is currently on map nn (as defined in MAPS table)
;
;
;-----------
;   ACTOR	<ID #><character name><skin><pose><x,y>
;
; This command creates an ACTOR in the scene. Actors can walk around and deliver
; scripted lines of text.  Each actor in the scene needs a unique ID number (unique
; to that scene, not to ALL scenes :-)
;
; You give the character a name, the name of a skin file with its image in it, and the
; pose (offset within that file).  These 'villager' skin files are stored in the world's
; MONSTER folder and are long filmstrips with many different villagers in a single
; file.  You also give the actor an initial position to be standing on the screen.
;
; X and Y vary from zero to 100 which relate to the max size of the window (so x=100 is
; always the far right edge of the screen, no matter what size the window has been stretched
; to.)  Using values sufficiently outside the range will start the actor 'off screen' so that
; a subsequent 'MOVE' command can have them appear to walk in from off stage.
;
; You usually define an ACTOR or two right at the start of the scene, but you can use
; the command at any time, in case you have an actor which is only present if certain
; conditions have been met.
;
; For example:
;
;    SCENE <arguments not shown>
;       ACTOR 1, "Old Carl", "joshVillagers", 3, 20, 80
;       IF -T12, @noYoungCarl
;       ACTOR 2, "Young Carl", "joshVillagers", 15, 50, 80
;    @noYoungCarl
;    END
;
; Here the scene starts by creating "Old Carl" as actor #1 standing at the lower left of
; the screen.  Then if the player does NOT have token 12 ("-T12") it jumps to the label
; and skips the creation of "Young Carl" who otherwise would be standing in the lower
; center of the screen.
;
;-----------
;   MOVE	<ID #>, <x>, <y> {,<optional mode>}
;
; This command tells a previously declared ACTOR to move to a new x, y position on the
; screen.  This is a real time action and it may take them awhile to amble on over.  You
; might need a WAIT command if you want the next scene command to not take place until after
; they get there.
;
; The optional <mode> value controls the nature of the motion.  If you don't specify it, it will
; use mode 0 (normal walking).  mode '1' will cause the actor to instantly teleport to the new x,y
; location (A good way to get a character offscreen in a hurry).  As of version A74, modes 2, 3, 4, and 5
; will make the actor move varying amounts of more_quickly.
;
; For example:
;
;    ...
;    MOVE  1, 50,50              <-- actor '1' walks leisurely to center of screen
;    MOVE  2, 0,0, 1             <-- actor '2' teleports instantly to upper left of screen
;
;-----------
;   POSE	<pose>	{, pose2, pose3}	(change pose of current actor)
;
; When you created the ACTOR, you specified both an image file name, and an offset (pose) to
; a particular image of that file's filmstrip.  If you have several images of the same
; character in that file, this command lets you flip between them for whatever reason you
; like.  For example, I use it to 'morph' the evil witch into her true self.
;
; The pose you specify will be held until you specify a different one.  HOWEVER, as of
; version A30, you can specify two additional poses (3 in all, pose1, pose2, and pose3).
;
; If you specify the additional poses then the actor will cycle between pose1 and pose2
; for approximately equal (but random) amounts of time, with occasional brief displays
; of pose3.  For example, pose1 and pose2 might be a frog looking in different directions,
; while pose3 shows his tongue flitting out.  You cannot currently control the timing,
; so for critical animations, just use a sequence of POSE commands with appropriate WAIT
; commands.  The advantage of the multi-pose POSE command is that the animation continues
; even after the script END command, and requires no special scripting.
;
;-----------
;	SELECT	<ID #>		(select actor # as the current speaker)
;
; Some commands work on the 'current actor' as opposed to calling one out by name.  This
; command lets you select the current actor by ID number.
;
;-----------
;	' line of speech by character (additional lines require 'more' click by reader)
;
; This was the first way of making an actor speak.  I seldom use it anymore, but let's
; pretend it is important anyway.  For example:
;
;   SCENE ...
;      ACTOR 1, "Billy", ...
;      ACTOR 2, "Sally", ...
;      SELECT 1
;      ' Hello, my name is Billy
;      SELECT 2
;      ' Hello, my name is Sally
;   END
;
; This is pretty clumsy, and if all you are doing is speaking, it is more efficient to use
; the "N:" form instead, as in:
;
;   SCENE ...
;      ACTOR 1, "Billy", ...
;      ACTOR 2, "Sally", ...
;      1: Hello, my name is Billy
;      2: Hello, my name is Sally
;   END
;
; Each line of text you put in creates a speech bubble over the head of the actor who said it.
; Only one actor can have a speech bubble up at a time, so the script will automatically pause
; before executing the next speech line until the previous bubble disappears.  Bubbles disappear
; after a brief timeout, or can be cleared by right-clicking in them.
;
; The percent sign symbol (%) is used as a special character.  The number following it lets you
; stick in real-time information about the current players.
;
;		%0 - speaking character's name
;		%1 - server player name (player hosting the scene)
;		%2 - client name (each client sees his or her own name)
;		%3 - a random insult name "stupid maggoty rat-face"
;		%4 - name of the last person to type in chat
;		%5 - name of last person who typed YOUR NAME at start of chat line
;   	%C  - class name of scene host ("magic-user")
;       %Cn - class name of class n (starting at 1) from world level tables.
;		%En - item number of equipped item in slot n (n=10 for HELMET..) use n=0 to get 'equipped right hand' item ID
;		%In - name of ITEM n
;		%K0 - Total number of monsters killed by scene host
;	%Kn - Number of monster ID n killed by scene host
;       %L  - level name of scene host ("emperor")
;       %Ln - level name for level n of scene host's class
;       %L-1 - level number of scene host ("99")
;		%Mn - name of MONSTER n
;		%Rn - Random number from 1 to n (n from 1 to 30,000) 
;		%Sn - name of SPELL n
;		%Tn - token name n
;       %% - inserts a single visible percent sign
;
; For example:
;
;      1: Hello, my name is %0.  Your name is %2. Your host's name is %1
;      2: I, %0, think you are a %3!
;      1: I am 99%% sure you are also a %3!
;
;-----------
;   N:  (shorthand SELECT N followed by ' --  N is 0 to 9 only)
;       as in:
;       2: Actor 2 said this
;		1: Actor 1 said this
;
; As described more fully above.
;
; As of A57, you can now use "actor 'H'" to mean "put words in the mouth of the scene host (an
; actual player, not an actor!)
;
;       1: Hello, foolish human
;		1: Repeat after me
;		1: Owa
;       H: Owa     <-- appears to have been typed by scene host
;       1: tana
;       H: tana
;		1: siam
;       H: siam
;       1: Ok, altogether real fast now
;		H: Ok, Owa tana siam..
;       H: Owatanasiam...
;       H: O wat an ass i am
;       H: Hey!!!!
;       1: Hee hee hee
;
; As of A61, you can now use "Actor 'N'" to mean "add some narration to the scene.
;
;       N: And then the sun set on joy.
;
; Narration appears in the chat window, and as a scrolling line of large text in the
; main scene window (but does NOT appear in a chat bubble).
;
;-----------
;   WAIT	<seconds>  (use decimal point for sub-seconds)
;
; This command lets you put in a little pause before the next command is executed.  As in:
;
;   SCENE ...
;       ACTOR 1, "Dave", joshVillagers, 1, 20, 80
;		MOVE 1, 80, 80
;		WAIT  3.5
;       1: I should be there about now
;   END
;
; This creates 'Dave" on the lower left of the screen and then starts him walking to the
; lower right.  3.5 seconds after starting his walk (whether he has finished it or not)
; his speech bubble pops up.
;
;-----------
;	FIGHT	<fight scene - no arguments means 'standard random fight appropriate to vicinity'>
;		FIGHT 1,2,2,4  (fight 4 monsters total, two of type 2)
;
; This command plays out a monster fight within the scripted scene itself.  The next 
; scene command is not executed until the results of the fight are known (all heroes dead
; or all monsters dead).  At that point the WIN and LOSE "IF" conditionals will work.
;
; You can call out a particular collection of monsters via their IDs from the MONSTERS table,
; or you can have monsters selected randomly from the current map area monster group.
;
; For example:
;
;     SCENE ...
;         ACTOR 1, "Zor", evilPeople, 1, 50, 50
;         1: Prepare to die, %2, you %3!
;         FIGHT 23,12,12
;         IF WON, @youWon
;         1: I knew you would lose, you %3!
;         END
;     @youWon
;         1: Big deal, you won, so what, who cares.
;     END
;
; So here we create 'Zor' in the top center of the screen and he insults us.  Then 3 monsters
; appear as in a regular fight scene (with Zor still standing there watching us).  We get one
; monster #23, and two monster #12s (as defined in the MONSTERS table)
;
; After the fight, if the player wins, we jump to label '@youWon' and graciously concede defeat.
; Otherwise we execute the line following the IF and brag a little, then END the scene.
;
; Note that this scene now has two END commands in it.  That's OK.  The first one we execute ends
; the scene.
;
; Stupid FIGHT tricks:
;
;  Use the opcode FIGHT2 for exactly the same effect, except the scene host is also 'stuck in the
;  fight (similar to a PK Attack) until they stand still without fighting for 20 seconds or so
;  (this is about as close to a forced fight to the death as the game gets)
;
; Mercenaries
;
;  If you call out a monster by ID, but add a minus sign, as in:
;  
;    FIGHT  1, 2, 3, -4
;
;  Then that monster will fight on your side (in this case monster ID 4 is the helper against 3 evil monsters)
;
; Mixed Stuff to The Max
;
;  If you include a '*' as one of the monster IDs, it means "also use monsters from the map", so:
;
;     FIGHT  *, 1, 2, 3
;
;  Means you will have a fight with monsters 1, 2, and 3 PLUS whatever a normal fight at this location might
;  have had.
;
; Scene 2 is the FIGHT SCENE
;
;   I hope I am not lying when I say that the FIGHT command in SCENE 2 is what controls all standard map
;   monster fights.  (the kind you get drawn into when hunting or walking the map).  So anything clever you
;   do in that scene will affect all monster fights.  So, you could check what map you were on, what tokens
;   the player had, their spiritual alignment (maybe) etc, and then populate the fight accordingly.
;   This was my intention, in any case, though I never had the courage to try anything radical.
;
;-----------
;	GIVE	<id#> 
;
; This command gives the specified object to all current members of the scene (um, even 
; dead ones I think).  Objects are specified the same as in the "IF" command conditionals
; with a letter followed by a number.  Unlike the IF command, however, you can only give
; one thing per line. (no plus and minus signs please)
;
; Objects you can give include:
;
;		Tn	token N
;		Gn	N pieces of gold
;		In	item N
;       Sn  spell N
;       Hn  n health points (up to max)
;       Mn  n magic points (up to max)
;       <given to all members of scene>
;
; For example
;
;     SCENE ...
;         ACTOR 1, "King", joshRoyalty, 3, 50, 50
;         IF T10, @killedDragon
;         1: I see you have not yet killed the dragon, begone!
;         END
;     @killedDragon
;         1: Hey, you killed the dragon, accept this gold from me, please!
;         GIVE G100
;     END
;
; So, when we visit this scene, the king checks our pocket for token 10 (which we
; presumably get after killing the dragon in some other scene) and if we don't have
; it, the scene ends with a 'hint'
;
; Otherwise, we jump to the label and the king rewards us with 100 gold pieces (generous
; guy, huh?)
;
; Note that this is a bad scene since once we kill the dragon the king will give us another
; 100 GP every time we visit the scene.  Most quests should have another token which means
; "I already gave you your reward" and the scene would check both tokens so we only got
; our reward once.
;
;-----------
;	TAKE	<ID>		<this is evil!>
;		<taken from all members of scene>
;
; Same as the GIVE command, but in reverse.  Very evil.
;
;-----------
;   ASK		<seconds> - waits a while for scene server to type something ("yes" or "no" flags set in response)
;
; This command is used when you want to ask the player a question and actually read his or
; her answer and do something based on the response.  The actual question is asked using the
; normal speech bubble stuff.  You just follow that command with an ASK command as in this
; example:
;
;     SCENE ...
;        ACTOR 1, "King", ...
;        1: Say, %1, does this coat make me look fat?
;		 ASK	20
;        IF  YES, @saidYes
;        1: You really think so?  Thanks!
;        END
;     @saidYes
;        1: Off with your head!  Guards, take %1 to the dungeon and relieve HIM of a few pounds!		
;     END
;
; Here the king poses a question.  The "ASK 20" pauses the script for up to 20 seconds (or
; until the host player types a line of chat).
;
; If a line of chat is entered before the timeout, and it starts with something resembling
; a yes, then the "YES" condition will be true and the "IF" command will jump to the label
; where the king is unhappy with us.  Otherwise (nothing was typed, or what was typed did
; not look like a yes) the king is happy enough and the scene ends.
;
; The "Qword" conditional lets you scan the host player's response for particular words or
; letter sequences ("yes" would be found inside of "yesterday" for example), so you could have
; complicated processing like:
;
;     ...
;     1: What is your favorite color?
;     ASK  30
;     IF Qblue, @wasBlue
;     IF Qred, @wasRed
;     IF Qorange, @wasOrange
;     ...
;
; Note that "Qwords" cannot include spaces, so you cannot have "QI don't know" which would be cool
; for the Monty Python fans.
;
; Oooooh, if I was a good little  programmer, this might work:
;
;      IF QI+Qdon't+@know, @heDontKnow
;
; Of course, that would also trigger on the player response: "Don't you know I like red?" since it 
; checks for the presence of the "Qword" anywhere in the response.  I *think* case is not 
; important (I'm using standard c library "strstr()" for anyone who is interested)
;
;-----------
;	OFFER	<item>{,<item>} - displays a SHOP button which, when pressed, offers the specified items for sale
;
; Normally a scene does not have a SHOP button until you execute an OFFER command.  The OFFER
; command comes in two flavors, differing in the way you specify the list of items available
; in the store.
;
; The OFFER command takes a simple item list and is best used for specialty stores offering
; a limited number of items, as in:
;
;     SCENE ...
;        ACTOR 1, "Shopkeeper", ...
;        1: I have only these items. Buy them or leave!
;        OFFER  4, 12, 103, 11, 22, 7, 15
;     END
;
; Only those seven items will appear when the player presses the SHOP button.  Item numbers
; match to entries in the ITEMS table
;
;-----------
;	OFFER2	<minLevel>,<maxLevel>{,itemClass} - displays a SHOP which offers all defined items between the two levels (with non-zero prices)
;			note: only the first 50 or so qualifying items will make it, so don't try for one store to sell EVERYTHING
;			the optional third argument limits it to items of the specified class.
;
; This newer form of the OFFER command is good for shops which provide a large number of items
; of a particular class.  For example, all boots between level 5 and 10 would be:
;
;      OFFER2 5, 10, 20
;
; Where the class number (20 for boots) is set in the ITEMS table 'class' column.
;
; You can have your store sell several classes  of items at the same time, by including the correct
; three numbers for each class: <minLevel>,<maxLevel>,<itemClass>
;
; As in:
;
;      OFFER2 5,10,20,  5,10,21,  1,10,22
;
; This would offer all class 20 items between levels 5 and 10, all class 21 items between levels
; 5 and 10, and all class 22 items between levels 1 and 10.  (the level limits are inclusive)
;
;-----------
;   GAME  <game number>
;
; Similar to the OFFER button (and you cannot use both OFFER and GAME in the same scene), this
; results in a GAME button appearing for the player.
;
; Pressing that button brings up a mini-game for the  player to enjoy while in the scene.
;
;   GAME 1	- The slobber slots machine.
;	GAME 2	- The Monster Racer
;	GAME 3	- The Search for Pi at Home
;	GAME 4	- Blackjack 
;   GAME 5  - Pokegatchi Training Center (same as 'train pet' on Equip Screen)
;   GAME 6  - Asteroids
;   GAME 7  - Stock Market Game
;   GAME 8  - Tetris
;
; These are all, so far, solo games (since WoS itself is the multiplayer game), but you can
; enjoy them in the presence of other players.
;
;-----------
;   COUNTDOWN <seconds>
;
; This command starts a COUNTDOWN timer (displayed on the main screen) which counts down to zero.
; When it hits zero, it disappears.  Cool huh?
;
; To make it useful, you need a scene which tests it with the 'X' conditional, as in:
;
;	IF  XP, @youAreTooLate
;  	1: You made it before the countdown finished!
;	END

; @youAreTooLate
;  	1: Could you possibly have walked any more slowly?
;
; You can turn the counter off prematurely by setting it to zero ("COUNTDOWN 0")
; The countdown automatically terminates if you leave the game, or change characters.
;
;----------------------------------------------
; The SCENE opcode has the following arguments:
;
;	SCENE		arg1		arg2		arg3		arg4		arg5		arg6
;				scnNum		scn.jpg		Style		Name		Effects		Weather
;
;	scnNum - every scene must have a unique scene number.  Link points on maps can
;			call out specific scene numbers.  In addition to that several scene numbers
;			are special:
;				0	Is always the intial well of souls (where you incarnate)
;				1	The standard 'camp' scene (links can override details)
;				2	The standard 'fight' scene (links can override details)
;				it is advised that you treat scene numbers 0 through 9 as 'reserved' to 
;				avoid conflicts with later developments
;
;	scn.jpg	- The background JPG file (from the SCENES folder of the world) to be used
;			as the background image of the scene.  Do not include the .JPG extension
;
;	Style	-	To Be Defined
;				WELL, FIGHT, SCENE, CUT
;				Just go with the flow on this one for now.  I might make it more important
;				later.  For now, here is the special meaning:
;					WELL - it is the primary Well scene.
;					FIGHT - it is the standard fight scene
;					SCENE - it is a scripted quest scene <-- use this normally
;					CUT	- it is a normal scene, but "heroes" are invisible (only actors appear).
;
;	Name	- The name of the scene (seen on title bar while in the scene)
;
;	Effects	-	Special effects applied to the background JPG.  These effects last for the
;				duration of the scene (except when temporarily modified by a spell during
;				a particular magical attack)
;				0	No effects
;				1	Underwater ripple (as though viewer is under water)
;				2	Lake ripple (as though the bottom 30% of the scene is a lake reflecting)
;				3	Video (every other line is black, giving a 'coarse video' quality
;				4	Jitter (random vertical jitter)
;				5	EarthQuake
;
;	Weather	-	Special effect (on top of all players) showin weather
;				0	no weather
;				1	rain
;				2   medium rain
;				3   heavy rain
;				7   light snow
;				8   medium snow
;				9   heavy snow
;
;-----------------
; PARTY <conditions>
;
; The PARTY command causes each client in the scene to evaluate the conditions (same as IF command conditions)
; and to leave the party if their conditions do not evaluate to TRUE.  Hence it defines what a legal party
; member should look like, and boots non-compliant clients from the party (but not from the scene)
;
; Generally this is intended to sever party members who do not deserve to follow the scene host to a new link, as
; in:
;
;    PARTY T23+T12
;    GOTO LINK 3, 4
;
; In this case, only clients who have tokens 23 and 12 will be allowed to stay in the party, and so when the 
; the party leader/scene host leaps to link (3,4) only those remaining party members go along.  The rest would,
; after the GOTO, be left sitting on the map when the scene expired.  I think.  I hope.  We'll see.
;
; Please note that unlike the IF command, these conditions are evaluated BY THE CLIENT (not by the scene server). 
;
; Another form of this command is EJECT
;
; The EJECT command is identical to PARTY only the people are also removed from the scene.  Remember
; the condion specifies the people who get to STAY in the scene and party.
;
;-----------------------
;  SET <cookieName>, <string>
;
; This command lets you store the string value into a 'cookie' of the specified name.  The cookie in question is
; only set for the scene host and is saved in their character's file.
;
; Later on, you can recover a cookie value by enclosing its name, like this:  #<cookieName>
;
; cookie names must not include spaces or punctuation marks.  Just letters and numbers.
;
; For example
;
;  SET favoriteColor, "blue"
;  1: Hello, %1, I see your favorite color is #<favoriteColor>
;
; The player will see:
;
;  "Hello, Bill, I see your favorite color is blue"
;
; The expansion of cookies is done BEFORE the evaluation of arguments, hence cookies called out inside of quoted
; strings will work... for example:
;
;  SET itemID, "15"
;  GIVE I#<itemID>
;
; In this case, the GIVE command will first be translated by substituting for the cookie, resulting in:
;
; GIVE I15
;
; Do not 'nest' cookies.  If you need to do something really weird, break it up into several steps.
;
; For more information about cookies, and a list of the current "Stock Cookies", please see the Quest Dictionary
; at http://www.synthetic-reality.com/wosquest.htm
;
;---------------------------
;
; ADD cookieName, <string>
;
; The string is evaluated as a number, the named cookie's contents are evaluated as a number, and the
; results are added together numerically and the sum is stored as the new value of the cookie.
;
; Math is performed as 'signed 32 bit integers' so watch out for underflow and overflow situations.  
;
; SET A, "15"
; ADD A, "22"
; 1: Jeepers, the sum is #<A>
;
; Should print: "Jeepers, the sum is 37"
;
; See SUB, MUL, and DIV commands for similar mathematical operations.
;
;-------------
; SUB cookieName, <string>
;
;  subtracts <string> value from cookie
;
;-------------
; MUL cookieName, <string>
;
; multiplies <string> value times cookie
;
;------------
; DIV cookieName, <string>
;
; Divides cookie by <string> (unless <string> evaluates to zero, then nothing happens)
; Note that 2/3 is 0, not 0.66666 since these are integer math operations.
;
;------------
; MODULUS cookieName, <string>
; MOD cookieName, <string>     <-- short form also accepted.
;
; Performs a modulus operation on the cookie.  (If you prefer, you can think of this as a
; 'remainder' function.
;
; You may not get the result you expect if cookie has a negative value to begin with.
; If <string> evaluates to 0, nothing happens.
;
;-----------------------------
; COMPARE  A,B  (with associated IFx commands)
;
;Fairly simple and brain damaged, I document by example:
;
;       COMPARE  A,B
;       IF=  @theyAreEqual
;       IF>  @AbiggerThanB
;       IF<  @AlessThanB
;
; The COMPARE command subtracts B from A and saves the result in a special place which doesn't get munged 
; until the next time you use the COMPARE command.
;
; The three IFx commands test that special result and jump to the label if the result was as indicated. 
; So your IFx command doesn't HAVE to immediately follow the COMPARE command, though I suspect it generally will.
;
; Arguments A and B are interpreted as signed decimal numbers.  For now you are stuck with constants and cookies.  
; So, you can do:
;
;        COMPARE  #<cookie>, "2"
;        COMPARE  #<cookie1>, #<cookie2>
;


+SCENES
;--------------
; SCENE 0 must be primary well of souls
;
; It is only used for switching souls (saved games), not for general resurrection and recharge
; Let's also use it as our own little tutorial for the new scenewriter (thank Merlin)
;
; First we need a 'SCENE' command to assign:
;  a scene number (zero), 
;  a BACKGROUND JPEG (temple.jpg),
;  the scene 'style' (WELL), 
;  the scene name "Well of Souls", 
;  the current EFFECT (2 =lake ripple),
;  and the current WEATHER (7 = snow)
;
SCENE 0		hood1, WELL, "DaHood", 2, 7

; Then we start a sound 'theme' (1=rippling stream)
	THEME	1

; Then we define ACTOR #1 (The Blind Sage) using frame 32 of the MONSTERS skin "joshMiscelleneous.bmp"
; The actor begins at location (0, 60) which is in the  bottom left of the screen
	ACTOR	1,	"Your Pops", peeps, 1, 0, 60

; Now we select actor 1 as the current actor
	SEL		1

; Now we set the POSE of the current actor (actor #1) using the 3-frame form.  This is 
; pretty boring since we use the same frame for all 3 choices (frame 32).  Normally you would
; use 3 different frames.  The game will automatically cycle between the first two frames
; with roughly equal probability.  The third frame will be used only briefly now and then (so
; it should be the "blinking eye" or "lashing tongue" or something else you only want to see now and
; then, while the first two frames would be the shifting between feet, or breathing, effect.
	POSE	32,32,32

; Now we start actor one walking towards (50,60) which is directly to the right of where he started.
; He will walk at a 'standard speed'
	MOVE	1,	50, 60

; Now we wait one second to let his motion be apparent to the player
	WAIT	1.0

; Now we have him talk.  Note the use of the ' command to make the chat bubble appear over the "Current" actor.
; I hardly ever do that anymore, since it is so easy to use "1:blah" instead.
	' Welcome to Da Hood kiddo.

; Now we have him move back to the left a bit.  The chat bubble is still over his head.  Since we waiting only
; one second after the first move command, we don't really know how far he made it before we changed direction.
; anyway, now he is moving "up" a little, relative to his previous destination.
	MOVE	1,	45, 60

; Now we have him deliver his second line of dialog, which replaces the previous chat bubble.  Usually chat bubbles
; pop automatically to make room for the next one, with each bubble remaining long enough to be read (so short
; sentences pop faster than long ones.
	' Im here to help you choose who you gonna be kiddo.

; And this actor is a bit fidgety, so he moves again.  Let's watch him move and chat.. move and chat for a bit.
	MOVE	1,	30, 70
	' When you get yo crap ready, make up yo mind on who you wanna be in this peice.
	MOVE	1,	40, 75
	' Yeah I knows dat I owes yo momma child support, well...
	' ...my broke self cant pay, you got a doller?
	MOVE	1,	25, 70
	' Anyway, being somebody in dis place has its advantages and disadvantages. I be pimp myself.
	MOVE	1,	35, 65
	' But you may not wanna live life like yer old pops.
	MOVE	1,	30, 70
	' BTW press dat MAP button if you wanna activate your GPS system, i ripped it off one of my hoes.
	MOVE	1,	40, 77
	' Like i wuz sayin earlier befow my head got all different, you can be whateva yous wanna be kiddo.
	MOVE	1,	20, 70
	' But yer old pops will always let you hang here in his crib.

; OK, he finally shut up.  We don't have anything else to accomplish in this scene, so we need to end it using the
; END command.  It ends the scene.
END

; Tada, a scene!  Please note that some player actions are blocked until the scene finishes.  For example, you can't
; cast a spell, use a weapon, or toss an item until the scene finishes.

;--------------
; SCENE 1 must be primary CAMP scene
;
SCENE 1, hood6
	THEME
;	MUSIC   (no music in camp scene, just theme)

; Check is this is a PK Attack (uses CAMP scene, not FIGHT scene, oddly enough)

	COMPARE #<num.isPKAttack>, 1
	IF= @pk
	COMPARE #<num.isPKAttack>, 2
	IF= @pk	

; Not a PK Attack, check if it is in Macguyver castle

	COMPARE #<num.mapNum>, 2
	IF=	@inCastle

; Not Macguyver castle, so we're done.  It's just a regular camp with no special stuff

	END

;
; It *is* a PK Attack, so we set up some special rules to make it 'honorable'
;
@pk
	; Set map flags: 32768 (no nasty spells) + 8192 (no tickets) + 4096 (no Heal)
	FLAGS	45056

	; Lock the room
	LOCK 1
	ACTOR 1, "PK Thug", gang2, 2, 50, 50
	1:PK DAT STUFF SUCKA!

	; Announce to the players that this is a special place
	N: PK Fight! 
	N: Locked Camp! No Excuses!
	N: No Hacking, if you can LT a Ticket go for it!

	; we have to END or they can't fight
	END

@eventPkAttackDone

	; maybe someday this event will work, and we can unlock the camp as soon as 
	; only one side is left standing

	LOCK 0
	FLAGS 0
	END


; We *are* in macguyver castle, so we have the little lock icon in the upper right,
; and can manually lock/unlock the camp.. to discusss our secret plans!
;
@inCastle
	; we get a little lock icon while in macguyver castle camps.
	SET sceneLock, 0
	ACTOR	9, "Lock", danNoFloat, 6, 95, 10
END

; The scene host has clicked on the little lock icon

@eventActorClick9
	COMPARE #<sceneLock>, 0
	IF= @lockScene
	LOCK 0
	SET sceneLock, 0
	SEL 9
	POSE	6
    WAIT 3.0
	END
@lockScene
	LOCK 1
	SET sceneLock, 1
	SEL 9
	POSE	5 
    WAIT 3.0
	END

;--------------
; SCENE 2 must be primary FIGHT scene (for automatic fights)
;
SCENE 2, hood3
	THEME  0
	MUSIC  fight.mid

	FIGHT

END

;--------------
; SCENE 3 (this is the evergreen starting scene on the main map, where you can return to be healed)
;
SCENE 3		hood1
	THEME	0
;	MUSIC	dahood.mid
	ACTOR	1,	"Yo Pops", peeps, 0, 25, 90
	POSE	5, 5, 13
	SEL		1
	MOVE	1,	15, 80

	IF T1, @continue
	' Welcome to da motel sucka! take a load off!
	' So looks like you gotta job now and have decided who you gonna be...
	' You got a doller, so i can get some malt liquor? (type YES or NO)
	ASK 30
	IF -YES, @saidNo
	' Word up? Aight! thanks kiddo, you ole pops needs his cough syrup ya know!
	' Yo if you need watches or cheap stuff like that yer old pops got some stuff!
    ' Hell no you cant HAVE it! But you can buy it from your pops!
	GIVE T1
	GOTO @continue


@saidNo
	' Den get out mah place sucka! go backs to yo momma!
	' You aint neva gonna survive Da Hood sucka!
	' Get da heck out!
	MOVE	1, -30, 80
	END

@continue
	IF ALIVE, @skip1
	' Yo dawg you got busted up! Lemme fix dat stuff!
	WAIT    4.0
	SOUND	"zap.wav"
	WAIT	1.0
	IF T1+T2, @SkipQuest
	IF T1-T2, @questy


@skip1
	MOVE	1,	10, 75
	GIVE	H3000
	GIVE	M3000 
	IF I99+T1-T2,@skipTicket
	GIVE	I99				; give him a ticket home


@skipTicket
	; offer EVERYTHING under level 10
	OFFER2	0,10
	' Heya kiddo!
	' Yo self can always chill here in my crib dawg! 
    IF T1+T2, @skipQuest
	IF T1-T2, @questy



@questy
	1: Yo, %1, Yo momma wants dat stoopit child support, take that junk to her. 
	1: maybe she will STFU fo once.
	1: And I aint fixin you up till you do it!
	END

@skipQuest
	GIVE L1
	GIVE L3000
	GIVE M3000
	' Why da heck you still here?
	END
	


END





;--------------
; SCENE 4 Momma
;
SCENE 4		hood6
	THEME	0
	MUSIC	mom.mid
	ACTOR	1,	"Momma", hook1, 2, 25, 90
	SEL		1
	MOVE	1,	15, 80
	1: hey baby! yo momma luvs ya.
	IF T1-T2, @dadpay
	IF T1+T2, @continue
	END

@dadpay
	1: Yo stank daddy pay yo child support yet!?
	H: chyeah momma he done payed.
	1: Well whaddya know, the ole scoundrel payed!
	1: Maybe he has changed his pimp ways!
	1: Maybe we kin get backs wif one anudder baby!
	H: momma you sho is crazy.
	H: Pops jus wannet you to shut you self up!
	GIVE T2
	1:here baby, i got you dat doo rag you wanted.
	1:You should be able to go into gang territory now, down deep in Da Hood.
    GOTO @continue
	END

@continue
	IF ALIVE, @last
	1: Oh no! somebody dun hurt mah baby!
	1:momma take care o ya dun worry bout a thang.
	GOTO @last
	END

@last	
	WAIT 3.0
	GIVE L1
	GIVE H5000
	GIVE L5000
	WAIT 1.0
	OFFER2 10,20
	1: You got so big on me baby! I remember...
	END

END




;---------
; general armor shop

SCENE 5 hood4
	THEME	0
	MUSIC	rap.mid
	ACTOR	1,	"G Skillet", gang1, 17, 25, 90
	SEL		1
	MOVE	1,	15, 80
	IF T2, @goahead

	1: Who be you sucka?
	H: I...uh...
	1: Yo self on our turf dawg. Break yo self!
	FIGHT 8,11,8,11
	1: Get out this peice sucka!
	GOTO, @leave1
	END

@goahead
	1: Yo dawgs dis boy one of us!
	1: shoot son go right on ahead!
	GOTO LINK 0, 5
	END

@leave1
	GOTO LINK 0, 4
	END
	
END

;---------
; BGPawn levels 15-25

SCENE 6 hood6
	THEME	0
	MUSIC	pawn.mid
	ACTOR	1,	"Pawn Shop Owner", rock1, 9, 25, 90
	POSE	9,10
	SEL		1
	MOVE	1,	15, 80
	OFFER2	15,25
	' Welcome to BallGround Pawn Shop
END

;---------
; Thrift Store offers 25-45

SCENE 7 hood6
	THEME	0
	MUSIC	pawn.mid
	ACTOR	1,	"Thrift Store Owner", rock2, 24, 25, 90
	POSE	24,25
	SEL		1
	MOVE	1,	15, 80
	OFFER2	25,45
	' You gonna buy somethin? you gonna sell something?
	' Make up yo mind.
END


;---------
; Mugging scene
;
SCENE 8 mugging
	THEME	0
	MUSIC	pawn.mid
	ACTOR	1,	"Some Kid", thug1, 9, 25, 90
	ACTOR	2, "Mugger", gang2, 24, 25, 90
	POSE	1,2
	SEL		1
	MOVE	1,	15, 80
	IF T2-T4+ALIVE, @scene
	IF T4, @wins
	IF T2-T4+DEAD, @dead
	END

@wins
	1: Ha ha!
	2: STFU!
	WAIT 5.0
	END

@scene
	1:Mister you gotta help me!
	2:Hand over yo money SUCKA!
	1: You gonna help me or not?! (Type YES or NO)
	ASK 30
	IF -YES, @sayno
	MUSIC fight.mid
	2: So you thinks you a match for me an da homies?!
	H: Yeah fool, bring dat stuff I'll own you fools.
	2: Yo homies whoop dis sucka!
	FIGHT 12, 13
	GOTO, @fightend
	END

@fightend
	IF ALIVE, @alive
	MUSIC pawn.mid
	2: Take dis fools money sucka!
	TAKE G1000
	1: Thanks for..OUCH...Trying...OUCH...mister...OUCH...you suck!
	WAIT 3.0
	IF DEAD, @dead
	END

@sayno
	2: Dats right, let me do my bidniss, an you go on doin yo bidness.
	END

@alive
	MUSIC mom.mid
	2: Mah homies!!!! NOOOOOOO!!!!
	1: Thanks mister! here take dis Ticket to da 25 cent rap concert!
	1: Its the least I can do!
	WAIT 2.0
	GIVE T4
	END

@dead
	GOTO LINK 2,3
	END

END

;---------
; Rap Concert
;
SCENE 9 hood1
	THEME	0
	MUSIC	dahood.mid
	ACTOR	1,	"25 Cent", gang2, 11, 25, 90
	POSE	1
	SEL		1
	MOVE	1,	15, 80
	IF T4-T5+ALIVE, @hasTickets
	IF DEAD-T4, @noticket
	IF ALIVE-T4, @noticket
	IF T4+T5-T11+ALIVE, @returned
	IF T4+T5-T11-DEAD, @redead
	IF T4+T5+T11-T28, @reward
	IF T4+T5+T11+T28+ALIVE, @returned
	IF T4+T5+T11+T28+DEAD, @redead
	IF T4+T5+T12, @betray
@noticket
	1:Sucka you cants be comin in da concert wif out tickets dawg!
	1:Get out!
	1:Fool!
	WAIT 3.0
	GOTO LINK 1,1

@hasTickets
	MUSIC rap.mid
	MOVE 1, 50, 60
	POSE 1,2
	1: *sings* I bust caps while I raps! Den I shoot craps!
	1: *sings* But it makes me tired so den i takes some naps!
	1: *sings* I chill wif dah homies out here in da hood!
	1: *sings* An everybody knows dat its all good!
	1: *sings* so if yo out here and you aint a nerd...
	1: *sings* throw a finga in da air an sing deez words!
	H: *chorus* I wish hoes came in jugs!
	1: *sings* what? what? what? what? jeah!
	H: *chorus* Ide share da jug 'a' hoes wif mah thugs!
	1: *sings* Jeah sucka!
	MOVE 1, 30, 30
	1: phew, dawg dat was tight, I love doin concerts in da hood!
	H: Dat show was da bomb!
	1: thanks dawg! 
	1: Oh snap! Dem rowdy fans! they tryin to gets a peice of me!
	1: dawg you gotta help me!
	FIGHT 30, 31, 30, 31, -32
	IF WIN, @live
	1: NAW SUCKA!!! HEEEELPPPP!!!!!
	1: Shoot Now I cant perform!
	END

@live
	1: Thanks dawg, you saved dis rapper from those crazies!
	1: Here, I was gonna go yachting later...
	1: But I tinks you should have deez new kicks I bought for da boat I bought.
	1: they be tight fo sho, you can be boating in mah yacht.
	1: It aint no dinghy, it aint no thingy!
	GIVE I700
	GIVE T5
	WAIT 3.0
	1: Thanks again dawg! we be tight fo life!
	WAIT 2.0
	END

@redead
	GIVE L1
	GIVE H5000
	GIVE M5000
	1: Rest up here sucka, I owes you one anyway.
	WAIT 3.0
	GOTO @returned
	END

@returned
	1: Nice ta see ya again dawg!
	END

@reward
	1: Yo dawg! Mah boy! Mah homie! I owe you big time!
	1: Mah Lawyer just called, told me you got dem pictures!
	1: Shoot son! Lemme get you sumptin!
	GIVE G1000000
	1: Here take dis cash fo yo trouble.
	1: And let me getcha one other thang...jus cause you still mah boy
	1: lets see....are you a POLITICIAN, or something ELSE?
	GOTO @ask
	END

@ask
	ASK 60
	IF QPolitician, @law
	IF QElse, @else
	1: So is you a POLITICIAN or somethign ELSE?
	GOTO @ask
	END

@law
	1: I figured you prolly were, here you might find dis thing useful!
	GIVE I570
	GIVE T28
	1:Thanks again dawg!
	GOTO @redead
	END

@else
	1: Aight I gots just da thang fo ya!
	GIVE I270
	GIVE T28
	1: Take dis shirt I wore it during my last concert!
	1: It might be valuable someday!
	GOTO @redead
	END

@betray
	1: How could you give the pictures to "him" dawg!?
	1: I thought you wuz mah homie.
	1: Aight aight, he threatened to kill you...
	1: look dawg I forgive ya...
	1: but I dont wanna see you no more.
	END

END



;---------
; Quest 1, The Fire Boots


SCENE 10 hood2

	ACTOR	1,	"Sho Nuff da Hood Shogun",		pimp2, 1, 50, 50
	POSE	1,26
	MUSIC dead.mid
	SEL		1
	
	1: So You are Probably wondering...
	1: What are the rules for PKing in DaHood?
	1: And other stuff like dat.
	1: Well since I run da Hood...
	1: I can tell you what dey be!
	GOTO @rules

@rules
	

	ACTOR 2, "PK", 	"butpk", 1, 40, 99
	ACTOR 3, "QNA", 	"butqa", 1, 30, 79
	ACTOR 4, "HINTS", 	"buthint", 1, 20, 59
	ACTOR 5, "PROPS", 	"butso", 1, 10, 39

	1: Type PK if you wanna know whats acceptable to do here in da hood.
	1: Type QNA if you wanna know more about da Hood.
	1: Type HINTS of yo stupid self is having problems.
	1: Type PROPS to see who helped out wif da hood, or to see if yo name on da list.

@choose
	1: Type what you wanna know about.
	ASK 60
	IF QPK, @pk
	IF QQNA, @qna
	IF QHINTS, @hints
	IF QPROPS, @props

	1: Okay illiterate fool, i said type "PK," "QNA," "HINTS," or "PROPS."
	GOTO @choose

@pk
	1: Okay you wanna know about PKing in daHood.
	1: Well unlike those wimpy suburbian places you have PKed in...
	1: Da Hood is far more hardcore about it...
	1: In DaHood "Teaming" "Snerting" "Rez-Killing" "Confusing"...
	1: Dat stuff is all good here. Its da hood for cryin out loud!
	1: Of course an old fashioned duel is cool too, w/e your into.
	1: However, dont be thinking that Hacking is cool cause it aint!
	1: Cheating prolly not a good idea either, nobody likes a cheater.
	WAIT 2.0
	1: Now remember how I said dat teaming and stuff be cool here?
	1: well guess what, so is running.
	1: Dats right sucka you heard me!
	1: You wanna run? run den fool!
	1: Since the odds never be even here, sometimes you gots ta run!
	1: Especially to tick off somebody who be mackin on ya kool-aid!
	1: Sright!
	H: So why is snerting okay here?
	1: Did I say you could speak fool?
	1: But to answer yo question dat you axed...
	1: If you chose to be a PKer den it means you accepted all the consequences...
	1: ...that go along wit it fool!
	1: I hope dat answered yo dumb PKing questions.
	WAIT 2.0
	GOTO @choose
	END
	
@qna
	1: So you wanna know whats up wif da hood?
	1: Okay Ill tell ya.
	1: You chose what lifestyle or "class" you wanted to lead.
	1: now you gots to go through life in da hood as what you chose to be.
	1: It be all about choices in da hood.
	1: Sometimes though you aint gonna have no choice...
	1: In fact sometimes you might have to do things you dont wanna do?
	H: Isnt that a bit harsh?
	1: STFU FOOL!
	1: Lifes tough get a helmet sucka.
	1: Anywayz, You be finding all kinds of trouble here...
	1: Youll find dat even some peeps or "monsters" you find here...
	1: can fix dem selves up or "Heal" as you suburbian kids call it.
	H: Is this like other wussy worlds where there isnt a real ending to the story?
	1: Sucka! Who said a story got to end?
	1: But to answer da question you axed...
	1: Jeah fool dis world can in fact be beat.
	H: So if it can be beat is their like a final boss?
	1: Sucka who did I say runs da hood?!
	H: ..........
	1: Anyway, Youll also notice dat unlike some other places...
	1: they aint no shops here fo specific stuff.
	1: If you want something you best get yo self to a pawn shop or a thrift sto.
	1: Occassionally you might even find a convenience sto for stuff to refresh yo self wif.
	H: What about if I die?
	1: Okay now dat question actually made sense.
	1: Usually if you wanna rest up in da Hood, youll find aint nothin free.
	1: youll have do do somebody a favor along da way or you may know this...
	1: ...as a "quest", but jeah you has gots ta be doin favors if you be wantin...
	1: to fix yo self up...
	1: But it aint so hard at first, heck yo pops is easy to please.
	WAIT 2.0
	
	GOTO @choose
	END
@hints
	1: So yo lazy self cant figure out how it be in da hood yet?
	1: aight here be some pointers den...
	1: but dey gonna be vague so dat maybe youll actually do SOME work around here.
	1: but deez is only to help you get started.
	1: neva say I aint never done nuttin for you.
	1: Yo Momma live in Ball Ground.
	1: You gots to take da subway to go downtown fool.
	1: A gang runs da subway, you best find a way to get in good wif dem.
	1: Yo Momma loves you.
	1: Some kid gots tickets to da 25 cent Rap Concert.
	1: 25 cent MIGHT let you fix you self up at his concert.
	1: If you cant figure things out from here den you be outta luck son...
	1: Come correct!
	WAIT 2.0
	GOTO @choose
	END
@props
	1: Deez be some of da peeps who made Da Hood Possible...
	1: Or peeps dat helped wif da hood wanted to give a shout out at.
	H: DaHood skins were made by PISS ANT
	1: DaHood story written by PISS ANT and ITALIAN ICE
	H: DaHood Scripting done by PISS ANT and ITALIAN ICE
	1: DaHood pictures were sized scaled and acquired by PISS ANT
	H: Additional advice and counsel were provided by....
	1: Hesacon (you rock booooyyyy, thanks for the help)
	H: Sir MJ (Thanks for the bmp help)
	1: Kamikaze Illuminate (Thanks for the progress evaluations)
	H: Gemini (Helpful hints on the story)
	1: Marthol (kept me in supply of food during the creation)
	H: SHOUT OUTS go to:
	1: JHO, cause he smells funny and he pwnz j00.
	H: Trish aka Lethal Injection, cause she says HARRRR to me. ooooh baby.
	1: Styles, cause hes da man he just dont know it yet.
	H: Karsh, My mentor, my suboordinate, my friend, and sometimes my mush puff.
	1: Kud, for having the cajones to say the stuff nobody has the guts to, even if its wrong XD.
	H: Jif, cause he turned out okay after all.
	1: Tifa, cause your da man, or a man, nobody knows for sure except...
	H: RP, cause you know for sure about Tifa XD.
	1: Apoc aka Dan, cause you always had my back.
	H: Luna aka Lunatix, cause you always heard me out.
	1: F'Nok, cause your the most biased moderator ever and we wouldnt want it any other way XD.
	H: Uncle Dan, aka Dan Samuel, aka Samsyn. The Godfather. I knew it was you. You broke my heart.
	1: Assasins Tale, cause you always have my back, and even sometimes my front...ewe...
	H: Beaver, cause your nuggets of wisdom reek of awesomeness.
	1: Zizanovic aka Ziz, cauze you keep it real.
	H: Mang aka Mangudai of Rha, cauze your loyal to the end...even if to something I dont like. :)
	1: Hyshka, cause you make me laugh, and you steal my lunch money.
	H: Riff, cause you freakin rule.
	1: Can Not, cause i hate your avatar, your lucky I like you. XD
	H: Buff, for no reason what so ever. dont want anyone being left out.
	1: Rinn, also for no reason what so ever.
	H: Kon, for being my antithesis, my antagonist, my bizzaro Piss Ant, and my divorce attourney. XD
	1: Mr. Utsler, for gving me some good tunes to listen to while I made this.
	H: Tool, for using up my prepaid minutes.
	1: Diamond, for H4Xing my mom.
	H: PsYcOtIc, for the spam.
	1: PsYcOtIc, for the spam. ha ha.
	H: Holly, for not finding my nacho jokes funny. not even a giggle.
	1: Kanye, for being loyal to your homies.
	H: Jasper, for all the support.
	1: Faded, for trying against all odds. again. and again. and again....
	H: To everyone else I neglected to mention here.
	WAIT 4.0
	GOTO @choose
	END
@done
	MOVE	2, -30, 90
	MOVE	3, -30, 90
	MOVE	4, -30, 90
	MOVE	5, -30, 90

	END
	
END

;---------
SCENE 11 hood4
	ACTOR 1, "Willie The Pimp", pimp1, 1, 20, 50
	ACTOR 2, "Roxanne", grup1, 1, 10, 50
	ACTOR 3, "Ophelia", grup2, 1, 10, 99
	POSE 1,3,2
	SEL 1
	MUSIC underworld.mid
	IF T2-T5, @hasT2
	IF T2+T5, @hasT5
	IF T2+T6, @pimp
	IF T2+T8, @watch
	IF I822-T8, @hack

@hasT5
	1: So you want me to let mah ladies go!?
	1: Or you wants to kill me and run my bidniss fo yo self?
	1: Or you wanna come correct and use my services?
	1: All deeze lovely ladies can be yours fo jus thirty five doller sucka!
	1: Well whats it gonna be sucka? 
	1: "FREE" my ladies, or try to "KILL" me and keepem to yo self, or ladies "LOVE" you long time?
	ASK 60
	IF Qfree, @free
	IF Qkill, @kill
	IF Qlove, @love
@kill
	1: Ladies, kill this fool!
	2: you got it Willie!
	3: with pleasure!
	WAIT 2.0
	MOVE	1, -50,50
	MOVE	2, -50, 50
	MOVE	3,-50,50
	WAIT	6.0
	FIGHT	39,40
	IF	WIN	@heWon1
	MOVE	1, 20,60
	1: Dats right sucka and dont neva come back!

	END

@heWon1
	MOVE	1, 30,80
	GIVE	T6
	1: Fine sucka, take da ladies, I wanted to get out da bidniss anyhow.
	END
@free
	1: I see how it be! Break yo self! Fool!
	2: Please save us!
	3: He is mean to us!
	MOVE 1, -50, 50
	MOVE 2, -50, 50
	MOVE 3, -50, 50
	WAIT 6.0
	FIGHT 36
	IF WIN @heWon2
	MOVE 1, 20, 50
	1: Ha best come correct son an never play a playa!	
	END
	
@heWon2
	MOVE 2, 30,80
	MOVE 3, 20,60 
	WAIT 2.0
	2: You did it!
	3: You freed us!
	2: We dont have to be prostitutes anymore!
	3: It was a horrible decision anyway!
	2: We can go back to school and actually make something of ourselves!
	3: Here, take this watch...
	GIVE I822
	2: You have truly earned it.
	GIVE T8
	END
@hack
	1: Your a dirty hacker.
	2: You might as well stop playing.
	3: aint nothing gonna work for you now.
	GOTO LINK 0,0
	END
@love
	1: Aight den! 35 doller sucka!
	TAKE G3500
	2: Oh baby!
	3: Yeah thats what im talkin about!
	WAIT 3.0
	GOTO LINK 1,3
	END
@pimp
	1: Shoot Im leaving sucka!
	MOVE 1, -50, 50
	2: Honey you can rest up here anytime!
	3: we will heal you up right!
	2: Free of charge.
	3: We also got some stuff to sell if you be needin anything sugar.
	GIVE L1
	GIVE L3000
	GIVE M3000
	OFFER2 0,70
	END
@watch
	1: Shoot Im leaving sucka!
	MOVE 1, -50, 50
	2: Hi there!
	3: we were just studying for our college exams!
	2: Its nice to see you again!
	END
@hasT2
	1: So you one of da gang boys huh?
	2: We love dem gang boys.
	3: we sho do!
	1: STFU WOMAN!
	1: anyways I be offerin dem stuff, so i guess i should offer you stuff too.
	OFFER2 0,5
	END
END


;---------
SCENE 12 bglibrary
	ACTOR	1,	"Stephen McFarworthy",	Biz2,	22,	30,	85
	POSE	22,21
	SEL		1

	IF T5-T10, @ready
	IF ALIVE-T5, @notready
	IF DEAD-T5, @notready
	IF I100, @pics
	IF T5+T10-T12, @done
	IF T5+T10+T12, @bad
	IF T5+T13+T11, @fought
	IF T5+T13-T11, @fought2
	
@ready
	1: Hello!
	1: Say now, my client mentioned you might be stopping by!
	1: He infomrs me you two, oh how did he put it...
	1: ...ah yes , "got tight" after his attack at the concert.
	1: Well he is now suing the city you see for placing him in unsafe conditions.
	1: Yes I know, a "harcore rap thug" worrying about safe conditions....
	1: Anyway, for this case to be successful, there is something I need.
	1: And since Mr. Cent mentioned you two were "tight" he suggested you could...
	1: ...do this one last favor for him.
	1: Over in Ball Ground is a photographer...
	1: He was hired to take some pictures at the concert for the fan club newsletter of Mr.Cent.
	1: Unfortunately, The pictures of the violence that ensued at the concert...
	1: ...have made The City government none to happy, and they have no desire to allow those pictures to surface.
	1: Someone in power must be pulling some strings.
	1: Your objective is to get those pictures so we can win Mr. Cent his money.
	1: Im sure Mr. Cent would happily reward you.
	1: Go now.
	GIVE T10
	END

@notready
	1: Im sorry I cannot be disturbed right now.
	1: Im on the phone with a client.
	1: He is curious as to the security of his upcoming concert.
	END

@pics
	TAKE I100
	1: Wonderful!
	1: Mr. Cent should be most happy with these!
	1: Now we can win our lawsuit!
	1: And I can earn my 15 percent fee!
	1: I'de imagine Mr. Cent would like to thank you in person!
	1: Thanks again!
	GIVE T11
	END

@done
	1: Mr. Cent sends his thanks.
	END

@bad
	1: Do you have the pictures?
	1: You gave them to "him"?
	1: You idiot!
	1: I told you to give them back to ME!
	1: I dont think Mr. Cent will want to see you after this.
	1: Get out.
	END
@fought
	1: Someone tried to kill you for the photos?!
	1: Thats horrible!
	1: Well now I know just how "tight" you and Mr. Cent really are!
	GOTO @done

@fought2
	1: Someone else tried to get these from you?
	1: Well I am glad that you brought them here!
	1: You truly are loyal to your friends arent you?
	1: Mr. Cent will be most pleased.
	GOTO @pics

END


;---------
SCENE 13 hood5
	ACTOR	1,	"Scared Photographer",	photo1,	1,	40,	70
	POSE	1,3,2
	SEL		1
	
	IF T10-T11, @lawyer
	IF T10+I100, @done
	IF ALIVE-T10, @nope
	IF DEAD-T10, @nope
	IF T10+T11, @done
	
@nope
	1: Who A-a-a-a-are you?
	1: *gulp*
	1: Do you work for....him?
	1: AHHHHHHHHH!
	1: You scared me!
	1: No I wont take your picture!
	1: Pictures cause trouble!
	1: AHHHHHHHHH!
	1: I though "he" was here!
	1: AHHHHHHHHH!
	END

@lawyer
	1: AHHHHHHH!
	1: Oh its you again!
	1: Why are you looking at me like that?
	H: I need the concert pictures.
	1: AHHHHHHH!
	H: I will pay you for them if you like.
	1: AHHHHHHH!
	H: Or maybe we could...
	1: AHHHHHHH!
	1: You work for "Him" dont you!?!?!?
	H: I....
	1: Help Me! He has found me!
	FIGHT 23, 35, 37, 33, 29
	IF WIN, @wonit
	1: Tell "Him" that he will never find me!!
	1: AHHHHHHH!
	END

@wonit
	1: AHHHHHH!
	1: I suppose your gonna bust a cap in my head?
	H: Dude, I just want the pictures for my homeboy's lawyer.
	1: lawyer?
	H: yes, a lawyer.
	1: So....you dont work for "Him" then?
	H: if "He" isnt a lawyer then I dont work for "Him".
	1: Well why didnt you say so?
	1: Sure take the pictures!
	1: But remember you never saw me!
	1: AHHHHHHH!
	GIVE I100
	END

@done
	1:AHHHHHH!
END

	



;---------
SCENE 14 hood1
	ACTOR 1, "Unknown Person" , dude2, 1, 40, 70
	MUSIC Annoy.mid
	POSE 1,3,2
	SEL 1

	IF ALIVE-I100, @notyet
	IF DEAD-I100, @notyet
	IF I100, @offer
	IF T12, @donebad
	IF T13, @done1
	IF T11, @done2
	
@notyet
	1: Psst...hey you, come here.
	1: I need a favor.
	1: There is a certain person in da hood...
	1: ...he is having a concert in Nite Hood...
	1: And he has a lawyer working for him...
	1: The lawyer is in Da Burbs I think...
	1: Anyway...Theyre trying to get some photos...
	1: My employer, well "He" would be very happy...
	1: If you gave ME those photographs.
	1: If you value your life, you will give them to ME...
	1: Give them to the lawyer and....well...
	1: ...you might not live in da hood too long.
	1: Got it?
	END

@offer
	1: So it looks like you got the photographs my boss wanted.
	1: "He" would be very happy if you gave them to me...
	1: NOW!
	1: So you gonna give me those photos? (YES or NO)
	GOTO @offer2

@offer2
	ASK 60
	IF Qyes, @yes
	IF Qno, @no
	1: So you gonna give me those photos or what? (YES or NO)
	END

@yes
	TAKE I100
	1: You just made "him" a very happy man.
	1: And saved "him" alot of money.
	1: And saved your self from a thorough whipping.
	1: Here is some cash for your trouble...
	GIVE G100000
	GIVE T12
	1: Now get out of here.
	END

@no
	1: Big mistake.
	1: YO GUYS KILL THIS IDIOT!
	FIGHT 28, 27, 42, 41
	IF WIN, @win
	1: I think I have made my point, come back if you change your mind.
	END

@win
	1: Okay okay okay!
	1: keep your stupid pictures!
	1: Eventually, "He" will deal with you personally.
	GIVE T13
	END

@done1
	1: Dont touch me! Im special!
	END

@done2
	1: You gave the pictures to the lawyer?!
	1: You moron!
	1: Why would you do that!?
	H: 25 cent be mah dawg sucka! kiss my hind side sucka!
	1: Grrrrr...
	1: You just made a...
	GOTO @no
	
END

;---------
SCENE 15 hood4
	THEME	1
	ACTOR	1,	"Biff",		guy1,	1,	40,	90
	MUSIC underworld.mid
	SEL 1
	IF T14-T15-T16, @wait
	IF T14+T15-T16, @fake
	IF T14+T16-T18, @done
	IF T14+T16+T18, @respect
	
	1: Words been spreading about you in da hood.
	1: They say you are gonna try to make a name for yo self.
	1: Well I might help you out...
	1: But you gotta do sumptin fo me sucka.
	1: There be dis pawn shop over in da burbs...
	1: An the dude who runs it is holdin a package for me...
	1: Now I dun payed for it but the sucka still aint validatin mah ticket right?
	H: Get to the point fool.
	1: Go to the pawn shop in da burbs and get mah package.
	GIVE T14
	END
@wait
	1: You get mah package yet?
	END

@fake
	1: So he sold you my package?
	1: well lets see it!
	WAIT 2.0
	1: This aint my package!
	1: What am I supposed to do with a pair of old musty ragged out shoes?
	1: Take these shoes and shove them up your hind end fool!
	1: Now go and get my REAL package from that fool!
	GIVE T17
	GIVE I702
	END

@done
	1: So you whooped up on him and his crew?
	1: Man I wish I coulda seen dat stuff dude!
	1: So You get mah package?
	H: Yeah fool, here it is....
	1: Word?! Tight! Yeah sucka dis be mah package!
	1: Yo dawg I cant be thankin you enough! 
	1: Ima spread da word dat there be a new big dawg in da hood!
	1: You gots da respect of alot peeps in da hood now!
	GIVE T18
	END

@respect
	1: Hey homie!
	1: You can chill at my place anytime!
	IF DEAD, @dead
	IF ALIVE, @alive
	END

@dead
	1: Yo you look busted up lemme get ya sumptin to fix dat...
	GIVE L1
	WAIT 3.0
	IF ALIVE, @alive
	END

@alive
	1: Now take a load off and chill out a while dawg.
	GIVE L5000
	GIVE M5000
	END

END
;---------
SCENE 16 hood4
	THEME	1
	MUSIC	annoy.mid
	ACTOR	1, "Burbs Pawn Shop Owner", dude1, 1, 40, 40
	SEL 1
	IF T14-T15-T16-T17, @package
	IF T14+T17, @take
	IF T14+T16, @done
	OFFER2 45, 75

	1: You see somethin you want dude?
	END

@package
	1: So Biff sent you to get his package?
	H: Dat be correct.
	1: Well he aint paid for the ticket on it yet.
	H: Biff said he paid you.
	1: You are right he did pay me.
	1: But he didnt pay me for the ticket.
	1: He paid me for the right to pay for the ticket.
	1: Get it?
	H: In other words you took his money and have no intention of givin him his package.
	1: Glad we understand each other.
	H: Perhaps I could buy the package then?
	1: Perhaps.
	H: *Thinking to self* Should I "BUY" the package	 or just Bust this fool up and "TAKE" the package?
	ASK 60
	IF Qbuy, @buy
	IF Qtake, @take
	END

@buy
	IF G>10000, @gold
	IF G<10000, @broke
	IF G=10000, @gold
	END

@gold
	1: Fine here is the package I was holding for Biff, ha ha ha.
	GIVE T15
	TAKE G10000
	END

@broke
	1: Yo broke self cant afford nuthin sucka!
	1: Get out mah shop if you aint got no cash!
	H: I may be ugly but at least I aint got any money!
	1: You got a PhD?
	1: Yeah fool, a Playa Haters Degree!
	H: A PhD aint gonna get you nothin round da hood now get out!
	END

@take
	H: I guess I will just have to bust a cap in yo face and TAKE that package.
	1: Good luck fool my boys in da back will mess you up but good.
	MOVE 1, -50, 50
	WAIT 3.0
	FIGHT 29, 29, 29, 29
	IF WIN, @real
	MOVE 1, 50, 50
	1: Tell Biff he can expect the same if he ever shows up here again!
	END

@real
	MOVE 1, 50, 50
	1: Fine!!! I get it!!! Just stop messing up my store!!!
	1: Here is the package Biff wanted!
	GIVE T16
	GOTO @done
	END

@done
	1: Jeez sucka, you be tougher than you look!
	1: The least you can do is buy something!
	OFFER2, 45, 75
	END	

END
;---------
SCENE 17 hood1
	ACTOR 1, "Jamel", dealer2, 1, 20, 50
	ACTOR 2, "Roxy", grup2, 1, 10, 50
	ACTOR 3, "Lucille", grup2, 1, 10, 99
	POSE 1, 3, 2
	POSE 2, 3, 2
	POSE 3, 3, 2
	SEL 1
	IF T18-T19, @respect
	IF T18+T19, @done

	1: Get outta here busta!
	2: Who da heck is dis clown?
	3: Lookin like some fool to me!
	H: Why you gotta be hatin like dat?
	1: Fool if you want respect in da hood you has to earn it!
	2: Jeah fool, and rights now....
	3: You aint gots any!
	END

@respect
	1: Oh snap! Whut up dawg!
	2: Biff told us what you did for him!
	3: Staright up jacked that pawn shop fool!
	1: And he said you be gettin his package for him!
	2: Well if Biff says you tight...
	3: Then you be tight wif us dawg!
	1: We be sorry bout hatin on you earlier an all...
	2: Here take dis nice pair of alligator shoes sugar!
	3: You be lookin FINE in them!
	1: Ide imagine yo self could go far in a pair of kicks like those!
	GIVE I705
	GIVE T19
	END

@done
	1: What up dawg!
	2: Hey there you fine thang you!
	3: What be going on sugar?
	END
END
;---------
SCENE 18 hood5
	MUSIC class.mid
	ACTOR 1, "Flip Side Gangsta", posse2, 1, 20, 50
	SEL 1
	IF T18+T19-T20, @respect1
	IF T20-T19, @respect2
	IF T20+T19+T24, @bidniss
	IF DEAD, @dead

	
	H: Who are you?
	1: I be da leader of da Flip Siders sucka!
	1: Most our bidniss be in dealing on da underground market...
	1: Most deez items we got are da finest quality merchandise sucka!
	1: But we only deal wif real G's sucka...
	1: And you aint no G.
	1: And more den dat...
	1: You be on my turf boy!
	1: But since you obviousley not be from round here...
	1: I let you decide whether you gonna run, or if you gonna die.
	1: So you gonna "RUN" or you wanna "DIE" punk?
	ASK 60
	IF Qrun, @run
	IF Qdie, @die
	END

@run
	1: Yeah sucka, dat be what I thought, get yo self outta Flip Side turf!
	END

@die
	1: Oh so you thinkin you can take on da Flip Side Posse?
	1: Okay Sucka bring dat stuff!
	MOVE 1, -50, 50
	WAIT 3.0
	FIGHT 44, 43, 24, 35
	IF WIN, @round2
	MOVE 1, 30, 80
	1: Yeah fool, break yo self!
	END

@round2
	FIGHT 19, 45, 48, 20
	IF WIN, @won1
	MOVE 1, 30, 80
	1: Yeah fool, break yo self!
	END

@won1
	MOVE 1, 30, 80
	1: Aight sucka!
	1: You really is a bad mutha sucka!
	1: You gots da respect of da Flip Side crew.
	1: You come back if you ever make it in da hood...
	1: And you and us can get down to...bidniss...
	GIVE T20
	END

@respect1
	1: So you got da respect of da 14th street crew?
	1: Well that dont mean squat round here!
	1: Da Flip Siders been whoopin up on those 14th street haters fo years dawg.
	1: And if you bee down wif them then you be GOING down wif them!
	1: You want the respect of da Flip Side crew you better earn it sucka!
	1: You wanna earn our respect or not fool?! (YES or NO)
	ASK 60
	IF Qyes, @die
	IF Qno, @run
	END

@respect2
	1: If you be wantin some bidniss, then you best have more then just the Flip Side crews respect.
	1: If I hear about you makin somethin of yo self then we will make sure you get what you deserve.
	1: Aight?
	END

@bidniss
	1: Oh snap dawg! I heard every gang in town has got yo back!
	1: Well sucka, only a real G could pull dat off in da hood!
	1: Now we can be doing some bidniss wif you dawg!
	OFFER 180, 181, 182, 183, 184, 185, 186, 187, 188, 189, 190, 191, 192, 193
	1: Anyways, buy whatever you need!
	1: I cant beleive you got da backing of everybody in da hood!
	1: Maybe you can finally get rid of "him" !
	GIVE T26
	END

@dead
	1: Holy snap!
	1: Yo guys look at this dead fool!
	1: ha ha ha ha! Get outta here dawg!
	END


END



;---------
;
; Smell my finger.
;
SCENE 19 bglibrary
	MUSIC class.mid
	ACTOR	1,	"J. King, Attourney at Law",  biz3, 1, 25, 80
	SEL 1
	IF T11-T22-T23, @lawyer
	IF T12-T22-T23, @crime
	IF T11+T22, @done
	IF T12+T22, @done
	IF T11+T23, @done
	IF T12+T23, @done
	IF T11+T23+T24, @go
	IF T12+T23+T24, @go
	IF T11+T22+T24, @go
	IF T12+T22+T24, @go	

	1: I am James King, the foremost attourney in Da Hood.
	1: I do legal consulting for just about every Law Firm in Da Hood.
	1: If you beleive in upholding the law...
	1: Then you must aid those who also try to uphold the law.
	1: Sometimes the law supports the most unlikely people.
	1: And sometimes those who make the law, break the law.
	1: For example, a musician of somekind might deserve the support of the law...
	1: And someone who is at the pinnacle of power, could be breaking every law he makes.
	1: like "him" for example...
	H: Who is this "him" I keep hearing about?
	1: The man who runs Da Hood.
	1: "he" seized power in Da Hood and runs the whole thing.
	1: He made every law there is in da hood.
	1: and he breaks every law there is in da hood.
	1: It doesnt matter what the laws are, it matters if citizens are protected by the law.
	1: And it matters if people follow the law.
	1: Im not so sure if you trully support the law or not.
	1: Come back when your ready to prove your support of the law.
	END

@crime
	1: You sabotaged 25 Cents lawyers case!
	1: You Are truly a criminal!
	1: Prepare to feel the long arm of the law!
	1: The hammer of justice crushes you!
	MOVE 1, -50, 50
	FIGHT 16, 15, 28
	IF WIN, @round2
	MOVE 1, 30, 80
	1: Justice has been served.
	END

@round2
	MOVE 1, 30, 80
	1: Very well, it appears you have earned a chance to prove yourself worthy
	1: Perform a civic duty and be a service to Da Hood instead of the hinderance you have been...
	1: And you will have the respect of Da Hood Law Practitioners Organization.
	H: So what do I gotta do, and make it quick doofus.
	GOTO @task
	END

@lawyer
	1: So it appears you helped Stephen McFarworthy with his clients case.
	H: Who?
	1: Your friend 25 Cents lawyer. You helped him correct?
	H: Yeah, what about it?
	1: I think you may have what it takes to be a true beleiver in the law.
	1: You must perform a civic duty however to prove your true support of the law.
	H: What do you need me to do?
	GOTO @task
	END

@task
	1: There is a convict over at Da Hood Jail.
	1: This person has been convicted of stealing food from a local convenience store.
	1: The Law states that the sentence for stealing in da hood of you are caught...
	1: Is death.
	1: Unfortunately no one is willing to perform the execution.
	1: Go over to the jail and perform the execution.
	1: By doing so you will receive a form of civic duty from the police chief.
	1: bring that document to me and you will proven yourself to be a true supporter of the law.
	1: And you will have the backing of Da Hood Law Practitioners Organization.
	1: Here, take this Lawyers badge, so that the police will allow you to perform your task.
	GIVE T21
	1: Now go.
	END

@done
	1: I see you have performed your civic duty!
	1: This is very encouraging!
	1: Very well!
	1: You officially have the backing of Da Hood Law Practitioners Organization!
	1: And more importantly you have the respect of the finest organization in DaHood.
	GIVE T24
	END

@go
	1: Nice of you to visit!
	1: The Law thanks you.
	END

END

;-------------------------
;2 in the pink 1 in the stink woohoo.

SCENE 20 jailcell
	MUSIC dahood.mid
	ACTOR 1, "Police Chief", cop1, 1, 30, 40
	ACTOR 2, "Convict", grup1, 1, 10, 60
	SEL 1
	IF T21-T22-T23, @duty
	IF T21+T22, @done1
	IF T21+T23, @done2

	1: So you thought you would steal eh?
	2: But I had too!
	1: Sure thats what they all say!
	2: But its true!
	1: You know what the sentence is for stealing in Da Hood.
	2: No not that please!
	1: Just as soon as we find a volunteer to carry it out...
	1: Justice will be served!
	END

@duty
	1: So you're here to carry out the execution eh?
	H: So I have been told.
	1: Well here she is!
	2: Please sir! dont!
	H: And why shouldnt I?
	2: All I did was steal some food for my starving children at home!
	2: I couldnt let my babies die!
	1: Enough! Are you gonna do it or not!? (YES or NO)
	ASK 60
	IF Qyes, @kill
	IF Qno, @free
	END

@kill
	1: Excellent! hope your ready sweety!
	2: OH PLEASE NO!!!!
	H: Yeah time to die dirty theif!
	MOVE 2, 1, -50, 50
	FIGHT 30
	IF WIN, @civic
	1: You idiot! She is escaping! catch her boys!
	END

@civic
	1: Good Job! Here is your certificate of civic duty!
	1: Well done!
	GIVE T22
	END

@done1
	1: Looks like we got another shoplifter!
	2: Get yo stank hands offa me sucka!
	1: Heya there buddy! Your excecution earlier gave us all the confidence to do it for ourselves in the future!
	1: You are a real peice of work!
	END

@done2
	1: Please dont hurt me!
	2: Thank goodness for people like you sir!
	END

@free
	1: So you say youll do itm then decide not to eh?
	1: I call that obstruction of justice!
	1: Boys take this person to a nice comfy jail cell!
	1: And why not throw in a dose of brutality with it!
	FIGHT 5, 27, 33, 46, 47
	IF WIN, @wonit
	1: Ha ha ha! Enjoy your next 10 to 20 sucker!
	END

@wonit
	1: Oh its not over yet kid!
	1: Send in the night shift!
	FIGHT 46, 46, 47, 47
	IF WIN, @wonit2
	1: Ha ha ha!
	END

@wonit2
	1: Fine! Send it the convicts!
	FIGHT 48, 41, 36, 26
	IF WIN, @wonit3
	1: Ha ha ha!
	END

@wonit3
	1: Amazing!
	1: No no no! Dont hurt me!
	H: Let her go and give me that stupid civic duty paper, NOW.
	1: Fine fine fine!
	1: Here take it!
	GIVE T23
	2: Thank you sir!
	END
	
;----------------------

SCENE 21 hood1
	MUSIC mom.mid
	ACTOR 1, "Poor Starving Kid", thug1, 1, 40, 40
	ACTOR 2, "Cold Lonely Kid", thug2, 1, 50, 60
	SEL 1
	IF T23, @choice
	IF T23+T25, @over

	1: I miss mommy!
	2: Where is mommy?
	1: She went to get us some food.
	2: I am soooo hungry....
	1: WAAAAAHHHHH MOMMY!!!!!!
	END

@choice
	ACTOR 3, "Poor Mother", grup1, 1, 30, 30
	3: Hi remember me? You saved my life at the jail!
	3: Now I can feed my babies!
	1: Mommy who is that?
	2: Yeah mommy who is that?
	3: A very nice person darlings.
	3: anyway here, please take this token of my gratitude...
	3: One is a shirt I knit just for you!
	1: Here! I want you to have something too!
	1: Its a hat that used to belong to my favorite rap artist!
	GIVE I271
	GIVE I223
	GIVE T25
	3: Thank you so much!
	END

@over
	1: Hello!
	2: Mommy is taking a shower right now.
	1: We will tell here you stopped by!
	END
	
END
;--------------------------------
SCENE 22, hood3
	ACTOR 1, "Security", Cop2, 1, 30, 30
	MUSIC dead.mid
	SEL 1
	IF T26-T27, @transfer
	IF T26+T27, @wongame
	IF DEAD, @dead

	1: Sorry, sir but "he" sees no one.
	1: No exceptions.
	1: Now scram!
	END

@transfer
	1: Oh wow! Its you!
	1: People are rioting everywhere!
	1: "he" is coming!
	1: Im getting out of here!
	MOVE 1, 1, -50, 50
	GOTO @him
	END

@him
	ACTOR 2, "Sho Nuff da Hood Shogun", pimp2, 1, 40, 40
	2: So you got da respect of everyone in da Hood.
	2: Big freakin deal.
	2: I run Da Hood in case yo dumb self forgot.
	2: I worked up from nuthin to get all dis power!
	2: Now Im da richest mack daddy dis side of the planet!
	2: Now dat you be knowin who I is...	
	2: You can do one of two things...
	2: You can Join me, and be my right hand man!
	2: Doesnt that sound nice?
	H: actually....
	2: FOOL SHUT UP I DIDNT SAY YOU COULD SPEAK!
	2: Anyway...
	2: Or option 2, You try to kill me *laughs* and be da man in Da Hood!
	2: HA HA HA HA like thatd ever happen!
	2: Whats it gonna be sucka!?
	H: *thinks to self* should I "KILL" him, or "JOIN" him?
	ASK 60
	IF Qjoin, @join
	IF Qkill, @kill
	END
	
@join
	2: So you do have some sense in you head after all!
	2: Well I have to say about dat stuff is...
	WAIT 2.0
	TAKE L1
	SOUND boom1.wav
	2: ...dat I just blew yo brains and all that sense outta yo head!
	2: ha ha ha ha! dumb fool!
	2: I run da hood!
	2: Sucka!
	END

@kill
	2: Aight den, yo dumbself just got a one way trip to a body bagfool!
	MOVE 2, -50, 50
	WAIT 3.0
	FIGHT 255
	IF WIN, @won1
	END

@won1
	MOVE 2, 30, 80
	2: Fine sucka, I aint no match fo you.
	2: Da Hood is yours.
	2: But just know dis sucka...
	2: They always gonna be some fool trying ta steal yo kool aid man.
	2: Good luck keeping Da Hood.
	2: Sucka!
	GIVE T27
	END

@dead
	1: You had better leave.
	END

@wongame
	1: You did it! You beat Sho Nuff! You have beaten DaHood!
	1: Great Job!
	1: Can I have your autograph?
	1: Please?
	END
END

 
;---------------------------------
; Here is the last line of the SCENES section of the quest file.
-SCENES



; Now we are at the extreme end of the file
;
; This took for freaking ever, it had better work.


