SCENE 0,		crystal, WELL, "Revolution of Terror", 2, 7


	THEME	1
	ACTOR	1,	"Gen", rotm, 32, 0, 90
	SEL		1
	MOVE	1,	50, 60
	WAIT	1.0
	1: Welcome to the Revolution of Terror,
	1: Click on me in case you need more help or if you just want to know something, if you're new in RoT then please visit the FAQ in Elliair.
	MOVE	1,	25, 78
	1: Have fun!
	END
@eventActorClick1
	MENU "Story Line=@story","Information=@info","Help=@help","Credits=@credit","Cheating?=@cheat","Advice=@advice","Contact us=@contact","Version=@version","Update=@update"," =@hidden"
	END
@advice
	1: Doing things the easy way is never rewarded in RoT, even though it seems to have an advantage first.
	1: Also pay close attention to what the people in RoT have to say, 
	1: they often say things just once and except for reading back there isn't any way to find out what they said.
	1: Sometimes you're lucky and they give hints when you re-enter the scene.
 	1: It's recommended that you select Statistics or Map while you're in scenes, some scripts might cause lag if you don't.
	1: When you think that WoS is crashing just press on either Map or Statistics and it *should* be fixed.
	1: Many people seem to be keen on levelling RoT will proof to be a challenge for you, 
	1: RoT is more a quest world though and you should try to keep your level near (or higher) then that of the monsters you fight in that area.
	1: RoT is made to have fun, don't let the game become a frustration,
	1: if you can't solve something immediately then start doing something else in the world first.
	1: There is more then enough to do.
	1: Have fun!
	END
@version
	1: You're currently playing the published version of RoT v3.00.
	1: To double check which version this is it's probably easiest to type /version in-game.
	1: It's not a cheat and it won't mark you as a cheater either.
	1: If you can't enter other people's camp then either you or them are in an older version.
	1: You can get patches/ updates on https://cetechnologies.nl/rot/download.htm.
	1: If you used the Update feature but you couldn't install the newest patch then you either already are in the newest version,
	1: or you need to update to a newer patch before you can use the update feature.
	1: If you experience other problems you could check the FAQ on the download page.
	1: That should help you figure out what's wrong.
	1: Have fun!
	END
@update
	1: I will now download the new RoT patch v3.10 for you.
	1: When the download window appears you'll have to click on Open file.
	1: If you get an authencity warning then you can just ignore that, 
	1: however if you don't trust it for some reason then you can always click on Save file instead.
	1: Click on Return To Game after downloading.
	WAIT 4.0
	HTML https://cetechnologies.nl/rot/newpatchV3-10.exe
	WAIT 2.0
	1: If you succesfully installed your patch you will need to reload the world first before you can use the new patch.
	1: If you weren't able to update your patch then please click on Version for more information.
	1: You can also get patches/ updates on https://cetechnologies.nl/rot/download.htm.
	1: Have fun!
	END
@story
	1: Revolution of Terror plays on an island called Kagoshima. 
	1: Right now there is a war going on.
	1: The population is divided in two sides, the side of Warlord Keithuso and the side of Emperor Shinzobi.
	1: You are a recruit in the army of Emperor Shinzobi and you will fight Warlord Keithuso.
	1: There are many ways to achieve your goal, you should do what suits you best.
	1: Don't let others tell you which path to take, be free and make your own decisions.
	1: If you wish to find out more about the story then I suggest you start playing.
	1: Have fun!
	END
@contact
	1: If you experience bugs in quests or in scripts then you should contact Silver.
	1: You can e-mail him at dumpmeel44@hotmail.com.
	1: In case you need to contact Devil or Atsumori then you ran out of luck, I don't have their e-mail adress anymore.
	1: Have fun with the game!
	END
