; Earth Class.  Tokens 700 and greater
SCENE 121 cop, SCENE, "Court Room"
ACTOR 1, "Judge and Jury", act, 3, 40, 70
ACTOR 2, "Guard", greetrobot, 1, 40, 95
ACTOR 3, "Guard", greetrobot, 1, 40, 45
MUSIC code.mid
1: %1, you are accused of High Treason against the Earth Council.
1: How do you plead? (INNOCENT or GUILTY)
@ask
ASK 999999
IF Qinnocent, @inn
IF Qguilty, @guilty
1: INNOCENT or GUILTY???
GOTO @ask
END
@inn
H: Innocent, sir.
1: So be it.  Prosecuter, please bring fourth your evidence.
ACTOR 4, "Prosecuter", huy, 1, -10, 110
MOVE 4, 70, 70, 1
4: Yes, My Judge.  It is simple.  The suspect, %1, was saw doing all the wrongs.
1: ALL the wrongs?
4: Yes, all the wrongs in the known universe.
1: Mr. %1, what do you have to say for yourself?
1: ..... Nothing?  As I thought.  I sentence you to BANISHMENT!
1: If you wish to see Earth again, you must report on the spacestation immediatly!
1: Good Day, %1.
GOTO LINK 36,0,0
END
@guilty
H: Guilty, sir.
1: So be it.  I sentence you to Military Service.  Please report to the Spacestation tommorow.
1: Good Day, %1.
GOTO LINK 36,0,0
END
;--------------
SCENE 122 ice, SCENE, "Conversation"
ACTOR 1,"Bob", joshTownies, 7, 40, 70
MUSIC AHS.mid
IF T700, @talk
1: Hey... you just woke up I guess.
GIVE T700
1: You hear the announcement?  Your hearing is going to be in just a few minutes..
COUNTDOWN 60
1: And that was a few minutes ago....
1: Make sure you come talk to me before you leave..
IF XP, @cops
END
@talk
IF XP, @cops
1: Good Luck, %1.
@XP
WAIT .5
IF XP, @cops
GOTO @XP
WAIT 1.0
END
@cops
1: Looks like its time to say goodbye.
1: I'll see you around, %1.
ACTOR 2,"Cop", act, 4, 50, 70
ACTOR 3,"Cop, act, 4, 50, 80
2: No, actually, you probably won't.  It's time for your trial, comeon, %1.
WAIT 2.0
GOTO SCENE 121
WAIT 5.0
2: ...uhh.. there must be a bug in the script.
2: Yell at Dan to fix it.
END
;---------------
SCENE 123 jaord, SCENE, "Earth"
ACTOR 1, "Warpgate Guard", gateguard, 1, 50, 70
1: You have been banished.  You are not allowed to land on the earth.
END
;------------
;T 710
SCENE 124 prodfac, SCENE, "Spacestation"
ACTOR 1, "Officer", act, 3, 60, 70
MUSIC cop.mid
GIVE L1
GIVE M6000
GIVE H6000
IF T756, @756
IF T755, @hlh
IF T731, @731
IF T730, @ty
IF T728, @now
IF T727, @reb
IF T720, @weq
IF T713, @ye
IF T712, @next
IF T710, @go
1: %1, at attention!
1: You are the slimiest of the slime, being banished from earth!  
1: YOU must prove yourself to ME before you are going ANYWHERE.
1: Is that clear, Private??
1: GOOD!  Now, I will activate the training warp!
GIVE T710
1: You can now purchase LOW level weapons from the spacestation.
OFFER 1,2,3,201,202,203,204,300,301,302,303,800,801,802,803,900,904,909,250,251,252
1: Understood? GOOD!  Go, now, Private!
1: Move, move, move!
END
@go
OFFER 1,2,3,201,202,203,204,300,301,302,303,800,801,802,803,900,904,909,250,251,252
1: Go to the training warp immediatly, private!
1: Go! Go! Go!
END
@next
OFFER 1,2,3,201,202,203,204,300,301,302,303,800,801,802,803,900,904,909,250,251,252
1: So, Cadet, your made of more than the wrong doing little %3 I thought you were!
1: Good.  You are to go to the planet Liot where we are currently assaulting a Rebel Outpost.
1: You can outfit your ship at a Merchant Outpost on the planet Rewag there.
1: Go and assist the fleet, Cadet!
GIVE T713
END
@ye
OFFER 1,2,3,201,202,203,204,300,301,302,303,800,801,802,803,900,904,909,250,251,252
1: Go, Cadet!  We don't have all day!
END
@weq
OFFER 2,3,4,215,216,217,218,219,310,311,312,313,314,315,316,317,812,814,816,817,818,842,845,848,851,854,913,914,915,916,917,257,258,259
1: Good Job, Cadet.  You can now purchase additional weapons from the Spacestation.
1: Your next mission is to go into the Tyre System and land on the planet Tyre.
1: There, you are to neutralize an on-planet threat.  Talk to Coronel Lenny.
END  
@reb
OFFER 2,3,4,215,216,217,218,219,310,311,312,313,314,315,316,317,812,814,816,817,818,842,845,848,851,854,913,914,915,916,917,257,258,259
GIVE T728
1: WHAT?  YOU DISABLED OUR FACTORIES ON TYRE!!
1: HE... TOLD YOU TO!
1: He must be a traitor!
1: Your new mission is to land on the planet and destroy those pesky Rebels!
1: Go, %1!
END
@now
OFFER 2,3,4,215,216,217,218,219,310,311,312,313,314,315,316,317,812,814,816,817,818,842,845,848,851,854,913,914,915,916,917,257,258,259
1: Go, Private!
END
@ty
1: Good work.  We were able to get the factories back on line and operational.
1: You now have one more mission before you, %1.
1: This will not be easy, and you may even earn a one way ticket to freedom.
GIVE T731
@731
OFFER 2,3,4,215,216,217,218,219,310,311,312,313,314,315,316,317,812,814,816,817,818,842,845,848,851,854,913,914,915,916,917,257,258,259
1: I am activating the warp.  Talk to Captain Relit on the Flagship Nesbil for further instructions.
1: Command out.
END
@hlh
OFFER 2,3,4,215,216,217,218,219,310,311,312,313,314,315,316,317,812,814,816,817,818,842,845,848,851,854,913,914,915,916,917,257,258,259
1: Excellent, %1.  You have earned your freedom.
1: ...however, you still may not return to earth.
1: I am sorry, but this is not my choice. It comes from the President herself.
1: You do, though, have one other option than to roam the universe.
GIVE T756
1: I am not supposed to do this, but I will make an exception for you.  I am opening the Warp in the Tyre system.
1: Noone knows where this warp leads.  Noone has ever returned from it.
1: However, it is said that many have seen flashes of a "Wonderful Light" from within it.
1: I leave it up to you, %1.
END
@756
OFFER 2,3,4,215,216,217,218,219,310,311,312,313,314,315,316,317,812,814,816,817,818,842,845,848,851,854,913,914,915,916,917,257,258,259
1: It is up to you, %1.
END
;-----------
;T711
SCENE 125 scene9, SCENE, "Isebrrg"
ACTOR 1, "Drill Sergeant", act3, 3, 50, 70
MUSIC Introduction.mid
IF T712, @done
IF T711, @numberleft
1: PRIVATE! PAY ATTENTION!
1: YOUR FIRST MISSION IS SIMPLE ENOUGH, YOU PUNY NERF-HEARDER!
1: SIMPLY GO OUT THERE AND KILL A FEW OF THOSE TRAINING DUMMY SHIPS!
GIVE T711
1: COME HERE AT ANY TIME TO SEE HOW WELL YOUR DOING!
1: NOW GET TO WORK, PRIVATE!
END
@numberleft
GIVE L1
GIVE M6000
GIVE H6000
SET e1, 5
SUB e1, #<KM.1>
SET e2, "5"
SUB e2, #<KM.2>
SET e3, "5"
SUB e3, #<KM.3>
SET e4, "5"
SUB e4, #<KM.4>

