; 600-700 ALIEN TOKENS!
SCENE 104 Scene9, SCENE, "Alien Homeworld"
ACTOR 1, "Hk'Tu Warrior", alien, 4, 40, 60
MUSIC Introduction.mid
IF T650, @done
IF T600, @go
1: %1, you arrive at last.
1: Are you ready to begin your test of Bal'tcha? (YES/NO)
ASK 999999
IF NO, @no
H: Yes, mighty Hk'Tu, I am prepared.
GIVE T600
1: Excellent.  Go fourth into the stars, then, and squash the aliens through the warp.
1: They are to surrender or die.  Good luck, my pupil.
1: Go, now.
END
@no
1: You wish to remain the youth that you are?
1: Then go back to your mother, weakling!
END
@go
1: You return? Why! Go fourth, it is your destiny, my pupil.
END
@done
1: Hk'tu %1, I must now pass on the knowledge of our fathers to you.
1: This is a sacred art, known to only the Hk'tu.
1: Here, in the core of this very planet, we have a secret warp.
1: It leads into a place none have ever returned from, but we believe them to be well.
1: You are now Hk'tu, and may traverse through this.  It is up to you.
1: Would you like to make the final jump? (YES/NO)
ASK 999999
IF Yes, @yes
GIVE T651
1: No? It is for the Hk'tu to decide, I understand.
1: Return if you change your mind, Hk'tu.
END
@yes
1: Then I will lead you into the warp.
1: This is your last chance to change your mind, otherwise you will warp in 5 seconds.
WAIT 5.0
1: Good Luck... War...rior...
GOTO LINK 12,0,0
;----------------
SCENE 105 mamaship, SCENE, "The Mothership"
ACTOR 1, "Construction AI-Bot", crow, 4, 25, 90
MUSIC code.mid
IF T650, @done
1: The Mothership is allmost done...
1: We will all go fourth into the stars soon!
1: To not be stuck on this icecube any longer...
1: I cannot wait!
END
	@done
	1: The mothership is completed!
	1: Just a few more days and we will be on our way!
	1: Many thanks to you for clearing the way, Hk'tu %1!
END
;-----------
SCENE 106 Warp3, SCENE, "Warp to your Destiny..."
ACTOR 1, "Warp Gate Guard", Gateguard, 1, 20, 60
MUSIC jumpoints.mid
IF T650, @secondwarp
IF T600, @cont
1: Please speak with your teacher on the Home Planet!
END
@cont
1: You are ready to challenge your Bal'tcha, then?
1: Good luck.
WAIT 2.0
GOTO LINK 30,0,0
END
@secondwarp
1: You wish to warp back?  As you command..
WAIT 2.0
GOTO LINK 30,0,0
END
;-------------
SCENE 107 Warp3, SCENE, "Warp Home"
ACTOR 1, "Warp Gate Guard", Gateguard, 1, 20, 60
MUSIC jumpoints.mid
IF T650, @warp
1: Youth, you cannot return home!
1: You must earn your Bal'tcha!
1: Go fourth into the stars!
END
@warp
1: Hk'tu %1, I will activate the warp for you in 2 seconds.
WAIT 2.0
GOTO LINK 29,2,0
END
;-------------------
;T 601 here
SCENE 108 ap2, SCENE, "HT10-1"
ACTOR 1, "Congress Robot", Robo, 1, 40, 60
MUSIC evil.mid
IF T602, @602
IF T601, @601
IF KM4, @murder
1: Welcome to the planet of the Star Congress.
1: This outpost is one of the outer rim territories, we have many Pirates that come through here.
1: Please, avoid killing pirates if you can.
1: Thank you very much.
END
@murder
MUSIC evil.mid
1: Murderer!
1: You murdered those innocent pirates!
GIVE T601
@601
1: You will pay for this crime against the Star Congress!
MUSIC bof.mid
MOVE 1, 200, 200, 1
FIGHT 2,3,3,4,4,6
IF ALIVE, @lived
MOVE 1, 40, 60, 1
1: Puny fool.  Never go against our might again!
END
@lived
MUSIC shorthappy.mid
GIVE T602
1: How.. how could you.. impossible.  You will never defeat us all!
1: The Star Congress is more powerful than you could imagine!  You will never take us!
END
@602
1: You can never defeat the Star Congress!
1: Never!
END
;-------------------
SCENE 109 hangar,SCENE,"Repair Shop"
	THEME	0
	MUSIC	Wellmusic.mid
	ACTOR	1,	"Mechanic", crow, 4, 25, 90
	OFFER 350,351,352,353,800,801,802,803,900,904,909,250,251,252,253,201,202,203,204,205,1,2,3
	IF T602, @oh
	1: Welcome to the hangar.
	GIVE L1
	GIVE H6000
	GIVE M6000
	1: Please look at what I have to offer.