@info
	1: As requested I shall give some information about RoT.
	1: RoT is short for Revolution of Terror, the world is based on a Japanese medieval world.
	1: Most of the quests are based on single player mode,
	1: but often people can help you out on your quests.
	1: Some quests are for multiplayer mode only, that is because they are to hard to beat alone.
	1: These quests are optional though.
	1: Every quest can be solved on different ways, generally good or evil ways.
	1: Each quest can solve a slight variation in the story line caused by how you behave yourself in RoT.
	1: The rewards are generally the same, sometimes evil pays better, other times good pays better.
	1: I guess I could also reveal some of the special features...
	1: There are a lot of new small mini games
	1: most of the times they're hidden in small quests.
	1: Almost every mini game can be done at any level, some require higher levels to finish though.
	1: One of the classes, the Slaver class is a class that starts with a pet, 
	1: you can choose between 2 different pets after visiting the Home scene in Elliair.
	1: Another class, the Amazones is made for females only, 
	1: most classes are neutral in gender but often a WoS world seems to be based on males only.
	1: RoT has therefore a class that is girls only!
	1: A third interesting class is the Merchant class, 
	1: they have to trade items with other players and can sell items back to shops with a larger profit then normal classes can.
	1: A fourth interesting class might be the Missionair class.
	1: If you like to do things the easier way and you're not into PKing then you should pick this class.
	1: However this is the only class that isn't balanced to 0,0 hits advantage compared with the other classes.
	1: All other classes are equal in strenght at level 99.
	1: There has also been an improvement in PK camps, 
	1: there are now 6 new types of PKing, forcing you to adept your strategies and hopefully giving more fun.
	1: You will learn more about the special features while you're playing the world.
	1: The creators of this world believe strongly in giving gamers what they want,
	1: if you have quest idea's or idea's for improvement then you can mail them to silver@wos-rot.com.
	1: You will receive a reply a.s.a.p. and maybe the idea will be put in.
	1: I can't make any promises though.
	1: However if your idea is put in then you will be contacted and your name will be put in the credits scene.
	1: That's about all the information I'm giving you right now, the rest you'll have to find out yourself.
	1: Have fun!
	END
@help	
	1: Right now you are in the Well, you have not incarnated yet into the real world.
	1: On the left you see a button called Map, if you click on it then you can see who is on the server.
	1: If you play in solo mode then you will only see yourself.
	1: On the right of the Map button you see the Restore button.
	1: If you already made a character then you can select this character and press on the Incarnate button to incarnate in RoT.
	1: The Incarnate button is the button on the right.
	1: In the middle you see the New button, to make a new character you have to press this button.
	1: A pop up will appear, here you can select your gender, Hero or Heroine, you can type your name and you can select if you're a PKer or Non PKer.
	1: PKer, or Player Killer, means that you can kill people, but they can also kill you.
	1: Non PKers cannot kill people unless they are in PK arena.
	1: PK arena is called Dark arena in RoT.
	1: Both PKers and Non PKers can resurrect people who died.
	1: After that you can pick your Ability Points.
	1: If you have no idea what they are then press Okay and the system will set them randomly for you.
	1: After picking the Ability Points you can choose a skin and incarnate in RoT automatically.
	1: Left of the Incarnate button you see the Haunt button, this feature only works on line.
	1: You must have an existing character to haunt, 
	1: after picking your existing character you have to select somebody on the Map that you wish to haunt.
	1: After that you can press the haunt button and you will incarnate as a ghost.
	1: To return to the well you can press on the Well button.
	1: After incarnating you're on your own, I advise you to visit the link you start on.
	1: If you still need more help then there is a Frequently Asked Questions link in Elliair to help you out more.
	1: Have fun!
	END
@credit
	1: There is a credits scene in Elliair, 
	1: if you're interested in who helped building this world then I suggest you visit that scene.
	1: Have fun!
	END
