
; Mirrormaze Quest
; Quest, Mirror Maze
	41,"You speak to the fortune teller"!
	42,"You get the password to the Underworld.


SCENE 134 shop

ACTOR 1, "Norman", joshTownsfolk, 18
	1: I'm parched.
	1: I'm also short of ready cash.
	1: But I'll give information in exchange for a drink- how about it?
ASK 35
IF YES @saidYes
	1: Okay then, I'll pass the info on to someone more deserving.
END

@saidYes
	1: Be very careful if you enter the mirror maze.
	1: Any soul who dies in there is trapped in the mirrors and cannot escape.
	1: If you die your only hope of escape..
	1: ..is to persuade a fellow quester to seek you out and resurrect you.
	1: Personally I'd avoid the place like the plague.
END


SCENE 80 bazaar
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Fortune Teller", seafolk  1
	POSE	1
	SEL		1
	MOVE	1,	15, 80
	
	' Fortunes told, let me see your future!
IF I1018, @hasI1018
	1: Yeah..yeah..I know!
	1: No fish out of water jokes- I've heard them all before.
	1: Anyway I'm not telling fortunes today.
	1: Haven't got any Mystical Myrtle leaves to burn in my brazier.
	1: Need all that fancy smoke and stuff: the punters like it.
END
@hasI1018
	1: OKAY! WOW!
	1: Let's burn this weed..cough splutter..bit smokey..
	1: ..couldn't you have dried it first?
IF T42, @hasT42	
WAIT  3
	1: I see a maze of glass..
	1: Very dangerous place.
	1: You will face your worst enemy there.
	1: There is a trapped soul needing returned to..
	1: ..cough...cough..sorry it's gone.
GIVE  T41
END

@hasT42
	1: I see you at the gate to the underworld..	
	1: ..they open for you...what a pity..you must be dead..
	1: (they don't let just ANYONE in there.
	1: you need a password and everythng!) 
	1: ..cough.. splutter... no wait! you seem to be alive..
	1: ..you are giving the gatekeeper a..a...RATS!
	1:  Sorry it's gone...
END



SCENE 81
	THEME
;	MUSIC  mortal.mid
	FIGHT 274
IF	WIN	@heWon
END

@heWon
GOTO LINK 11,5
END

SCENE 82
	THEME
;	MUSIC  mortal.mid
	FIGHT 275
IF	WIN	@heWon
END

@heWon
GOTO LINK 11,4
END

SCENE 83
	THEME
;	MUSIC  mortal.mid
	FIGHT 276
IF	WIN	@heWon
END

@heWon
GOTO LINK 11,7
END

SCENE 84
	THEME
;	MUSIC  mortal.mid
	FIGHT 277
IF WIN	@heWon
END

@heWon
GOTO LINK 11,9
END

SCENE 85
	THEME
;	MUSIC  mortal.mid
	FIGHT 278

IF WIN	@heWon
END

@heWon
GOTO LINK 11,11
END

SCENE 86
	THEME
;	MUSIC  mortal.mid
	FIGHT 274,278
IF WIN	@heWon
END

@heWon
GOTO LINK 11,2
END

SCENE 87
	THEME
;	MUSIC  mortal.mid
	FIGHT 274,275,276,277,278
IF	WIN	@heWon
END

@heWon
GOTO SCENE 88
END

: mirror thief
SCENE 88 cave2
MUSIC	waltz2.mid
	ACTOR	1,	"Kha the hopelss", lostguy  1
	POSE	1
	SEL		1
	MOVE	1,	15, 80
	
	1: At last!
	1: I thought I'd be trapped here for all eternity!
	1: The ONLY way out is to use a ticket home.
	1: I came to find the lost mirror and here it is.
	1: If you want it it's yours.
	1: But you'll need to give me a ticket home so I can get out. 
	1: Do you agree to that?

ASK 10
IF -YES, @saidNo

	1: Here's the mirror then, thanks %1!
	1: I'll leave this sort of stuff to questers like you in future.
GIVE  I1017
TAKE  I99
END




@saidNo
	1: I guess I'm stuck here still someone rescues me then.
	1: The mirror? NO WAY!
	1: You want the mirror you get me out of here.

END

: gardener
SCENE 89 cloudyVeldt2
MUSIC	waltz2.mid
	ACTOR	1,	"Gordon", gardener,  1
	POSE	1
	SEL		1
	MOVE	1,	15, 80

IF I1015, @hasI1015

	1: I used to have a thriving garden here.
	1: Grew Bog Roses and Bog Myrtle.
	1: Unfortunately I have none now.
	1: The guy who ran the seed shop got fed up and left town.
	1: Didn't like the rain.
	1: Funny that.
END

@hasI1015
	1: What a find!
	1: Here, take this exotic leaf, I can grow more now.
	1: I'll look after this seed VERY carefully.
	1: It could be the last of its kind.
TAKE  I1015
GIVE  I1018
END

: Sandwitch
SCENE 90 bgstage2
MUSIC	waltz2.mid
	ACTOR	1,	"Sand Witch", sandWitch,  1
	POSE	1
	SEL		1
	MOVE	1,	15, 80

IF T42, @hasT42
IF I1017, @hasI1017

IF T41, @hasT41
	1: It's gone!
	1: I am lost!
	1: I only wanted to see how young and beautiful I looked!
	
END

@hasT41
	1: I need someone to go into the Maze of Glass.	
	1: I'm sure that's where it is.
	1: What?
	1: The mirror of course!
	1: Weren't you listening!
	1: Oh go away..nobody can help.
END

@hasI1017

	1: Well done %1.
	1: I think you should visit my sister in the underworld.
	1: She has used powerful magic to keep out the warlock.
	1: Nobody can get in without a password.
	1: But he cast an equally powerful spell, so she can't get out.
	1: If you break the spell and release her we will all be free.
	1: Password?...of course I know it.
	1: Oh right..sorry.....coffin.
GIVE  T42
END

@hasT42
	1: Go on-- get out there and QUEST!
END

SCENE 91 bazaar
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Cartographer", pixie  1
	POSE	1
	SEL		1
	MOVE	1,	15, 80
	
	1: Quality maps for sale!
	1: Actually a quality MAP..I only have one left.
	1: Not much call for maps to such a dangerous place.
	1: Only idiots go there by choice.
	OFFER	1014
END

SCENE 92 aztec
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Maze Keeper", pixie  2
	POSE	1
	SEL		1
	MOVE	1,	15, 80


IF I1014, @hasI1014
IF I1011, @hasI1011
	1: If you wish to enter you must have a map.
	1: I let someone in a month ago..haven't seen him since.
	1: He DIDN'T have a map.
	1: So the new rule has been introduced for your own safety.
END

@hasI1011	
	1: I suggest you ask for a refund-
	1: That map is so poorly drawn you couldn't find your way to the end of your nose.
	1: YES! That DOES mean I'm not letting you in.

END

@hasI1014
IF I99, @continue

GIVE I99
GOTO  @continue
END

@continue
	1: I'm still worried about letting you in.	
	1: So on your own head be it
WAIT  5

GOTO LINK 11,0
END


