; FICHER and LAKE
; SCENE 10 <shack>
;
SCENE 10	shop
	THEME	0
	ACTOR	1,	"Brother Joe", TownPeople, 7, 50, 90
	SEL	1
	IF T1, @CameBack
	' Welcome to my home...
	' The roof doesn't seem to keep the rain out very well...
	WAIT 5.0
	' But you are welcome to rest here, if you like.
	' You'll fing good boots to the south, In Briarton.
	' If you need Weapons, you can get them in edger.
	' You'll find an armory On the way There...
	' Just follow the road to the west, all the way to the end.
	' But be careful, the city is a dangerous place, and it is a treacherous journey. 
	' When you get back, you may want to head for the training grounds.
	' The Jellies there are pretty easy to kill.
	GIVE T1
	GOTO @Rest
@CameBack
	' You came back!
@Rest
	IF ALIVE, @HomeLiving
	' Ouch! looks like you got tore up pretty good...
	' Here.. let me fix you up... 
	WAIT	5.0
	GIVE	L1
	GIVE	H5000
	GIVE	M5000 
	' There you go! Good as new....
@HomeLiving
	GIVE	H500
	GIVE	M500
	' Well, thanks for stopping by, I don't get many visitors...
END

	
;---------
; The docks at fischerr
SCENE 11 FicherrDock
	THEME	0
	MUSIC	Vivald2.mid
	ACTOR	1,	"Boatmaster", josh21, 2, 45, 75
	SEL 1
	' Yes, I am the boatmaster...
	POSE 	3
	' What, havent you ever seen a talking lobster before?
	POSE 	6
	IF I1 @cleansfish
	IF I2 @cleansfish
	IF I3 @cleansfish
 	GOTO @noticket
@cleansfish
	' You caught some Fish!
	' Want me to clean those for you?
	ASK 10
	IF YES @looksforfish
	' No?
	' Suit yourself...
	GOTO @noticket
@looksforfish
	IF I1 @cleanssm
	IF I2 @cleansmd
	IF I3 @cleanslg
	' Ok, All clean!
	GOTO @noticket
@cleanssm
	TAKE I1
	GIVE I4
 	GOTO @looksforfish
@cleansmd
	TAKE I2
	GIVE I5
	GOTO @looksforfish
@cleanslg
	TAKE I3
	GIVE I6
	GOTO @looksforfish
@noticket
	' Sorry, we don't sell boat tickets!
	' Here is what i can offer...
	OFFER2 0,50,0
END

;---------
; Tough fish
SCENE 12 
	ACTOR	1,	"Fishing Girl", TownPeople, 28, 45, 75
	POSE 28,30
	' This is the BEST fishing spot Around!
	' I caught three REELERS Yesterday!	
END

;---------
;JELLIES
SCENE 13 
	ACTOR	1,	"Jelly Man", TownPeople, 20, 45, 75
	ACTOR	2,	"Jelly", josh4, 2,48,78
	SEL 1
 	' There are jellies of all kinds here!
	' They make Great Pets!
	SEL 2
	' ouRP!
	OFFER 401,402,403,404,405,406,407,408
END

;
;