@cheat
	1: Well of Souls may support cheat codes, however RoT does not.
	1: If you use cheat codes your characters will be banned to Unknown Hell and they can't be unbanned anymore.
	1: Maybe you know how to modify worlds, that's great for you but RoT does not support this either.
	1: Your characters will be banned to Unknown Hell or you end up playing in a different version.
	1: If you play in a different version you can't enter other peoples camp and they can't enter yours.
	1: Maybe you have some evil knowledge about how to break worlds, generally this isn't appreciated.
	1: If you're spotted on line then your soul ID will be banned in the next patch.
	1: Also will your character most likely be banned to Unknown Hell.
	1: Maybe you gained some knowledge about how to use Hex Editors or Game Trainers.
	1: Generally this isn't appreciated and RoT does not support it either.
	1: Your characters will most likely end up being banned to Unknown Hell.
	1: If you're spotted using a Game Trainer on line then your soul ID will be banned next patch.
	1: If you never do any of this then you don't have to fear anything.
	1: However if you do end up being banned, while you played legitly, then please send an e-mail to dumpmeel44@hotmail.com
	1: Please explain exactly what you did and when you did it, also put in the statistics about your character:
	1: such as hours played, monsters killed, mods you have travelled through and so on.
	1: Your character can not be unbanned, but you can help fixing this bug to prevent it in the future.
	1: As long as you play legit you don't have to fear anything.
	1: Have fun!
	END
@hidden
	MOVE 1, -100,100,1
	FX 1
	WEATHER 0
	BKGND nightmare
	ACTOR 2, "",monster014, 1,-20,95
	SEL 2
	POSE 1,4
	MOVE 2,35,65
	WAIT 6.0
	2: All your fears will soon come true...
	SOUND "evillaugh.wav"
	ACTOR 8, "", explosion,1, -150,100
	ACTOR 9, "", explosion,1, -150,100

;
; explosion script, this baby will rock you all!
;
	MOVE 8,50,50,1
	SOUND explosion

	SEL 8
	POSE 1
	WAIT 0.2
	POSE 2
	WAIT 0.2
	POSE 3
	WAIT 0.2
	POSE 4
	WAIT 0.2
	MOVE 8,-150,100,1

	MOVE 8,30,80,1
	SOUND explosion

	SEL 8
	POSE 1
	WAIT 0.2
	POSE 2
	WAIT 0.2
	POSE 3
	WAIT 0.2
	POSE 4
	WAIT 0.2
	MOVE 8,-150,100,1

	MOVE 9,80,70,1
	SOUND explosion

	SEL 9
	POSE 1
	WAIT 0.2
	POSE 2
	WAIT 0.2
	POSE 3
	WAIT 0.2
	POSE 4
	WAIT 0.2
	MOVE 9,-150,100,1

	MOVE 2,-20,95,1	
	FX 2
	WEATHER 7
	BKGND crystal
	MOVE 1,25,78,1
	END



SCENE 1

	THEME
;	MUSIC   (no music in camp scene, just theme)

	COMPARE #<num.isPKAttack>, 1
	IF= @pk
	COMPARE #<num.isPKAttack>, 2
	IF= @pk
	SET slavaon, #<rating>	
;
; I do NOT tolerate any form of cheating, modding, world breaking or fast levelling, if you don't want to play RoT legitly then don't play at all.
;
#include banscripts.txt

; Check for fix scripts to fix characters that were broken in the past.
#include fixscripts.txt

	CALL 1373@werewolfTransformation

	COMPARE #<num.hostEquipId13>, "2143"
	IF= @ankhoflife
	GOTO @endankhoflife
@ankhoflife
	IF ALIVE, @endankhoflife
	HOST_GIVE L1
	HOST_GIVE H#<num.hostMaxHP>
	HOST_GIVE M#<num.hostMaxMP>
@endankhoflife

@setlock
	IF #35+DEAD, @summonDoctorAdlington
	IF #15, @setspecialleavebutton
	IF #33, @skiplockx2
	IF #31, @haven
	IF C21, @skiplockx2

#include merchant2.txt	
	SET sceneLock, 0
	ACTOR	9, "Lock", danNoFloat, 6, 95, 10
	END

@skiplock
	IF P0, @setlock
	END
	
@summonDoctorAdlington
	CALL 5017@summonDoctorAdlington
	GOTO @setlock

@setspecialleavebutton
#include R0005.txt
	END
@haven
	GOTO SCENE 310

; The scene host has clicked on the little lock icon

@eventActorClick9
#include lpscript2.txt	