SET e5, "5"
SUB e5, #<KM.5>
SET e6, "5"
SUB e6, #<KM.6>
SET e7, "8"
SUB e7, #<num.hostLevel>
;----------
COMPARE #<e1>, 0
IF> @training
COMPARE #<e2>, 0
IF> @training
COMPARE #<e3>, 0
IF> @training
COMPARE #<e4>, 0
IF> @training
COMPARE #<e5>, 0
IF> @training
COMPARE #<e6>, 0
IF> @training
COMPARE #<e7>, 0
IF > @training
@done
1: Excellent, Private! You have killed the required training bots!
1: Return to the spacestation for your next assignment!
GIVE T712
END
@training
1: You have not completed the mission!
COMPARE #<e7>, 0
IF= @l
IF< @l
1: You still need to gain #<e7> levels.
@l
1: You still need to kill:
COMPARE #<e1>, 0
IF= @1
IF< @1
1: #<e1> Peashooters
@1
COMPARE #<e2>, 0
IF= @2
IF< @2
1: #<e2> Lighters
@2
COMPARE #<e3>, 0
IF= @3
IF< @3
1: #<e3> Dark Fighters
@3
COMPARE #<e4>, 0
IF= @4
IF< @4
1: #<e4> Pirate Cruisers
@4
COMPARE #<e5>, 0
IF= @5
IF< @5
1: #<e5> Jakt Attack Ship's
@5
COMPARE #<e6>, 0
IF= @6
IF< @6
1: #<e6> Discoveries.
@6
1: Return when you have killed them all!
END
;--------
SCENE 130, Jaord, SCENE, "Liot"
MUSIC ab.mid
IF T720, @done
FIGHT 8, 7, 7, 10, 10, 13, 11, 11, -15, -15
IF ALIVE, @won
GOTO EXIT
END
@won
MUSIC shorthappy.mid
ACTOR 1, "Earth Cruiser", rebel1, 1, 30, 70
GIVE T720
@done
1: Cadet, get back to the Spacestation.  Good Fighting out there.
END
;-------
SCENE 131, fort, SCENE, "Guardpost"
MUSIC BG3starsystem.mid
IF T730, @won
IF T731, @fighting
IF T728, @found
IF T726, @winit
IF T725, @work
ACTOR 1, "Rebel", joshTownsfolk, 1, 60, 60
MOVE 1, 59, 60
ACTOR 2, "Rebel", joshTownsfolk, 2, 50, 60
1: If you were to say... give this game to 300 people, what would that do?
2: Yes, what would that do indeed?
1: In the name of English Science, we shoul... oh my!
1: He's here!  Quick, into charachter!
MOVE 1, -200, 200
MOVE 2, -200,-200
WAIT 7.0
ACTOR 3, "Corporal Lenny", act, 3, -10, 60
MOVE 3, 40, 50
ACTOR 4, "Guard", army2, 1, -20, 60
MOVE 4, 30, 50
3: Uhh.. *cough*.. %1! We.. we've been.. *cough*.. expecting you!
3: We have a very important... uhh...
4: Mission!
3: Yes, uh, mission for you!
3: We.. no longer need those Imperial Factories, they're... defunct.
3: But, theres this automatic defence thing.
3: And we don't know the...
4: We FORGOT! 
3: Right, we forgot the code.  So, uh, get to work, Private!
GIVE T725
END
@work
ACTOR 3, "Corporal Lenny", act, 3, 50, 60
ACTOR 4, "Guard", army2, 1, 40, 60
3: Hop to, Cadet!
END
@winit
ACTOR 3, "Corporal Lenny", act, 3, 50, 60
ACTOR 4, "Guard", army2, 1, 40, 60
3: Uhh.. excellent work.. uhh.. %1.
3: Now we can reprogram those factories to work...
GIVE T727
3: I mean, to self destruct.
3: You can.. return.. to base now, %1.
4: Move along...
END
@found
ACTOR 3, "Corporal Lenny", act, 3, 50, 60
ACTOR 1, "Rebel", joshTownsfolk, 1, 60, 60
Move 1, 59, 60
1: So, all we have to do is turn the factories back on and... who are you?
3: Who, me? 
1: No, you idiot, its %1!
3: Ohh.. uhh.. *cough* %1!  You need to return to the base and sign up for your new duty.
3: Unless...
1: Oh... no...
3: HIT THE DECKKK!!!
BKGND white
SOUND pains7.wav
wait .5
@fighting
MUSIC bof.mid
GIVE T731
MOVE 1, 200, 200, 1
MOVE 3, 200, 200, 1
BKGND fort
ACTOR 2, "Defence Bot", oil, 1, 30, 60
MOVE 2, 29, 60
2: Explosion detected... Defences Activated.
FIGHT 171, 171, 171, 166, 166, 169
IF ALIVE, @more
2: Defence Complete.
END
@more
MUSIC b4.mid
2: Calling.. reinforcements..
FIGHT 171, 171, 169, 169, 169, 166
IF ALIVE, @last
2: Defence Complete.
END
@last
MUSIC bof.mid
2: Engaging.. Enemy..
MOVE 2, 200, 200, 1
FIGHT 71, 171, 171, 171, 169
IF ALIVE, @won
1: Enemy Defeated.
END
@won
IF -T730, @ugh
END
@ugh
GIVE T730
END