END
	@oh
1: I'm in this for the money... I could care less what the authorities say...
GIVE L1
GIVE H6000
GIVE M6000
1: Please look at what I have to offer.
END
;--------
SCENE 110 Warp3, SCENE, "Warp 78G"
ACTOR 1, "Warp Gate Guard", Gateguard, 1, 20, 60
MUSIC jumpoints.mid
IF T602, @warpout
1: Welcome to Warp 78G.
1: The Star Congress is expecting a shipment, so the Warp has been temporarily closed.
1: Please return later.
END
@warpout
1: ....yes... umm.. sir, I think.. we can find a way for you...
1: Please, just wait a few seconds..
WAIT 2.0
GOTO LINK 31,0,0
END
;-------
;T610+
SCENE 111 scene5, SCENE, "Rebel Base"
	ACTOR 	1, "Rebel Leader", joshTownies,	29, 20, 90
	IF T613, @613
	IF T612, @612
	IF T615, @615
	IF T614, @alive
	IF T611, @star
	IF T610, @plant
    MUSIC rebel.mid
	1: Pssst... over here...
	1: Could you help us out?
	1: I have a problem with the Starcongress planet, and I can have it taken care of.
	1: But I need someone to bring the package through for me.
	1: Could you help us out? (YES/NO)
	ASK 9999999
	IF YES, @yes
	1: No?  Coward...
END
	@yes
	1: Great.  Take this dynamite and simply goto the starcongress planet.
	GIVE T610
	@plant
	1: Once the oppurtunity presents itself, "PLANT" the bomb.
	1: Good luck.
END
	@star
	MUSIC ab.mid
	1: GUARDS!  The ship %1 has a bomb!  Stop it!
	FIGHT 7,7,10,10,8
	IF ALIVE, @alive
	1: Never attempt that again.