;	MENU "Lock Scene=@lockscenenow","Unlock Scene=@unlockscenenow"
;	END
@unlockscenenow
	COMPARE #<sceneLock>, 0
	IF= @lockscenenow
	LOCK 0
	SET sceneLock, 0
	SEL 9
	POSE	6
	HOST_TAKE T163
	HOST_TAKE T164
	HOST_TAKE T165
	HOST_TAKE T166
	COUNTDOWN 10
	WAIT 10
	END
@lockscenenow
	LOCK 1
	SET sceneLock, 1
	SEL 9
	POSE	5
	HOST_TAKE T163
	HOST_TAKE T164
	HOST_TAKE T165
	HOST_TAKE T166
	COUNTDOWN 10
	WAIT 10 
	END
@eventActorAttack9
	IF R1, @hurtlock
	END
@hurtlock
	9: Will you please stop harassing me!?
	9: I might be just a lock but I have feelings to you know!
	9: It's hard enough to sit here all day and watch how you kill each other, but now you're hitting me too??
	9: I demand compensation!
	WAIT 3.0
	N: The lock steals 100 GP from everybody!
	TAKE G100
	WAIT 3.0
	9: Ha! 
	9: That will teach you not to mess with a lock!
	END
@eventActorSpell9
	IF R4, @locktickle
	END
@locktickle
	9: That tickles...
	9: Please stop it!
	END
@eventActorGive9
	IF R10, @lockthank
	END
@lockthank
	COMPARE #<item.goldGiven>,"0"
	IF> @lockgold
	9: Thank you!
	9: I always wanted to have a neat %I#<item.id>!
	END
@lockgold
	9: Only #<item.goldGiven> GP?
	9: I thought a loyal lock like me deserved a little more then that!
	END

@chibipk
	N: %1 did a Chibi Attack, good luck %2! 
	FLAGS 8192
	LOCK 1
	END

@pk
	IF #33, @chibipk

	ACTOR 8, "PK Camp Host", mirror,4, -50,-80
	ACTOR 7, "PK Camp Host", mirror,4, 50,80

	; Set map flags: 32768 (no nasty spells) + 8192 (no tickets) + 4096 (no Heal)
	N: %1 did a PK Attack! 
	N: Good luck %2!
	FLAGS	45056
	LOCK 1
	HOST_TAKE T163
;	IF #20,@eventpk1
	COUNTDOWN 10
	N: You have 10 seconds to attack the Camp Host and pick a PK fight!
	EJECT V#<num.hostLevel>
	END
@eventPkAttackDone
	LOCK 0
	FLAGS 0
	END
@eventActorSpell7
@eventActorAttack7
	EJECT V#<num.hostLevel>
	IF XP,@eventpkend
	MENU "Normal Fight=@eventpk1","Heal Fight=@eventpk2","No Buff Fight=@eventpk3","Disease Spell Fight=@eventpk4","Slaves/Summons Fight=@eventpk5","Everything Allowed=@eventpk7" ,"No Slaves Allowed=@eventpk10","No PK Fight=@eventpk6"
	MOVE 7,-50,-80,1
;	MOVE 8,50,80,1
	END
@eventpkend
	N: Time expired, this is a normal PK fight!
	N: No healing, no running.
	MOVE 7,-50,-80,1
	END	
@eventpk1
	N: This is a normal PK fight! 
	N: No healing, no running.
	MOVE 7,-50,-80,1
	END
@eventpk2
	FLAGS 40960
	N: Healing is allowed!
	MOVE 7,-50,-80,1
	END
@eventpk3
	FLAGS 110592
	N: Buffs are not allowed!		
	MOVE 7,-50,-80,1
	END
@eventpk4
	FLAGS 12288
	N: Disease spells are allowed!
	MOVE 7,-50,-80,1
	END
@eventpk5
	FLAGS 45058
	N: Slaves and Summons are allowed to fight!
	MOVE 7,-50,-80,1
	END
@eventpk10
	FLAGS 45184
	N: No slaves are allowed!
	MOVE 7,-50,-80,1
	END
@eventpk6
	FLAGS 8192
	LOCK 0
	N: No PK Fight!
	GOTO EXIT
	MOVE 7,-50,-80,1
	END
