;------------QUEST 2, THE SPACE MONSTER--------------

SCENE 20		hangar
	MUSIC vivald2.mid
	ACTOR 1 "Paul", joshtownsfolk, 13, 45, 45
	SEL		1
	IF T20, @toldhim
	IF T25, @beatmonster
	' Are you in Space Corps?
	ASK 20
	IF -YES, @saidno
	' Oh, you're a cadet, too?
	MOVE	1, 60, 70
	WAIT 2.5
	POSE 15
	' Have you heard about the space monster?
	' It's been terrorizing Space Corps for weeks.
	GIVE T20
	MOVE	1, 61, 85
	WAIT 1.5
	POSE 14
@toldhim
	' I bet you can kill it, %1!
	END
@saidno
	' Oh, just asking.
	END
@beatmonster
	' You BEAT the monster?!!
	' Whoa! Cool!
	END

;---------------------------------------------------

SCENE 21		stars
	IF T23, @weak
	MUSIC boss3.mid
	FIGHT	1, 26
	GIVE T21
	GOTO SCENE 6
	END
@weak
	MUSIC killmonster.mid
	FIGHT	1, 27
	IF LOSE, @lost
	GIVE T24
@lost
	GOTO SCENE 6
	END

;---------------------------------------------------

SCENE 22		hangar
	MUSIC mayor.mid
	IF T23, @skip
	ACTOR 1 "Mad Scientist", actorskins, 6, 35, 45
	SEL		1
	POSE 6, 8
	' How did you get in here?!
	POSE 7
	' Guards, take care of this intruder!
	POSE 6, 8
	MUSIC Boss2.mid
	FIGHT 212, 212, 212
	MUSIC #silence
	IF WON, @hewon
	' HA! Pathetic!
	END
@hewon
	' You can't destroy my power generator!
	WAIT 4.0
	SOUND boom2.wav
	' Okay, maybe you can.
	GIVE T23
	' GO AWAY!
	END
@skip
	IF T50-T52, @kefka
	END
@kefka
	IF T52, @skipall
	ACTOR 1	"Kefka",	kefka,	1,	15,	80
	ACTOR 2	"Professor J",	J,	1,	40,	45
	POSE	1,	1,	4
	POSE	2,	3,	1
	IF T51, @fight
	2: HELP ME!
	2: He put a nerd sign on my back and I can't get it off!
	1: HAHAHA!!
	GIVE T51
	H: THIS is the worst torture you can think of?
	1: Shut up!
	H: Well either give me J or face the consequences!
	1: You?! HA!
@fight
	1: You couldn't save him if you tried, you %3!
	MUSIC boss2.mid
	MOVE 	1,-10, 80
	WAIT 3.0
	FIGHT 119
	IF WON, @hewon2
	MOVE 	1,15, 80
	WAIT 2.0
	1: Lousy %3...
	END
@hewon2
	MOVE 	1,15,80
	1: ow...
	POSE	2,	12
	2: Thanks %1!
	2: Meet me back on Saturn!
	GIVE T52
@skipall
	END
	