; Quest 7, The Temple of Darkness
;	70, "The Paladin Captain holds the key to the darkness temple and asks that I defeat the Dark Knights."
;	71, "I defeated the Dark Knights in Farlia."
;	72, "I chose a more peaceful alternative."
;	73, "I returned with 'proof' of their defeat and the Captain gave me the Shade's Sorrow."
;	74, "I returned without proof of their defeat and the Captain accused me of collaborating with the Dark Knights."
;	75, "I unsealed the Temple of Darkness."
;	76, "I battled Akumu and lit the pillar of Darkness."
;	77, "The southern gates were breached and the dock to Shadowfast Island is now accessable."

SCENE	700	Fire,	SCENE,	"Paladin Camp"
ACTOR	1, "General Naltwys", Manda, 1, 17, 71
IF	T70, @hasT70
1: Hm... You seem like a sturdy young adventurer.
1: What brings you here to our encampment?
H: I'm on a quest to unseal the temples.
1: Oh, I see. 
1: Perhaps we will be able to help you, then.
1: As you no doubt already know, we Paladins are at war with the Dark Knights of Farlia.
1: One of our operatives infiltrated Farlia and stole Shade's Sorrow, the stone that controls the gates to the Temple of Darkness.
1: We will have finally crushed those evil bastards when they can't even enter their temple to pray for salvation from us!
1: !Mwahahahaa!
H: Er...
1: Oh, right. Well, if you're an adventurer, then this is a good deal, see. If you "take care" of some Dark Knights for me, I'll reward you with Shade's Sorrow.
H: ...I see.
1: Head to Farlia by going through the Forest of the Dead and then take care of the Dark Knights there.
GIVE	T70
END
@hasT70
IF	T71, @hasProof
IF	T72, @hasNothing
1: Farlia is to the west once you get through the Forest of the Dead.
1: I'm counting on you, kid.
END
@hasProof
IF	T73, @GoodEnd
1: Oh! So you have proof of their defeat!
1: This letter states that they actually plan on laying down their weapons due to your actions, eh?
1: Wow, %1! You're a badass!
1: All right, here you go.
GIVE	I164
GIVE	T73
END
@hasNothing
IF	T74, @badend
1: You... You refused to slay them?
1: Very well... You will soon meet your fate!
1: Get #<g.him>!
MUSIC	Boss1.mid
FIGHT 108, 108, 108
IF	WIN, @win
1: Hmph! It will take more than that to strike down the almighty Order of the Hand!
END
@win
GIVE	T74
GIVE	I164
1: Wh...What? How can you... Be so powerful?
1: A...All right. Take this stupid stone...
1: The Order of the Hand will live.....on...
WAIT	2
N: And so, the General died.
WAIT	2
N: %1 wondered how many more lives #<g.he> would have to take.
WAIT	2
N: However, #<g.his> adventure wasn't over, yet...
END
@goodend
1: You will be forever hailed within the Order of the Hand, %1.
1: I thank you.
END
@badend
MOVE	1, 1, 1, 1
END
;--------
SCENE	701	ArmorShop, SCENE, "Imperial Armory"
ACTOR	1, "Regin", joshtownsfolk, 1, 17, 71
IF	T74, @end
1: Welcome to the Imperial Armory!
1: We have the best goods available on this side of the forest!
1: Check them out!
OFFER	154, 158, 162, 191, 195, 199, 204, 205, 211, 215, 219, 223, 227, 231, 235, 239, 243, 247
END
@end
1: Get out.
END
;--------
SCENE	702	ItemShop, SCENE, "Imperial Apothecary"
ACTOR	1, "Gerin", joshtownsfolk, 9, 17, 71
IF	T74, @end
1: Oh, you need some Imperial quality items, eh?
1: Well, here they are! The best the Order of the Hand has!
OFFER 1, 2, 3, 4, 7, 8, 12, 13, 15, 16, 99, 253
END
@end
1: I don't offer my services to those who collaborate with the Dark Knights.
END
;--------
SCENE	703	Bedroom, SCENE, "Imperial Barracks"
ACTOR	1, "Igern", joshtownsfolk, 13, 17, 71
@eventactorclick1
IF	T74, @end
1: There's some beds over there if you want to rest.
1: How about it?
MENU	"Yes=@yes", "No=@no", "Set as Save Point=@save"
END
@yes
1: Sleep well...
WAIT	4
N: Hp + Mp Restored!
GIVE	L1
GIVE	H32000
GIVE	M32000
END
@no
1: All right then. Come back whenever.
END
@end
1: Scum like you can't sleep on our holy beds.
END
@save
SET	SPID, 59
SET	SPlocation, "the Paladin Encampment"
SET	SPset, 1
N: Paladin Encampment set as your Save Point.
END
;---------
SCENE	704	ArmorShop, SCENE, "Nephlite's Forge"
ACTOR	1, "Nephlite", josh17, 1, 17, 71
IF	T71, @end
1: Welcome!
H: Holy crap! Jimbo?
1: Jimbo? Who's that?
1: My name is Nephlite.
1: Anyway, welcome to my store!
OFFER	155, 159, 188, 192, 196, 200, 206, 207, 212, 216, 220, 224, 228, 232, 236, 240, 244, 248
END
@end
1: Sorry, pal, but your face is all over the wanted posters around town.
1: I have nothing against you, but if I'm caught selling goods to you, I'll be in deep shit.
END