@eventpk7
	FLAGS 8194
	N: Everything is allowed!
	N: Including slaves, healing, buffs and nasty spells!
	MOVE 7,-50,-80,1
	END

@eventActorSpell8	
@eventActorAttack8
	IF C12, @menualva
	IF C13, @menualva
	IF C14, @menualva
	IF C15, @menualva
	IF C32, @menualva
	IF C33, @menualva
	IF C34, @menualva
	IF C35, @menualva
@pkgofor
	IF ALIVE, @pkgofo
	IF DEAD,  @pkover
@pkover
	8: You seem to be dead, I shall unlock the pk camp.
	LOCK 0
	SET sceneLock, 0	
	END
@pkgofo
	8: You cannot unlock the camp yet since you are still alive.
	END
@menualva
	MENU "Exit Fight=@eventpk6","Unlock normal=@pkgofor","Change background=@alvadrod" 
@alvadroa
;	HOST_GIVE L1
;	HOST_GIVE H#<num.hostMaxHP>
;	HOST_GIVE M#<num.hostMaxMP>
;	END
@alvadrob
;	HOST_GIVE H#<num.hostMaxHP>
;	HOST_GIVE M#<num.hostMaxMP>
;	END
@alvadrod
	MENU "nightmare=@neo","battlefeildx=@neo2","bkroon=@neo3","bluesky=@neo4","cloudscape=@neo5","lakeside=@neo6","oceancastle=@neo7","pyramid=@neo8","skycity=@neo9","3 mountains=@neo10"
	END
@neo
	BKGND nightmare
	END
@neo1
	BKGND gateoftime&space
	FX 2
	END
@neo2
	BKGND battlefeildx
	FX 5
	END
@neo3
	BKGND bkroon
	END
@neo4	
	BKGND bluesky
	END
@neo5
	BKGND cloudscape
	END
@neo6
	BKGND lakeside1
	END
@neo7
	BKGND oceancastle
	FX 2 
	END
@neo8
	BKGND prya
	FX 2 
	END
@neo9
	BKGND scenes088
	FX 2
	END
@neo10
	BKGND scenes101
	END
#include qspotions.txt
;--------------

; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
SCENE 2
	THEME
;	
; FIGHT SCENE
;
	IF C21, @S11
	SET slavaon, #<rating>	
#include banscripts.txt


; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; SPECIAL FIGHT SCENE SCRIPT
;
; R A N D O M   E N C O U N T E R S
;
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX


	IF T457, @link3
	COMPARE "#<num.serverTimeMonth>", "12"
	IF= @xmasmaybe

@link3

#include werewolfintro.txt

	; Give a warning to players who didn't do the challenge yet for their level bracket.

	CALL @challengeWarning
	CALL @gunslingerWarning
	CALL 1373@werewolfTransformation

	IF T664+I777+R10-T665|T664+I777+R10-T666, @flyerblackjack
	IF H25-T663, @birthdaypresent
	IF R8+I2132, @randoma
	IF R2-I2132, @randoma
	IF #38+T908, @gotoExit
	IF #38, @fightMRF
	IF #11, @lonewarrior
	IF #17, @specialslave
	IF GS+R2-S199, @summonmini
	IF #0+R10-I2132, @kittyraft
	IF #0+R30+I2132, @kittyraft
	IF V99+R6-I2132+S35+S36+S65+S66+S95+S96+S115+S116+S135+S136+S155+S156+S175+S176+S197+S198-S265, @fightgorgath
	IF V99+R24+I2132+S35+S36+S65+S66+S95+S96+S115+S116+S135+S136+S155+S156+S175+S176+S197+S198-S265, @fightgorgath
	IF C1-T520+R10,  @katanaupdate
	IF C16-T520+R10, @katanaupdate 
	IF C36-T520+R10, @katanaupdate 
	IF C37-T520+R10, @katanaupdate
	IF C38-T520+R10, @katanaupdate

	IF T299-T412,@rotwarscript 	
	
	GOTO @fightcommand
	END
	
@gotoExit
	GOTO EXIT

