;***********************************************************************Rune Drives Quest*************************************************************************
;Last Scene Used=150
;Last Token Used=76
;***********************************************************************Entrance to Giant's Cradle*****************************************************************
SCENE 153 castle2
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
ACTOR 3, "Sealed Door", Doors, 2, 25, 90
ACTOR 4, "Tablet", joshMiscellaneous, 15, 45, 91
ACTOR 5, "Red Valice Slot", Misc, 3, 35, 80
ACTOR 6, "Blue Valice Slot", Misc, 3, 15, 80
IF I206+I207, @opd
1: This looks like the entrance!
2: What's that stone tablet?
H: Let me read it and see.
END
@eventActorClick4
IF T77, @valice
4: With the Red Valice on the right and the Blue Valice on the left, the world will be in peace.
4: Only when the world is in peace the door shall open.
1: Not ANOTHER puzzle!
H: It says something about a Red Valice and a Blue Valice.
H: I think if we can find them, then the Door will open.
2: But we have no idea where to look.
H: That could be a problem.
1: Why don't we ask Emma?
H: Good idea!
GIVE T77
END
@valice
4: With the Red Valice on the right and the Blue Valice on the left, the world will be in peace.
4: Only when the world is in peace the door shall open.
END
@eventActorClick3
IF T79+T80, @opd2
3: [The Door is Sealed]
END
@opd2
GOTO LINK 72, 0, 0
@opd
H: Now that we have the Blue Valice and the Red Valice, we can get in.
1: I guess we have to put them in those slots.
1: Let's see here.
1: Blue Valice on the left and Red Valice on the right.
H: Got it!
GIVE T78
END
@eventActorClick5
IF -T78, @nt
5: [The Red Valice has been put in place]
GIVE T79
END
@eventActorClick6
IF -T78, @nt
6: [The Blue Valice has been put in place]
GIVE T80
END
@nt
END
;*****************************************************************************Red Valice*****************************************************************************
SCENE 151 lavacave
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
IF I206, @e
WAIT 2.0sec
H: I never knew the Volcano was so big.
1: You've been here before?
H: Yes
H: I came here before when I found out about Lady Harken.
1: Oh
H: But this passage way just seemed to open up.
2: Interesting.
2: It is kinda hot in here.
1: You're telling me!
H: Let's just get the Red Valice and get out of here.
WAIT 3.0sec
SOUND "zThunder9.wav"
ACTOR 3, "Lady Harken", LadyHarken, 1, 25, 90
MUSIC "quarterknights.mid"
3: Ha ha ha!
1: Who are you?
H: That's Lady Harken.
3: That's right!
3: And don't you forget it.
3: Now, give me those items or else!
H: Never!
3: Fine..
3: I guess I will have to take them by force!
WAIT 2.0sec
MOVE 1, 0, 0, 1
MOVE 2, 0, 0, 1
MOVE 3, 0, 0, 1
MUSIC "Som2boss.mid"
FIGHT -2019, -2020, 2025
IF WON, @nextfight
@lhl
MOVE 3, 25, 90, 1
WAIT 2.0sec
3: Don't mess with the Metal Demons!!
SOUND "zThunder9.wav"
END
@nextfight
MUSIC "Som2boss.mid"
FIGHT 2026
IF WON, @blh
GOTO @lhl
@blh
H: Don't mess with us!
H: Let's go!
N: Recieved Red Valice!
GIVE I206
WAIT 3.0sec
GOTO SCENE 203
END
@e
END
;******************************************************************************Blue Valice**************************************************************************
SCENE 152 iceCave
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
IF I207, @e1
1: Brrr!!
1: I'm freezing!!
H: I had no idea that this cave would turn to ice.
2: We are down pretty deep.
1: [Shiver]
H: I think the Blue Valice might have something to do with it.
1: Speaking of which, I think we need to get it and LEAVE
1: Before I turn to a chunk of ice!
2: Yeah
WAIT 3.0sec
SOUND "zThunder9.wav"
ACTOR 3, "Belsek", josh16, 1, 25, 90
MUSIC "Boss3.mid"
3: I"m baaaaaaaack!!!
3: Mwahahaahaha!!!!!
1: What's with all the demons popping up?
H: They're the Metal Demons.
H: They are trying to suck all the energy out of the planet by reviving their queen.
3: You seem to know a little too much!
3: Now give me the items!
H: No
3: Grrr..
3: You've made me angry, and that's not a good thing!
WAIT 2.0sec
MOVE 1, 0, 0, 1
MOVE 2, 0, 0, 1
MOVE 3, 0, 0, 1
FIGHT -2019, -2020, 2027
IF WON, @bb
@lb
MOVE 3, 25, 90, 1
WAIT 1.0sec
3: Die SUCKAs!
END
@bb
MUSIC "Boss3.mid"
FIGHT 2028
IF WON, @bb2
GOTO @lb
@bb2
GIVE I207
H: Slimebag!
N: Recieved Blue Valice!
WAIT 3.0sec
GOTO SCENE 203
END
@e1
END
;*******************************************************************************First Rune Drive*********************************************************************
SCENE 155 castle2
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
IF I208, @ffrd
1: We made it!
H: The Rune Drive should be around here somewhere.
2: Hmm..
SOUND "zWater5.wav"
1: That didn't sound good.
2: We better watch our backs.
WAIT 1.0sec
SOUND "zWater5.wav"
MOVE 1, 0, 0, 1
MOVE 2, 0, 0, 1
MUSIC "luf2boss.mid"
FIGHT -2019, -2020, 2029
IF WON, @bwb
H: Dang!
END
@bwb
N: Aquired Rune Drive!
H: Let's see here.
H: It says something about a tower here.
H: I wonder where that is.
H: Hmm..
GIVE I208
GIVE T82
WAIT 2.0sec
GOTO SCENE 202
END
@ffrd
END
;*************************************************************************************Meet Jane**********************************************************************
SCENE 154 bgLibrary
THEME 0
MUSIC "calamityjane.mid"
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
IF T81, @jwu
ACTOR 3, "Jane", joshTownsfolk3, 31, 25, 90
3: Hello there!
3: My name is Jane.
3: You seem new around here.
3: What brings you to our town?
H: You wouldn't know of a tower around here, would you?
3: Actually
3: There is a tower not too far from here.
3: It's called the Epitah of the Sea Wind.
H: Could you show us where it's at?
3: Sure
3: I was going to go there to get treasure.
2: You're a treasure hunter too?
3: [Laughs]
3: You've never heard of the great Calamity Jane.
2: Errr.....no
3: .....well
3: Anways!
3: When are we leaving!?
N: Jane joins your party!
GIVE T81
END
@jwu
ACTOR 3, "Jane", joshTownsfolk4, 25, 68, 32
END
;**************************************************************************Epitah of the Sea Wind*******************************************************************
SCENE 156 bgLibrary
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
ACTOR 3, "Jane", joshTownsfolk4, 25, 68, 32
ACTOR 4, "Bookcase", Misc2, 1, 25, 90
ACTOR 5, "Bookcase", Misc2, 1, 15, 90
ACTOR 6, "Bed", Misc, 4, 35, 90
END
@eventActorClick4
4: _ e_ _ _  _ _ _ d
END
@eventActorClick5
5: _ _ t_ _  B_ _ _
END
@eventActorClick6
H: zzzz...
MUSIC "cc210.mid"
WAIT 5.0sec
GIVE L1
GIVE H10000
GIVE M10000
MUSIC ""
END
;******************************************************************************Bookshelves*************************************************************************
SCENE 157 bgLibrary
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
ACTOR 3, "Jane", joshTownsfolk4, 25, 68, 32
ACTOR 4, "Bookcase", Misc2, 1, 25, 90
ACTOR 5, "Bookcase", Misc2, 1, 15, 90
END
@eventActorClick4
4: M _ _ _ _  _ i _ _
END
@eventActorClick5
5: _ _ _ a _  _ _ r _
END
:******************************************************************************Bookshelves2***********************************************************************
SCENE 158 bgLibrary
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
ACTOR 3, "Jane", joshTownsfolk4, 25, 68, 32
ACTOR 4, "Bookcase", Misc2, 1, 25, 90
ACTOR 5, "Bookcase", Misc2, 1, 15, 90
END
@eventActorClick4
4: _ _ _ _ l  _ _ _ _
END
@eventActorClick5
5: And the parts of the book were scattered throughout.
END
;*****************************************************************************Password Door************************************************************************
SCENE 159 bgLibrary
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
ACTOR 3, "Jane", joshTownsfolk4, 25, 68, 32
ACTOR 4, "Bookcase", Misc2, 1, 25, 90
END
@eventActorClick4
IF T83, @nmn
4: Please enter Password.
ASK 50
IF QMetal^Bird, @yme
4: Incorrect!
END
@yme
4: Correct!
SOUND "zOpen1.wav"
GIVE T83
END
@nmn
END
:***************************************************************************Second Rune Drive*********************************************************************
SCENE 160 castle2
THEME 0
ACTOR 1, "Lilka", Lilka, 1, 88, 32
ACTOR 2, "Jack", Jack, 1, 76, 62
ACTOR 3, "Jane", joshTownsfolk4, 25, 68, 32
IF I209, @gbbf
IF T84, @bff
3: I can't believe I came all this way and there wasn't any treasure.
2: Really..
1: But look!
1: Isn't that the Rune Drive?
H: Let's get it and get out of here.
ACTOR 4, "Flash", josh94, 1, 25, 90
ACTOR 5, "Boomerang", josh35, 1, 35, 90
MUSIC "waflash.mid"
4: I can't let you do that.
1: Who are you?!
H: He must be a Metal Demon also.
4: Ha ha ha
4: That's where you are wrong.
1: What?
4: I do not work for the Metal Demons.
2: Then what are you doing here?
4: I am here to kill you.
1: That doesn't make any sense!
1: You are here to kill us, yet you don't even work for the Metal Demons.
1: I'm confused.
H: Look, we don't have time to mess with you right now.
H: So if you'll excuse us.
4: You're not leaving here alive!
4: Get them Boomerang!
GIVE T84
@bff
WAIT 2.0sec
MOVE 1, 0, 0, 1
MOVE 2, 0, 0, 1
MOVE 4, 0, 0, 1
MOVE 5, 0, 0, 1
FIGHT -2019, -2020, 2030
IF WON, @nbff
H: Damnit!
END
@nbff
MUSIC "waflash.mid"
FIGHT 2031
IF WON, @nff
END
@nff
MOVE 4, 25, 90, 1
WAIT 2.0sec
4: How could you have beaten Boomerang.
4: ....
4: No matter.
4: I will destroy you!
WAIT 2.0sec
MOVE 4, 0, 0, 1
MUSIC "waflash.mid"
FIGHT 2032
IF WON, @fnf
END
@fnf
MUSIC "waflash.mid"
FIGHT 2033
IF WON, @bbf
END
@bbf
MOVE 4, 25, 90, 1
MOVE 5, 35, 90, 1
WAIT 2.0sec
4: You are stronger than I thought.
4: Don't think you won't see me again!
WAIT 2.0sec
SOUND "zFlash1.wav"
MOVE 4, 0, 0, 1
MOVE 5, 0, 0, 1
H: The Rune Drive!
N: Found Rune Drive!
GIVE I209
GOTO SCENE 204
END
@gbbf
END
;End of Rune Drives quest.
;Last scene used=160
;Last Token used=84