; Quest 6, The Temple of Wind
;	60, "I heard about the wind stopping and a windmill to the south."
;	61, "I located the windmill and defeated the guardian of the Sky Emblem."
;	62, "I traded the Sky Emblem for the pile of gems."
;	63, "I took the pile of gems to the bazaar in Talroa and bought Sylphid's Fortility."
;	64, "I unsealed the gate to the Wind Temple."
;	65, "I battled the Airaptor with Kinomu's help and we lit the pillar."
;	66, "I accepted Kinomu's offer to join me in lighting the other temples."
;	67, "I declined Kinomu's offer to join me in lighting the other temples."
;	68, "Kinomu is in my party."

SCENE	600	Kitchen, SCENE, "Elder's Shanty"
ACTOR	1, "Elder Bonchi", joshTownsfolk, 22, 17, 71
IF	T60, @hasT60
1: You are an adventurer, are you not?
H: Yeah, I am.
1: I have something I need your help with.
H: Such as?
1: There's a windmill to the south, which is used to power our granaries and other things.
1: However, a monster took the sky emblem and held himself up in the windmill.
1: Now, the wind has stopped and nobody can get to the mill because of the monster.
1: If you take care of it, I'll give you this large pile of gems.
H: Understood.
GIVE	T60
END
@hasT60
IF	T61, @HasT61
1: The windmill is to the south, right off the Wilderwien Road.
1: Please hurry! Our food is running short!
END
@HasT61
IF	T62, @hasT62
1: You did it! You found the Sky Emblem!
1: In exchange, I will give you this pile of gems, as promised.
TAKE	I166
GIVE	I167
GIVE	T62
1: Thanks again!
END
@hasT62
1: Welcome back, child.
1: I don't know of anything else this town has to offer you, but you are free to stay as long as you'd like.
END

;-----------
SCENE	601	WindTempleIn1, SCENE, "The Windmill"
IF	T60, @hasT60
N: The windmill is silent, and unmoving.
END
@hasT60
IF	T61, @hasT61
N: The windmill is silent, and unmoving.
WAIT	2
H: ...This must be the place.
WAIT	2
N: ...Who disturbs my slumber...
WAIT	3
N: You wish a quick, painless death?
WAIT	3
N: ...Very well.
MUSIC	Boss1.mid
FIGHT	107
IF WIN, @win
END
@win
MUSIC	Victory2.mid
H: I did it!
H: Here's the sky emblem, too.
GIVE	I166
GIVE	T61
END
@hasT61
IF	T62, @hasT62
N: The windmill is silent, and unmoving.
WAIT	2
H: Hm... Perhaps if I take the Sky Emblem back to the elder, he will be able to make the windmill move again.
END
@HasT62
N: The windmill solemnly churns...
END
;----------
SCENE	602	Desert1, SCENE, "Wind Temple Entrance"
IF	T63, @hasT63
N: The gates to the Wind Temple were sealed tightly.
WAIT	2
H: I need the key to get past this point. I should come back later.
END
@hasT63
IF	T64, @hasT64
N: %1 stood before the gates of the Wind Temple.
WAIT	3
N: #<g.Che> held #<g.his> hand above #<g.his> head.
WAIT	3
N: Sylphid's Fortility shone brightly, and the way inside was unsealed.
WAIT	3
GIVE	T64
GOTO	LINK	113, 0
END
@hasT64
GOTO	LINK	113, 0
END
;---------
SCENE	603	WindTempleIn3, SCENE, "Pillar of Wind"
IF	T65, @hasT65
ACTOR	1, "Kinomu", Kinomu, 1, 17, 71
H: Kinomu... Why am I not surprised that you're here?
1: Haha, you don't give me enough credit, %1.
1: However, this temple has another test for you.
H: Augh, another one?
1: Yes, and this guardian is more difficult than most.
1: Allow me to render my assistance in this battle.
MOVE	1, 1, 1, 1
MUSIC	Boss7.mid
FIGHT	101, -105
IF	WIN, @won
N: And on that day, the world cried in pain over %1's death.
WAIT	3
N: Will you warp back to Wildern?
@Menu
MENU	"Yes=@yes", "No=@no"
GOTO	@menu
@Yes
GOTO	LINK	96, 0
@no
END
@hasT65
N: The light of the Wind Temple shines again.
END
@won
GOTO	SCENE	604
END
;-------
SCENE	604	WindTempleIn3, SCENE, "Pillar of Wind"
ACTOR	1, "Kinomu", Kinomu, 1, 17, 71
1: I'm impressed. It seems that the elementalists are becoming determined to keep their little secret from you.
H: Little secret?
1: You're so naive sometimes, %1.
1: As you've been unlocking these seals, You've been opening the way to a number of ever-increasing magical powers.
1: As these seals are broken, the Elementals are growing more powerful.
H: But wait... Isn't that a good thing?
1: Hahahaha... You will see in due time, %1.
1: I am willing to aid you in unsealing future Temples, should you need the help.
WAIT	2
N: Will you accept Kinomu's offer?
@Menu
MENU	"Yes=@yes", "No=@no"
GOTO	@menu
@Yes
1: Very well then. Let's go.
GIVE	T66
GIVE	T65
HOST_GIVE	T68
END
@no
H: No thanks.
1: Understood. Take care, then.
GIVE	T67
GIVE	T65
END
;---------
SCENE	605	ArmorShop, SCENE, "Jorgenson's Equipment Warehouse"
ACTOR	1, "Jorgenson", joshRoyalty, 6, 17, 71
1: You'll have a laughing good time with our equipment!
OFFER	156, 160, 189, 193, 197, 201, 208, 209, 213, 217, 221, 225, 229, 233, 237, 241, 245, 249
END
;--------
SCENE	606	Bedroom, SCENE, "The Haystack"
ACTOR	1, "Marinith", joshMiscellaneous, 14, 17, 71
1: Welcome to The Haystack!
SET	Innprice, 75
MUL	Innprice, #<num.peopleinscene>
1: Fer yer group to stay the night, it costs ya #<innprice> Septi.
1: Will y'all be stayin' with us?
@menu
MENU	"Hit the hay=@yes", "Naw, pardner=@no", "Set yer Save Point=@save"
GOTO	@menu
@no
1: Come again, y'all!
END
@yes
IF	-G#<innprice>, @noafford
1: All right, y'all, sleep well.
GIVE	L1
GIVE	H32000
GIVE	M32000
HOST_TAKE	G#<innprice>
END
@noafford
1: Sorry... y'all don't have the #<innprice> Septi.
1: Come again, y'all.
END
@save
SET	SPID, 96
SET	SPlocation, "Wildern"
SET	SPset, 1
END
N: Wildern set as save point.
END