@fightMRF
	GOTO SCENE 5223
	
@kittyraft
	IF T504, @fightcommand
	IF T505, @fightcommand
	GOTO SCENE 1351

@challengeWarning
	IF V29-V30-S35|V39-V40-S65|V49-V50-S95|V59-V60-S115|V69-V70-S135|V79-V80-S155|V89-V90-S175, @challengeWarningGive
	RETURN

@challengeWarningGive
	IF T5, @challengeWarningSkip
	N: Warning: you didn't do the level #<num.hostLevel> Challenge yet to earn a summon spell.
@challengeWarningSkip
	RETURN
	
@gunslingerWarning
	IF T118+V24-V25-T1200|T118+V44-V45-T1201|T118+V64-V65-T1202|T118+V84-V85-T1203, @gunSlingerHCWarning
	RETURN

@gunSlingerHCWarning
	N: Warning: this is the last level that you can do the %C63 hardcore challenge!
	RETURN

@xmasmaybe
	COMPARE "#<num.serverTimeDay>","24"
	IF= @randomxmass
	COMPARE "#<num.serverTimeDay>","25"
	IF= @randomxmass
	COMPARE "#<num.serverTimeDay>","26"
	IF= @randomxmass
	GOTO @link3
@randomxmass
	IF R90, @link3
	GOTO SCENE 1330

@rotwarscript
#include rotwar.txt
END
@randoma
	IF R75,@storyline
	IF R50,@stealthfight 
	IF R50,@randomally
	GOTO @wandering
	END	

@katanaupdate
	GOTO SCENE 1357

; random stealth monster fights
@stealthfight 
	IF T430,@wandering
	IF T435,@wandering
	IF T2031-V17, @wandering
	GOTO SCENE 300

; random mysterious stranger fights
@randomally
	IF T430, @wandering
	IF T432, @wandering
	GOTO SCENE 301

; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; SUMMON MINI ME:
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
@summonmini
	IF S199,@fightcommand
	IF -GS, @fightcommand
	
	GOTO SCENE 303

; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; STORY LINE:
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
@storyline

	IF T442, @fightcommand

	IF T219, @storyliner
	IF T218, @storylineq
	IF T217, @storylinep
	IF T216, @storylineo
	IF T215, @storylinen
	IF T214, @storylinem
	IF T213, @storylinel
	IF T210, @storylinek
	IF T209, @storylinej
	IF T208, @storylinei
	IF T207, @storylineh
	IF T206, @storylineg
	IF T205, @storylinef
	IF T204, @storylinee	
	IF T203, @storylined
	IF T202, @storylinec
	IF T201, @storylineb
	IF T200, @storylinea

	GOTO SCENE 1175
@storylinea
	GOTO SCENE 1176
@storylineb
	GOTO SCENE 1177
@storylinec
	GOTO SCENE 1178
@storylined
	GOTO SCENE 1179
@storylinee
	GOTO SCENE 1180
@storylinef
	GOTO SCENE 1181
@storylineg
	GOTO SCENE 1182
@storylineh
	GOTO SCENE 1183
@storylinei
	GOTO SCENE 1184
@storylinej
	GOTO SCENE 1185
@storylinek
	GOTO SCENE 1185
@storylinel
	GOTO SCENE 1186
@storylinem
	GOTO SCENE 1187
@storylinen
	GOTO SCENE 1187
@storylineo
	GOTO SCENE 1188
@storylinep
	GOTO SCENE 1189
@storylineq
	IF -T433-T436, @storyliner
	GOTO SCENE 1190
@storyliner

	GOTO @fightcommand
; until I made the other movie scenes.	
	END

; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; FIGHT SCENE:
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; start of Sky Lands script
@specialslave
	FLAGS 2048
	BKGND standingstones
	ACTOR 61, "FLEE!", rotm2, 10,90,15
	EJECT T172
	
	LOCK 1
	IF -G15000|GS-G7500,@nomoSkyLands
	
	FIGHT
	
	SET monster.id, #<monster.lastFightId1>
	SET temp, #<monster.level>
	MUL temp, #<monster.lastFightCount>
	MUL temp, 20
	IF -GS, @skipSkyLandsGS
	DIV temp, 2

