;Quest 4- The Earth Temple

SCENE	40	Bedroom, SCENE, "The Green Dragon Inn"
ACTOR	1, "James", joshtownsfolk, 13, 17, 71
IF	DEAD, @Dead
@start
SET	GDInnPrice, 45
MUL	GDInnPrice, #<num.PeopleInScene>
1: One room for a party of #<num.PeopleInScene> is #<GDInnPrice> Septi.
1: Will you be staying with us tonight?
@Menu1
MENU	"Yes=@Yes", "No=@No", "Set as Save Point=@save"
GOTO	@Menu1
END
@No
1: Oh, that's too bad.
1: Please come again.
END
@Yes
IF	G#<GDInnPrice>, @Canafford
1: I'm sorry. You have insufficient funds to pay for your room.
1: Please come again.
END
@Canafford
TAKE	G#<GDInnPrice>
GIVE	L1
GIVE	H32000
GIVE	M32000
1: Thanks!
1: Please come again!
END
@Dead
1: You look a little under the weather, there.
1: Here you go!
GIVE	L1
N: Revived!
GOTO	@start
END
@save
N: Yew set as your current save point.
SET	SPID, 32
SET	SPlocation, "Yew"
SET	SPset, 1
END
;-----
SCENE 41	Forest2, SCENE, "Forest Clearing"
IF	T40, @Empty
ACTOR	1, "Thief Lancer", josh64, 1, 17, 71
1: You! Stop there!
1: You're passing into the territory of the Shadow Gang!
1: If you want to pass, it'll be all your money, or your life.
1: Which will YOU choose?
@Menu1
MENU "All my money=@money", "Life=@Life"
GOTO	@Menu1
END
@Money
COMPARE #<num.hostGP>, 1
IF< @Nomoney
1: Bwahahahaha! Thanks for the money, chump! Looks like I'm getting #<num.hostGP> Septi out of the deal!
TAKE	G#<num.hostGP>
1: You're free to go now, chump.
WAIT	2
GOTO	LINK	30, 0
END
@Nomoney
1: It looks like you don't have any money to pay the Shadow Gang's toll with.
1: I guess you'll have to die, instead!
GOTO	@Battle
@Life
H: I'd die before I gave my money to the likes of you!
1: Bahahaha... That can be arranged.
@Battle
1: Get 'em!
MOVE 1, 1, 1, 1
MUSIC	Boss1.mid
FIGHT	42, 43
IF	WIN, @Win
MOVE	1, 17, 71, 1
1: Bahahahaha! That'll teach you to mess with the Shadow Gang!
END
@Win
H: ...It looks like those thieves dropped something in that fight.
H: It looks like a small, brown crystal...
H: I heard there's a jewel expert in Yew, just through this forest.
H: If I talk to him, he may be able to tell me more.
GIVE	T40
WAIT	2
GOTO	LINK	30, 0
END
@Empty
GOTO	LINK	30, 0
END
;----
SCENE	42	ArmorShop, SCENE, "Faldare's Assthumping Armor"
ACTOR	1, "Faldare", joshTownsfolk, 9, 17, 71
1: Greetings!
1: Welcome to my assthumping armor shop!
OFFER	134, 135, 136, 137, 138, 139, 151
END
;----
SCENE	43	ItemShop, SCENE, "Ye Olde Item Shoppe"
ACTOR	1, "Milandril", joshTownsfolk, 2, 17, 71
IF	T434, @refuse
1: Welcome to ye olde item shoppe!
1: Our name may be olde, but our goods ain't!
OFFER 1, 2, 3, 4, 7, 8, 12, 13, 15, 16, 18, 99, 141, 253
END
@eventactorclick1
IF	T430, @hasT430
1: I heard about a dragon living across the river in the Tolshroud Woods.
1: If you... Take care of it for me, there'll be something for you.
H: Why would you want to kill a Dragon?
1: They devastate land, and people. Nothing good comes from a Dragon. I want it dead.
GIVE	T430
H: ...I guess I'll check it out.
END
@hasT430
IF	T431, @goodend
IF	T432, @badend
1: Go kill that dragon...
END
@goodend
IF	T433, @hasT433
1: Ah... The Dragon is dead! Good.
1: Here you go, take this as a reward!
N: Received 40,000 Septi!
HOST_GIVE	G40000
GIVE	T433
END
@hasT433
END
@badend
IF	T434, @hasT434
1: You didn't kill the dragon?
1: What are you, some kind of dragon-lover?
1: I hope you choke.
GIVE	T434
END
@hasT434
END
@refuse
1: I won't sell my goods to a DRAGON-LOVER.
END
;------
SCENE	430	Bedroom, SCENE, "Dragon's Home"
IF	T431, @hasT431
ACTOR	1, "Dragon Guy", josh92, 1, 17, 71
IF	T432, @hasT432
1: Hi there!
H: Hey.
1: What can I do for you?
H: I'm supposed to kill you.
1: Kill me? Why?
H: Well, because there's someone that doesn't like you, and I'll get a big fat reward for doing it.
1: Hm... How about if I give you a big fat reward for sparing me?
@menu
MENU "What kind of reward?=@maybe", "No=@no"
GOTO	@menu
@Maybe
H: Hm... What sort of reward are you talking about?
1: I'll give you the power to control a dragon.
@Menu2
MENU	"I'll take it!=@yes", "No thanks, you die now=@no"
GOTO	@Menu2
@yes
H: I'll take it!
1: Very well then... Close your eyes...
HOST_GIVE	I1000
1: You are now the master of an Onyx Dragon. Treat it well.
HOST_GIVE	T432
H: Thanks.
1: No, thank you for sparing me. Perhaps I'll have something else for you in the future.
END
@no
H: No, I'm not interested.
1: I see... Very well then. May the best warrior win.
MOVE	1, 1, 1, 1
MUSIC	Boss-Sidequest.mid
FIGHT	111, 110
IF	WIN, @won
MOVE	1, 17, 30, 1
1: ...I am sorry we could not get along.
END
@won
H: I finished off the Dragon. Time for me to go.
HOST_GIVE	T431
END
@hasT431
END
@hasT432
1: If I find out anything nice, I'll let you know.
END
;----
SCENE	44	Kitchen, SCENE, "The Jewler"
ACTOR	1, "Don the Jewler", joshRoyalty, 2, 17, 71
IF	T41, @gemAppraised
1: Why hello there! How may I help you this wonderful evening?
H: I was attacked by a band of robbers, and when I defeated them, they dropped this.
1: Oh... Let's have a look at it, shall we?
1: Smashing! It appears that there's a small "J" monogramed on this gem!
H: A "J?" What is that supposed to mean?
1: Simple, dear #<g.boy>, this gem belongs to someone!
1: Do you know anyone who's name begins with J?
H: /a thinks back to the people #<g.he>'s met in the past...
1: Take this to someone whose name starts with J and ask them about it!
GIVE	T41
END
@gemAppraised
IF	T42, @GemGiven
1: Did you find the owner of the gem yet?
H: Nope, not yet.
1: Remember, the owner's name starts with a J!
END
@GemGiven
1: Did you find the owner of the gem yet?
H: Yep! I got another gem in return!
1: Smashing! A good trade, I must say!
END
;-----
SCENE	45	EarthTempleOut, SCENE, "Earth Temple Entrance"
IF	T42, @hasT42
WAIT	1
N: There's a strange rock here.
WAIT	2
N: An inscription on it reads:
N: "Only those who show compassion may enter."
END
@HasT42
IF	T43, @hasT43
WAIT	1
N: Gnome's Compassion shines brightly as %1 holds it into the air.
WAIT	2
N: The Rock at the altar reacts strangely, and suddenly...
WAIT	1
GIVE	T43
GOTO	LINK	33, 0
END
@hasT43
GOTO	LINK	33, 0
END
;-----
SCENE	46	EarthTemple3, SCENE, "Pillar of Earth"
MUSIC	Sacred.mid
ACTOR	1, "Gnome", Elementals, 3, 15, 16
IF	T44, @hasT44
1: ...%1... The one who has shown the temple Compassion.
H: That is me, who are you?
1: I am the Elemental of Earth, Gnome.
1: Those who appear to bring light to the Temple must be those who seek the Judgement.
H: That I am.
1: Very well then. This test is to prove if thy valor is as powerful as thy compassion!
1: Come, %1! Feel the might of the Earth beneath thine feet!
MUSIC	Boss4.mid
FIGHT2	49
IF	WIN, @Won
1: ...Thou hast fallen before the might of the Earth.
1: If thou canst not face this beast, how dost thou expect to face the Judgement?
1: Go now, mortal. Try again when thy body doth breathe life once again.
N: Would you like to warp back to Yew?
@Menu1
MENU	"Yes=@yes", "No=@no"
GOTO	@Menu1
END
@Yes
GOTO	LINK	32, 0
END
@No
END
@Won
MUSIC	Victory3.mid
1: Thou hast proven thy strength.
1: The light of the Temple hast returned to this pillar!
1: Go now, for the southern lands await.
1: To the south, a border doth lie.
1: Cross that border to reach yon Tolshroud Continent.
1: There, the next stage of thy journey awaits.
GIVE	T44
END
@hasT44
1: The highland in the Tolshroud Continent awaits thee.
1: Seek the power of light that beckons thy valor!
END
;-----
SCENE	47	CastleGates, SCENE, "Northrend Border"
ACTOR	1, "Guard", joshRoyalty, 4, 40, 80
IF	T44, @hasT44
1: ...
END
@hasT44
IF	T45, @HasT45
1: Halt! You may not pass.
N: There must be a way to get the guard to move.
WAIT	2
N: Maybe if you find a big, tough looking guy...
WAIT	2
N: ...You might be able to scare the guard away.
GIVE	T45
END
@HasT45
IF	T46, @hasT46
1: You may not pass.
END
@hasT46
IF	T47, @hasT47
ACTOR	2, "Jimbo", josh17, 1, 100, 50
MOVE	2, 50, 50
1: ...
1: That's... That's a big guy you have there.
2: ...This big guy thinks you better let %1 through.
1: ...And if I don't?
H: If you don't...
2: ...Then you'll pay with your life.
1: P-Please don't...H-hurt me!
2: Then let #<g.him> through.
1: Yes, yes! Right away!
1: Please, go through!
H: Thanks, Jimbo.
2: Anytime, %1. I'm heading back to the shop now... Drop by if you need me.
GIVE	T47
MOVE	2, 105, 50
WAIT	2
1: W-would you like to go through now?
@Menu1
MENU	"Yes=@Yes", "No=@No"
GOTO	@Menu1
END
@No
1: O-okay. C-come back when you n-need to get through.
END
@Yes
1: P-please... Go through!
GOTO	LINK	41, 0
END
@hasT47
1: Please, go through!
WAIT	2
GOTO	LINK	41, 0
END
;-----
SCENE	48	CastleGates, SCENE, "Tolshroud Border"
IF	T48, @HasT48
H: ...Here I am.
H: The very outskirts of my next destination.
H: Already, I've been through so much, but it feels like my journey's just beginning.
H: ...I will be the one that unseals the Temples and faces the Judgement of Tamriel!
WAIT	2
N: And so, %1 crossed the border to the Tolshroud Continent.
WAIT	2
N: Leaving the land of Northrend behind #<g.him>, %1 journeyed onward...
WAIT	2
N: The next stage of #<g.his> adventure awaited #<g.him>...
GIVE	T48
WAIT	3
GOTO	LINK	44, 0
END
@hasT48
GOTO	LINK	44, 0
END
;Hi there. I'm a nifty comment line.