;-----------------
SCENE 132, np1t, SCENE, "Earth Mining Factory Site"
MUSIC evil.mid
IF T726, @nomore
ACTOR 1, "Guardbot", desert9, 3, 40, 50
1: Personel.. Detected...
1: Enter.. clearance code...
1: You have 5 seconds to comply...
1: Just kidding.. ha..ha.. there is no code.. you have to fight..
1: Defences activating.  Defences activating.
1: Warning... Warning...
MOVE 1, 200, 200, 1
MUSIC ab.mid
FIGHT 166, 165, 165
MOVE 1, 50, 70, 1
IF ALIVE, @more
1: Defences... powerdown...
END
@more
MUSIC b3.mid
1: Personel... Detected..
1: You have... comply!
1: 3.!
1: Defen.. actv!
MOVE 1, 200, 200, 1
FIGHT 166, 166, 165, 166
MOVE 1, 50, 70, 1
IF ALIVE, @done
1: Defences.. powerdown...
END
@done
MUSIC shorthappy.mid
MOVE 1, 50, 70, 1
1: PerSOnelell DEtective!
1: You COmplYI!
1: ^%3^98!
1: DE@$!
1: {Shock} {Shock}
1: Poweerrrrddddddooooowwwwwnnnnn....
MOVE 1, 200, 200, 1
GIVE T726
@nomore
END
;-----
SCENE 133, bwCourtHouse, SCENE, "Living Chambers"
IF S751, @sleep
MUSIC shop2.mid
ACTOR 1, "Mr. Bennet", JoshTownsfolk, 17, 50, 70
IF T741, @milk
1: %1, I seem to have a small problem..
1: I can't fall asleep without a glass of milk, and yet none is to be found.
1: And because I'm a computer generated being that doesn't really exist, I can't even go to the store!
GIVE T740
1: Could you please find me a glass of milk?
END
@milk
1: Thank you, %1.. I think I can finally get some sleep now...
1: In return, I'll teach you this skill I picked up a while ago..
GIVE S751
1: ... Thank you again.. *Yawn*
MOVE 1, 200, 200
END