END
@alive
1: No.. please.. don't.. don't "PLANT" the bomb!
ASK 999999
IF Qplant, @boom
GIVE T614
1: Thank you.. thank you for sparing us!
END
@612
1: Great job, %1, thanks for destroying the base.
1: Please, take this item.
1: Thanks again.
GIVE I716
END
@boom
SOUND pain3s.wav
GIVE I716
GIVE T615
MOVE 1, 200, 200, 1
ACTOR 2, "", trans, 2, 30, 70
WAIT .2
BKGND white
MOVE 2, 40, 30, 1
ACTOR 3, "", trans, 2, 50, 40
WAIT .2
BKGND Scene7
MOVE 2, 50, 60, 1
MOVE 3, 10, 20, 1
WAIT .2
ACTOR 4, "", trans, 2, 30, 20
MOVE 2, 30, 70, 1
MOVE 3, 70, 30, 1
MOVE 4, 20, 60, 1
WAIT .2
BKGND Scene7
ACTOR 5, "", trans, 2, 30, 80
MOVE 2, 30, 70, 1
MOVE 3, 70, 90, 1
MOVE 4, 20, 30, 1
MOVE 5, 80, 10, 1
WAIT .2
ACTOR 6, "", trans, 2, 40, 50
BKGND white
MOVE 2, 20, 30, 1
MOVE 3, 50, 70, 1
MOVE 4, 10, 20, 1
MOVE 5, 56, 20, 1
MOVE 6, 20, 30, 1
WAOT .2
ACTOR 7, "", trans, 2, 40, 50
ACTOR 8, "", trans, 2, 80, 20
MOVE 2, 200, 200, 1
MOVE 3, 200, 200, 1
MOVE 4, 200, 200, 1
MOVE 5, 200, 200, 1
MOVE 6, 200, 200, 1
MOVE 7, 200, 200, 1
MOVE 8, 200, 200, 1
MOVE 1, 60, 50, 1
BKGND scene7
1: Noooooooo....
WAIT 2.0
MOVE 1, 200, 200, 1
BKGND white
@615
MOVE 1, 200, 200, 1
BKGND white
END
@613
1: Great job, %1, thanks for destroying the Starcongress base.
1: Please, take this item.
1: Thanks again.
GIVE I716
END
;----
;-----
SCENE 112 black, SCENE, "Starcongress Base"
IF T613, @613
BKGND scene7
ACTOR 1, "Starcongress Official", act2, 3, 20, 90
IF T614, @614
IF T612, @alive
IF T611, @plant
IF T610, @rebel
MUSIC Jail.mid
1: Welcome to the Base.
1: We have a small.. problem.  The rebels, you see.. they are a constant annoyance.
1: If you could help us out, we would be much obliged. (YES/NO)
ASK 999999
IF YES, @yes
1: No? Coward.
END
@614
1: Great job, %1, thanks for destroying the rebel base.
1: Please, take this item.
1: Thanks again.
GIVE I716
END
@yes
@plant
MUSIC Jail.mid
1: Excellent.  Simply take this bomb and "PLANT" it at the earliest oppurtunity.
GIVE T611
1: Thank you, and good luck.
END
@rebel
MUSIC ab.mid
1: Wha.. are.. GUARDS!  THIS SHIP HAS A BOMB!  TAKE HIM!
FIGHT 50,50,51
IF ALIVE, @alive
1: Never try to harm the Star Congress again!
END
@alive
1: No.. please.. don't.. don't "PLANT" the bomb!
ASK 999999
IF Qplant, @boom
GIVE T612
1: Thank you.. thank you for sparing us!
END
@boom
SOUND pain6s.wav
GIVE I716
GIVE T613
MOVE 1, 200, 200, 1
ACTOR 2, "", trans, 2, 30, 70
WAIT .2
BKGND white
MOVE 2, 40, 30, 1
ACTOR 3, "", trans, 2, 50, 40
WAIT .2
BKGND Scene7
MOVE 2, 50, 60, 1
MOVE 3, 10, 20, 1
WAIT .2
ACTOR 4, "", trans, 2, 30, 20
MOVE 2, 30, 70, 1
MOVE 3, 70, 30, 1
MOVE 4, 20, 60, 1
WAIT .2
BKGND Scene7
ACTOR 5, "", trans, 2, 30, 80
MOVE 2, 30, 70, 1
MOVE 3, 70, 90, 1
MOVE 4, 20, 30, 1
MOVE 5, 80, 10, 1
WAIT .2
ACTOR 6, "", trans, 2, 40, 50
BKGND white
MOVE 2, 20, 30, 1
MOVE 3, 50, 70, 1
MOVE 4, 10, 20, 1
MOVE 5, 56, 20, 1
MOVE 6, 20, 30, 1
WAOT .2
ACTOR 7, "", trans, 2, 40, 50
ACTOR 8, "", trans, 2, 80, 20
MOVE 2, 200, 200, 1
MOVE 3, 200, 200, 1
MOVE 4, 200, 200, 1
MOVE 5, 200, 200, 1
MOVE 6, 200, 200, 1
MOVE 7, 200, 200, 1
MOVE 8, 200, 200, 1
MOVE 1, 60, 50, 1
BKGND scene7
1: Noooooooo....
WAIT 2.0
MOVE 1, 200, 200, 1
BKGND white
@613
MOVE 1, 200, 200, 1
BKGND white
END
;----
SCENE 113 Warp1, SCENE, "Warp Beta-I"
ACTOR 1, "Warp Gate Guard", Gateguard, 1, 20, 60
MUSIC jumpoints.mid
IF E716, @warp
IF E718, @warp
1: You must have a Mach 2 Engine equipped to attempt this warp.
END
@warp
1: Warping in 1 second...
WAIT 2.0
GOTO LINK 32,3,0
END
;----------
;T620-X
SCENE 114 black, CUT, "Transmission"
IF T620, @goto
MUSIC Introduction.mid
BKGND bridge
ACTOR 1, "Hk'Tu Warrior", alien, 4, 40, 60
1: Good work, my pupil.  You have made it this far.
1: Below, you see the planet Likeria.  We must have a forward base constructed there.
1: Build a teleportation device for inter-system movement of our troops once we arrive.
1: Gather the necessary materials from the locals peacefully.  They must not know we are coming.
1: Good luck.  You are allmost ready to become a Hk'Tu!
GIVE T620
@goto
GOTO LINK 33,0,0
END
;----------
SCENE 115 giza2, SCENE, "Local's Hut"
Actor 1, "Local", huy, 1, 40, 60
MOVE 1, 39, 60
MUSIC mic.mid
IF T622, @heal
IF T621+KM200.10, @thanks
IF T621, @yes
1: Stranger.... do you think, perhaps, you could, maybe, help me out?
1: These old robots, I call them firebots, keep attacking my village.
1: I lack the weapons to stop them, could you please help me out? (YES/NO)
ASK 99999
IF YES, @yes
1: No? please, come back and reconsider some day..
END
@yes
GIVE T621
1: You have currently only killed #<KM.200> Firebots.
1: When you kill ten I'll give you an engine.
GIVE L1
GIVE H6000
GIVE M6000
END
@thanks
1: Thank you for that, kind %2.  Please, take my gifts.
GIVE I718
GIVE T622
GIVE L1
GIVE H6000
GIVE M6000
1: Come back if you ever need me to heal you again.
END
@heal
GIVE L1
GIVE H6000
GIVE M6000
1: Thank you for helping me, %1.
END
;-------
SCENE 116 rome1, SCENE, "Local's Hut"
ACTOR 1, "Local", kl, 1, 40, 60
MOVE 1, 39, 60
music mic.mid
IF T627, @thanks
IF T626, @yay
IF T625, @water
1: Hello... umm.. do you think you could *cough* help.. me out?
1: Could *cough*...
1: Excuse me.  Could you go to the oasis, and, fetch me some water?
GIVE T625
1: I ran out, and I am afraid I do not have the energy to make the trek myself.
1: *cough*
1: Thank you...
END
@water
1: Please.. *cough*... Water...
END
@yay
1: Thank you!
1: Thank you very, very much!
1: Here, I found this gigantic shiny ball lying in the desert.  You can have it.
GIVE T627
GIVE L1
GIVE H6000
GIVE M6000
END
@thanks
1: Thank you!
GIVE L1
GIVE H6000
GIVE M6000
END
;--------
SCENE 117 wetMesa3, SCENE, "Oasis"
ACTOR 1, "Fish", joshAnimals, 12, 30, 50
MUSIC sub.mid
1: GLUB!
1: So, you need Water?
1: GLUB!
1: Everyone Allways wants water from ME!
1: As if *I* have all of the water in the WORLD!
1: Water doesn't grow on trees, you know!
1: I'm afraid I'll have to charge you for this water, Mr. %1!
1: 3,000!  No less! (YES/NO)
ASK 99999
IF YES, @yes
1: No? Cheap! CHEEAAPPP!
1: I ask a mear 3,000 for this ideal water, and you turn me down..
1: GLUB!
1: GLUB YOU!
1: GLLLUUUBBB!
END
@yes
IF G3000, @cont
1: YOU were trying to RIP ME OFF!
1: WEREN'T YOU!
1: You thought "Ha.. stupid fish.  I only have 2,500, but if I give it all to him, he won't notice!"
1: Well, he DID!
1: GLUB!
1: GLUBBBBB YOUU!
1: GLUBB GLUBB GLUBB!
END
@cont
TAKE G3000
GIVE T626
1: There, I gave you the water.
1: You'll have to take my word on this one, because the guy who put me here is too lazy to draw a picture.
1: So this is actually imaginary water, but you can still acomplish your quest with it.
1: Stop Looking at me like I'm not real!
1: I have a heart and soul, too!
1: Ask me anything!... you'll see!
WAIT 6.0
1: Assuming you just really did that, you just made a fool of yourself!
1: Ahhh...hahahahhaha...
1: Never trust a fish!
END
;--------
SCENE 118 alien, SCENE, "Teleportation Unit"
IF T630, @done
ACTOR 2, "Desert Beast", desert9, 1, 40, 30
MUSIC ded.mid
2: Enemy.. detected...
2: Engaging Defencive Capabilities...
MOVE 2, 200, 200, 1
FIGHT  192, 194, 196, 201
IF ALIVE, @next
MOVE 2, 50, 40, 1
2: Defences.... deactivated.
END
@next
MOVE 2, 200, 200, 1
GIVE H400
GIVE M100
FIGHT 196,194, 201, 194
IF ALIVE, @next2
MOVE 2, 50, 30, 1
2: Defences... deactivated.
END
@next2
MOVE 2, 200, 200, 1
FIGHT 196, 196, 201, 201, 196
IF ALIVE, @won
MOVE 2, 50, 40, 1
2: Defences.... deactivated.
END
@won
MOVE 2, 40, 50, 1
2: Defences... surpassed.  Ownership transfered.
2: Sir, you are now in command of this building.  Build what you will.
MOVE 2, 200, 200, 1
ACTOR 1, "Computer"
GIVE T630
1: Terminals.. online.
1: Transdimensional Capabilities.. online.
1: Updated Cartogyrein Drivers.. online.
1: Aliensoft Walls ME.. loading...
1: ...loading...
1: All systems online.
1: Incoming message from Hk'tu...
MUSIC Introduction.mid
BKGND bridge
ACTOR 3, "Hk'Tu Warrior", alien, 4, 50, 60
3: Excellent work, my apprentence.  Now, only one obstacle stands between you and your Bal'tcha.
3: The system of Evergreen must be taken.  Go fourth.  This will not be easy for you, I am afraid.
3: Good luck, %1.
END
@done
MUSIC ded.mid
END
;--------
SCENE 119 Scene10, SCENE, "Warp to Evergreen"
ACTOR 1, "Warp Gate Guard", Gateguard, 1, 20, 60
MUSIC jumpoints.mid
IF E718+T630, @warp
IF E718-T630, @nogo
1: You must have a Mach 3 engine equipped to enter this warp.
END
@nogo
1: There has been an odd energy flux within the warp.
1: No ships are being allowed to pass until future notice.
END
@warp
1: Prepare to warp in 3 seconds...
WAIT 3.0
GOTO LINK 34,3,0
END
;-------
SCENE 120		lance2,SCENE,"Evergreen"
	MUSIC	Introduction.mid
	ACTOR	1,	"Alpha T-37", greetrobot, 1, 25, 90
	ACTOR 2, "Computer"
	IF T650, @done
	1: Welcome to th... What... wha... What are you?
	H: I have come to eliminate you.  Prepare yourself.
	1: Wa... no!  Gu..Gu.. Guards!
	MOVE 1, 200, 200, 1