@skipSkyLandsGS
	HOST_TAKE G#<temp>
	N: This fight cost you #<temp> GP.
	END

@nomoSkyLands
	N: You don't have enough money left to fight!
	END
	
@eventActorAttack61
@eventActorSpell61
@eventActorGive61
@eventActorClick61
	GOTO EXIT
; end of Sky Lands script

@fightcommand
	IF #19+R1,@fightkagospirit
	IF #26, @terryandmary
	IF #15, @fightoffhellskitchen
#include R0001.txt
	IF V95, @fightcommand3
	IF  #1, @norun
	IF R15, @fightcommand2
	
	CALL 5199@beforefightgunslingerstart

	FIGHT
	GOTO @finalend	
 	
@fightcommand2
	CALL 5199@beforefightgunslingerstart
	FIGHT2
	GOTO @finalend	
	
@fightcommand3
	CALL 5199@beforefightgunslingerstart
	FIGHT
	GOTO @finalend	

@fightkagospirit
	GOTO SCENE 307

@fightoffhellskitchen
	GOTO SCENE 308
	
@norun
	IF R85, @fightcommand2
	IF R15, @fightcommand3
	GOTO @norun
	
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; SPECIAL REWARDS:
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
@finalend
; include the after fight reward script
	CALL 984@rewardMissionPP
	CALL 5198@gunslingerCPRAndAfterFightQuotes
	
#include R0004.txt
	END	; this end will never be called regardless, but it's just here to prevent confusion.

@terryandmary
	GOTO SCENE 304

; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; WANDERING SLAVER
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; I will make a wandering merchant(for each main class) here with special rare stuff. 
@wandering
	LOCK 1
	IF R50,@slaverwan
	IF R75,@merchant

	GOTO @wandering

@slaverwan

	GOTO SCENE 305


; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; WANDERING MERCHANT QUEST
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;
@merchant

	GOTO SCENE 306


; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; SUMMON GORGATH
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;
@fightgorgath
	GOTO SCENE 1385

; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; BIRTHDAY PET
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;
@birthdaypresent
	GOTO SCENE 311
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; BLACKJACK
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;	 
@flyerblackjack
	GOTO SCENE 312
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
; LONE WARRIOR QUEST
; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;
@lonewarrior
	IF T412, @fightcommand
	IF T299, @rotwarscript
	IF T331, @fightcommand 
	IF T332, @fightcommand

	IF R5, @lonewarriors
	GOTO @fightcommand

@lonewarriors
	GOTO SCENE 302

;--------------
;

; a little teleport scene to fix things. Ordinarily not accessible.	
SCENE 6
#include publickey.txt	
	STRCMP #<str.soul>, "SOUL 1373"
	IF= @cont
	END
@cont
	TAKE T172
	ASK 3000
	GOTO LINK #<lastAsk>,0,0	
	

;---------
; Headless Horse Man
; 
SCENE 13 magestower, "Sleepy Hallow"
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Ghost Headless Horse Man", rotm, 18, 25, 90
    SEL		1
	MOVE	1,	15, 80
@start
	1: You have came this far, now I shall defeat you!
    1: Feel the wraith of the Headless Horse Man!
    MOVE	1, -30, 80
    WAIT	5.0
    FIGHT	240   
END

;---------
SCENE 15 unamed,SCENE,"Kon Artist"
	THEME	1
	ACTOR	1,	"Kon Artist",		rotm,	20,	40,	90
	POSE	24,23
	1: Hi I'm Kon Artist,
	1: I'm only here to let you know I stole the creeping death map for my world.
    H: Stealer! 
    H: I'll spare your life though...
END


; Comment: The difference between a mad man and a genius is just a few IQ, if you're to smart then you start thinking faster
; the your brains can process, causing madness. Mad ppl are actually ppl who are to smart, it happens when your IQ is near
; 180 - 200 or above. I guess this proves the human brain is only limited at this moment (maybe humanity can alter it later),
; infinite wisdom doesn't exist.