;--------
SCENE	705	ItemShop, SCENE, "Farlia's F'nokkin Items"
ACTOR	1, "Tukanis", joshtownsfolk, 9, 17, 71
IF	T71, @end
1: Oh, you need some quality items, eh?
1: Well, here they are! Protect yourself from a Paladin invasion with these!
OFFER 1, 2, 3, 4, 7, 8, 12, 13, 15, 16, 99, 253
END
@end
1: You'll never get away with this, murderer!
END
;--------
SCENE	706	Bedroom, SCENE, "Dark Knight Dreams"
SET	Innprice, 65
MUL	Innprice, #<num.peopleInScene>
ACTOR	1, "Larkisto", "joshTownsfolk", 14, 17, 71
IF	T71, @end
1: Hello, and welcome to our establishment.
1: For your group of #<num.peopleinscene> to stay, it will cost #<innprice> Septi.
1: Is this okay?
@Menu
MENU	"Stay the Night=@yes", "Decline=@no", "Set as Save Point=@save"
GOTO	@menu
@yes
COMPARE #<num.peopleinscene>, 1
IF> @multiple
IF -G#<innprice>, @nomoney
HOST_TAKE	G#<innprice>
GIVE	L1
GIVE	H32000
GIVE	M32000
1: Thank you for staying. Please come again.
END
@multiple
1: How would you like to pay for this?
@Menu2
MENU "Leader pays for all=@leader", "Party members pay equally=@party"
GOTO	@Menu2
@leader
MUL	innprice, #<num.peopleinscene>
IF -G#<innprice>, @nomoney
HOST_TAKE	G#<innprice>
GIVE	L1
GIVE	H32000
GIVE	M32000
1: Thank you, come again!
END
@party
IF -G#<innprice>, @nomoney
TAKE	G#<innprice>
GIVE	L1
GIVE	H32000
GIVE	M32000
1: Thank you, come again!
END
@no
1: Come again.
END
@nomoney
1: I'm sorry, but you can't afford the room.
END
@End
1: You killed members of my family! I'll never forgive you!
END
@save
N: Farlia set as your save point.
SET	SPID, 77
SET	SPlocation, "Farlia"
SET	SPset, 1
END
;----------
SCENE	707	Farlia2, SCENE, "Outside the Dark Knights' barracks"
IF	T70, @hasT70
H: ...Sure is quiet, here.
END
@hasT70
IF	T71, @badend
IF	T72, @goodend
WAIT	2
N: ...Who goes there?
WAIT	3
H: ...My name is %1!
WAIT	3
N: ...What brings you here, %1?
WAIT	3
@Menu
MENU	"I'm here to kill you=@die", "I'm here to befriend you=@live"
GOTO	@Menu
@die
N: ...I see. So that's how it must be.
WAIT	3
N: Then we have no choice.
MUSIC	Boss1.mid
FIGHT	109, 109, 109
IF	WIN, @won
N: ..Pathetic.
END
@won
GIVE	T71
N: I see you have fallen into the Paladins' web of lies as well.
WAIT	3
N: This is a sad turn of events, but we have no choice.
WAIT	3
N: Take this paper... It will bring an end to this long war.
WAIT	3
N: Now leave... You are not welcome here.
END
@live
N: I see...
WAIT	3
N: Then return to the Paladin Encampment and tell them of your choice.
WAIT	3
N: Beware, though. I'm sure they will not be pleased.
WAIT	3
N: You will always be welcome in Farlia, friend.
GIVE	T72
END
@badend
N: Leave now.
END
@goodend
N: Welcome, friend. If we hear of anything, we may contact you.
END
;-------
SCENE	708	DarkTempleOut, SCENE, "Outside the Dark Temple"
IF	T73, @hasKey
IF	T74, @hasKey
N: %1 tried to enter the temple of Darkness...
WAIT	3
N: But the door had a mystic barrier!
END
@haskey
IF	T75, @hasT75
N: %1 raised #<g.his> hand high into the air...
WAIT	3
N: Shade's Sorrow shone brightly!
WAIT	3
N: The path to the Temple of Darkness opened!
WAIT	3
GIVE	T75
GOTO	LINK	108, 0
@hasT75
GOTO	LINK	108, 0
;-------
SCENE 709	DarkTemple2, SCENE, "Statue of the Goddess"
WAIT	2
N: %1 looked upon the statue, and felt relieved.
WAIT	2
N: Hp and Mp restored!
GIVE	L1
GIVE	H32000
GIVE	M32000
END
;--------
SCENE	710	DarkTemple3, SCENE, "Pillar of Darkness"
IF T76, @hasT76
H: Here it is... The pillar of darkness...
WAIT	3
N: You... Will not leave here alive...
WAIT	2
N: The Judgement must not happen!
WAIT	3
IF	T68, @KinomuBattle
MUSIC	Boss6.mid
FIGHT	103
IF	WIN, @won
@lose
N: The Judgement will never happen!
WAIT	3
N: Back to Farlia with you!
GOTO	LINK	77, 0
END
@kinomubattle
MUSIC	Boss6.mid
FIGHT	103, -105
IF	WIN, @won
IF	DEAD, @lose
END
@Won
GOTO	SCENE	711
@hasT76
END
;---------
SCENE	711	DarkTemple3, SCENE, "Pillar of Darkness"
ACTOR	1, "Kinomu", Kinomu, 1, 17, 71
1: You've been doing very well, %1.
1: After the Hero, Tamriel Freth died, his body was sealed in a great temple atop the highest mountain in the world.
1: However, this was not done to honour him.
1: The elementalists feared what would happen if someone were to take the Dreamstone Dagger yet again.
H: The Dreamstone Dagger?
1: It is a mythic weapon.
1: Made of a material known as Dreamstone, the Dagger can conform its shape and size to fit the user.
1: In the hands of Tamriel Freth, it was a mighty broadsword, but who knows what it will look like when a new Hero arises and takes it?
H: You mean... The descendant of Tamriel.
1: Hmmm... Yes, one of the descendants of Tamriel will take it.
H: ...One of?
1: Hahaha, I have said too much. Come, we must press on!
1: Make sure you have done everything there is to do on this continent... When you're done, we head for Wildern.
H: Understood.
GIVE	T76
END
;----------