MUSIC ded.mid
	FIGHT 185,185,184,184,183
	IF ALIVE, @second
	MOVE 1, 50, 60, 1
	1: You will never defeat human kind!
END
	@second
MUSIC bof.mid
	2: Second wave incoming!  ETA 5 seconds!
	WAIT 6.0
	FIGHT 185, 185, 184, 184, 181, 183
	IF ALIVE, @three
	MOVE 1, 50, 60, 1
	1: Human Kind will defeat you!
END
	@three
MUSIC ab.mid
	2: Final wave incoming!  5 seconds ETA! Brace yourself!
	WAIT 6.0
	FIGHT 185,185,183,185,184,183
	IF ALIVE, @won
	MOVE 1, 30, 60, 1
	1: The fleet is victorious!
END
	@won
	MUSIC Victory.mid
	GIVE T650
	1: How could you have possibly defeated our fleet??
	1: It.. it cannot be!
	1: Great.. great.. sir..
	2: <-<-<-<>INCOMING TRANSMISSION<>->->->
@done
	MOVE 1, 200, 200, 1
	BKGND bridge
	ACTOR 3, "Hk'Tu Warrior", alien, 4, 40, 60
	3: You have achieved your Bal'tcha.  Please, return to your home.  Our fleets will be moving in.
	3: You have done an excellent job, Hk'tu %1.
END
;--------
SCENE 126, giza5, SCENE, "Desert Shop"
MUSIC shop2.mid
ACTOR 1, "Local", JoshTownsfolk, 12, 40, 60
OFFER 3,4,5,211,212,241,242,243,244,245,357,358,359,360,361,362,363,364,365,366,367,809,810,811,812,813,814,37,38,836
GIVE L1
GIVE H6000
GIVE M6000
1: Hey.  My twin over at the other Desert Shop sells all sorts of stuff.
END
;-------
SCENE 127, giza4, SCENE, "Desert Shop"
MUSIC Wellmusic.mid
ACTOR 1, "Local", JoshTownsfolk, 12, 40, 60
OFFER 842,845,848,851,854,913,914,915,916,917,274,275,276
GIVE L1
GIVE M6000
GIVE H6000
1: Hey.  My twin over at the other Desert Shop sells all sorts of stuff.
END
;---------------