;------
SCENE 134, neonDiner, SCENE, "Bar"
MUSIC Wellmusic.mid
ACTOR 1, "Josaphine", joshTownsfolk, 32, 50, 70
OFFER 100, 101, 102, 103
GIVE L1
GIVE M6000
GIVE H6000
IF T740-T741, @milk
1: How ya doin, sweety pie?
IF T726-T730, @bad
END
@bad
1: That bad, eh?  Must be hard... good luck with those rebels.
1: Too bad, they gave me some good buisness down 'ere..
END
@milk
1: Ya need some milk?
1: Its rare down here, I'm afraid.. it'll cost you something huge.
1: 5,000 Gold.  We got a deal? (YES/NO)
ASK 9999
IF YES, @y
1: Nah? Don't blame ya.. 'spensive stuff.
END
@y
IF G5000, @buy
1: You trying to rip me off? I said 5,000 and you don't even have it!
END
@buy
TAKE G5000
GIVE T741
1: There ya go sugar.
END
;-------------
SCENE 135, warp1, SCENE, "Stargate Beta-1"
MUSIC jumpoints.mid
ACTOR 1, "Warpgate Guard", gateguard, 3, 50, 70
MOVE 1, 3, 49, 70
1: Good luck, %1...
WAIT 2.0
GOTO LINK 42,0,0
END
;------------
SCENE 136, mamaship, SCENE, "Flagship"
MUSIC AfterWorld1.mid
ACTOR 1, "Captain Relit", joshRoyalty, 2, 50, 70
IF T755, @thanks
IF T752, @shop
IF T753, @coon
IF T751, @fight
1: Cadet %1, we are in need of your help.  When we built this warp, we sent this ship through.  Ever since...
1: .. Ever since.. we have been defending Earth from constant attacks from the Aliens.
1: We must end this by decimating their home planet.  I will...
ACTOR 2, "Computer"
2: Warning!  Enemy Fleet Incoming!
GIVE M6000
GIVE H6000
GIVE T751
BKGND mamashipr
1: %1, I call on your services.  We have a small alien fleet incoming, help us defend ourselves!
COUNTDOWN 60
@fight
IF XP, @po
GOTO @fight
END
@po
1: Here they come!
GIVE L1
GIVE H6000
GIVE M6000
MOVE 1, 200, 200, 1
MUSIC bof.mid
FIGHT 108, 108, 108, -184, -184
IF ALIVE, @won
1: Oh no!
END
@won
MUSIC AfterWorld1.mid
MOVE 1, 50, 70, 1
1: Great job, %1.
GIVE L1
GIVE M6000
GIVE H6000
1: Now, to the matter at hand.  The Alien homeworld is very well defended, 
1: Computer, bring up vid-sat 1.
WAIT .5
GOTO SCENE 137
WAIT .5
END
@coon
1: So, cadet, its going to be up to you.  We will be sending in some backup for you, of course.
1: Here, we will let you purchase new items from the ships onboard store.
1: Good luck.
OFFER 3,4,5,6,219,220,221,317,318,319,320,818,819,820,843,846,849,852,855,917,918,919,260
Give T752
END
@shop
OFFER 3,4,5,6,219,220,221,317,318,319,320,818,819,820,843,846,849,852,855,917,918,919,260
1: Good luck, %1.
GIVE L1
GIVE M6000
GIVE H6000
END
@thanks
OFFER 3,4,5,6,219,220,221,317,318,319,320,818,819,820,843,846,849,852,855,917,918,919,260
GIVE L1
GIVE M6000
GIVE H6000
1: Thank you!
1: Excellent, Excellent work %1!
1: I have reported your work to the spacestation, They will recognize you there.
1: Great job, %1!  You have ensured the future of the planet earth!
END
;-------
SCENE 137 ap2, CUT, "Vid-Sat 1"
ACTOR 1, "Captain Relit"
ACTOR 2, "Computer"
ACTOR 3, "", alien1, 40, 50
ACTOR 4, "", alien1, 50, 50
ACTOR 5, "", alien15, 60, 70
ACTOR 6, "", alien6, 70, 40
ACTOR 7, "", alien1, 70, 80
ACTOR 8, "", alien1, 20, 40
ACTOR 9, "", alien15, 20, 30
MOVE 6, 200, 200
MOVE 3, 40, 50, 1
MOVE 4, 50, 50, 1
MOVE 5, 60, 70, 1
MOVE 7, 70, 80, 1
MOVE 8, 20, 40, 1
MOVE 9, 200, 200
1: As you can see, the defences are quite large, and more are bound to be nearby for them to call on.
1: Unfortuanatly, the light cruisers have very high powered scanners equipped on board.  They'll know your coming.
GIVE T753
WAIT 3.0
GOTO SCENE 136
WAIT .5
END
;-----
SCENE 138, ap2, SCENE, "Alien Homeworld"
IF T755, @no
IF T753, @cont
ACTOR 1, "Computer"
@no
1: No lifeforms detected.
END
@cont
MUSIC bof.mid
FIGHT 105, 105, 106, 106, 108, 108, -186, -185
IF ALIVE, @next
END
@next
MUSIC ab.mid
FIGHT 105, 105, 106, 106, 106, 105, 106, 105, 108, 108, -186, -185, -186
IF ALIVE, @next2
END
@next2
MUSIC ded.mid
FIGHT 111, 111, 119, 106, 105, 106, 105, ,111, 119, 111, 119, -186, -186, -185
IF ALIVE, @won
END
@won
MUSIC victory.mid
GIVE T755
GOTO LINK 42, 2, 1
END
;---
