; PIRATE STORYLINE: Tokens 500-600
; USE MARKERS BEFORE EACH QUEST SEQUENCE, DAMNIT!
SCENE 87 prodfac, SCENE, "Station XT-1"
ACTOR	1, "Alpha T-37", oil, 1, 25, 90 
MOVE 1, 24, 90
	MUSIC	Introduction.mid
	IF T500, @return
	' Welcome to the spacestation, scumbag.
	' Being the weakling that you are, I suppose you'll need to know about the universe your in.
	' So, little one, do you need to waste my time? (YES/NO)
	ASK 9999
	IF +Yes, @yes
	' No?  Good thing.
	GIVE T500
	GOTO @return
	@yes
	' You want the info, huh?  Well, in this galaxy, you have to travel to different places using warps.
	' Some of these 'warp points' require different engines, some do not.
	' A few even require that you have higher levels of ship!  But these are very rare.
	' Note that everything is harder to do in space, out here it isnt any of that whimpy stuff like Evergreen..
	' Do you want me to waste even *more* of my precious time and repeat myself? (YES/NO)
	IF Yes, @yes
	' Good.
	GIVE T500
	@return
	GIVE L1
	GIVE H6000
	GIVE M6000
	' Allways coming back for additional repairs, %1....
	' One day I'll start charging you for it!
END
;----------------
	SCENE 88 scene10, SCENE, "Warp Point 45T"
	ACTOR 1, "Warpgate Guard", gateguard, 4, 30, 70
	MUSIC   Jumpoints.mid
 	IF T501, @warp
	IF T500, @went
	1: In order to enter this warp, you must have spoken to the robot at Station XT-1.
	1: Please go there and return when you have.
END
	@went
	1: Welcome to Warp 45-T.  Here, you can warp to the Weqin Sector.
	1: Unlike this sector, it is completely lawless.  Once you go through this warp, you can be hurt.
	1: Do you still want to go? (YES/NO)
	ASK 999999
	IF YES, @yes
	1: No? Okay.  Return when you are ready.
END
	@yes
	GIVE T501
	@warp
	1: Warping in 2 seconds.
	WAIT 2.0
	GOTO LINK 23,0,0
END
;----------------
; TOKEN 502-4
	SCENE 89 ice, SCENE, "Egit"
	MUSIC	port.mid
	IF T504, @danish
	ACTOR 1, "Message Pod", crow, 2, 30, 70
	IF T503, @leave
	IF I97, @d
	IF T502, @m
	1: MESSAGE FOR %1.
	1: TRANSMIT_START_1: %1, I have a.... job for you.
	1: A small ship recently escaped from my base with a... important file of mine.
	1: Do me a favor and hunt him down for me? 
	1: Just fight ships around this sector, one is sure to drop it..
	GIVE T502
	1: Once you have the item, bring it back to this message probe and the probe will give you your reward.
	1: Good luck, %1.
	1: MESSAGE_END.
END
	@m
	1: You do not have the item.
	1: Please return when you have found it.
END
	@d
	1: You have the item.  Give it to me now.
	TAKE I97
	GIVE T503
	1: Thank you.  Please wait while I find your reward..
	1: GIVE_REWARD
	GIVE T504
	GIVE G5000
	GIVE I716
	1: Thank you.  
	1: CODE_HOME
	MOVE 1, -200, -200
END
	@leave
	1: GIVE_REWARD
	GIVE T504
	GIVE G5000
	GIVE I716
	1: Thank you.  CODE_HOME
	MOVE 1, -200, -200
END
	@danish
END
;------------------
; TOKEN 505
	SCENE 90 warp5, SCENE, "Warp Beta 8"
	ACTOR 1, "Warpgate Guard", gateguard, 4, 30, 70
	MUSIC   Jumpoints.mid
	IF T505, @warp
	IF -E716, @noitem
	1: Excellent, I see you have an engine powerful enough to make the jump.
	1: Remember, again, once you enter this warp, you will be able to be hurt.
	1: Do you want to warp? (YES/NO)
	ASK 99999
	IF No, @no
	1: Okay, warping will begin in 3 seconds.
	WAIT 3.0
	GIVE T505
	GOTO LINK 24,0,0
END
	@noitem
	1: In order to attempt this warp, you must have at least a Mach 2 Engine equipped.
	1: Please return when you have this done.
END
	@warp
	1: Warping in one second..
	WAIT 2.0
	GOTO LINK 24,0,0
END
;------
;TOKEN 506-7
	SCENE 91, scene7, SCENE, "Leinix"
	MUSIC	port.mid
	IF T512, @yay
	IF T511, @reward
	IF T506, @done
	ACTOR 1, "Starfleet Official", act, 3, 30, 70
	IF T514, @514
	IF T507, @quest
	1: So, %1, we meet at last.
	1: We've heard about your... previous encounters.  
	1: In fact, as you can see, we've been watching you for some time, Mr. %1.
	1: Here is what we offer.  You help us bring the criminal on Erit to justice,
	1: and we'll give you a clean slate.  A good deal, isn't it? (YES/NO)
	ASK 99999
	IF Yes, @yes
	GIVE T514
	@514
	H: I have a better idea.  I give you the finger, and you give me my phone call.
	1: Your going to help us whether you want to or not, Mr. %1.  Guards!
	FIGHT 9,50,50,51,51,9
	IF ALIVE, @alive
	1: Goodbye, Mr. %1....
END
	@alive
	GIVE T506
	1: No!  There is no way you could of beaten.. guards?  Guards!
	1: Fool.. you do not know what you have set into motion!
	1: Fool!
	MOVE 1, 200, 200
END
	@yes
	GIVE T507
	1: Excellent.  I knew you would see it our way.
	1: We are going to act as if you have decimated us.
	1: We will cease transmissions, and await your signal.
	1: All you must do is go to Erit, and tell them we have been destroyed.
	1: They should let their guard down, and then you must send the signal.
	1: Go, now!  Good luck!
END
	@quest
	1: We await your signal!
END
	@done
	ACTOR 4,	"Native",		joshAnimals,	1,	20,	70
	4: Narrrg...
	4: Narrrg...
	4: Noones here!
	4: Narrrg...
	4: How come animals are allways forced to play demoralizing roles like this?
	4: I mean, comeon, we have feelings too!  Just because we're mindless, doesnt mean we should just sit around saying "Narrg..."!
	4: Im contacting the authorities on this!
	4: You can't just go pushing all the animals you see around like that.
	4: Next thing you know we'll be second class animals!
	4: I'm going to make that phone call now...
	MOVE 4, 50, 300
END
	@reward
	1: Excellent, excellent, excellent work!
	1: The Star Congress is forever in your debt!
	1: Please, take this with our gratitude!
	TAKE I716
	GIVE I715
	GIVE G5000
	GIVE T512
END
	@yay
	1: Thank you!
	GIVE L1
	GIVE H6000
	GIVE M6000
END
;-----
;T508-X
SCENE 92, Scene6, SCENE, "Erit"
MUSIC AlienHomeSystem.mid
IF T511, @empty
ACTOR 1, "Mr.X", Act2, 3, 30, 70
IF T510, @thanks
IF T508+T506, @good
IF T508-T507, @await
IF T509-T507-T506, @reconsider
IF T507, @evil
IF T506, @killed
	1: Welcome, %1, to my.. humble.. planet..
	1: I have heard of your.. previous.. jobs, and am interested in your services.
	1: I see.. surprise on your face.  Not what you expected?  Yes, the best disguise is that of the enemy.
	1: Who would dare to accuse me, Lieutenant-Class 1 Rikin of being Mr.X?  No one.
	1: Anyway, the official.. they cause, more, and more trouble... in the system.  I need them.. taken care of.
	1: Would you accept this mission?  You will be well rewarded, this I promise.  And Mr.X allways keeps his promises. (YES/NO)
	ASK 99999
	IF NO, @no
	GIVE T508
	1: Good.  Begone, then, %1, and return when you have succeeded.  I expect comm silence from them, and no less!
END
	@no
	1: I beg of you... to reconsider, %1.  Please, come back, if you do.
	GIVE T509
END
	@reconsider
	1: So, you have... reconsidered the alternatives? (YES/NO)
	ASK 99999
	IF NO, @no
	TAKE T509
	GIVE T508
	1: Good.  Begone, then, %1, and return when you have suceeded.  I expect comm silence from them, and no less!
END
	@await
	1: I await news from my sources that the government has been.. taken care of.
	1: Swimming with the fishies, and all that.  Understand, %1?
	1: I thought so.
END
	@good
	1: My sources tell me.. you have succeeded.. in the mission I chose to give to.. you.
	1: Good.  I will reward you now, %1.  Then you must be gone.
	GIVE T510
	TAKE I716
	GIVE I715
	GIVE G20000
END
	@killed
	1: I.. see you have.. removed the government. 
	1: I needed this service, and I thank you greatly.
	1: Please, take this as my.. thanks.
	GIVE T510
	TAKE I716
	GIVE I715
	GIVE G20000
END
	@thanks
	1: Thank you, alot, %1... really.
	GIVE L1
	GIVE H6000
	GIVE M6000
END
	@evil
	1: So, my sources tell me the government has been.. taken care of.  Very good, %1.
	1: I owe you.  Please, take this with my thanks....
	ACTOR 2, "Cop", robo, 1, 30, 60
	ACTOR 3, "Cop", robo, 1, 30, 80
	ACTOR 4, "Cop", robo, 1, 40, 70
	ACTOR 5, "Starfleet Official", act, 3, 60, 70
	1:Whhaaa?
	GIVE T511
	5: Hello, Mr. X.
	5: You have the right to remain %3 silent.
	5: Lets go.
	5: %1, come to Leinix for your reward.
	MOVE 1, 200, 200
	MOVE 2, 200, 200
	MOVE 3, 200, 200
	MOVE 4, 200, 200
	MOVE 5, 200, 200
	1: Ill get you, %1!
	1: You'll pa...
	5: *kick* Move!
END
	@empty
	ACTOR 1, "Cop", robo, 1, 30, 70
	1: Move along.. move along...
	1: Nothing to see here..
	1: Literally.
	1: You see, your done with this quest.
	1: Why are you still here?
	1: Oh.... I see, you must be in the bathroom.
	1: ... You fall in or something?
	1: Move along.. move along...
	1: Nothing but a guy stuck in a toilet to see here..
	1: Hahahaha.. ha.. ha...
	1: Ha... okay, so what if that wasnt funny?
	1: Leave me alone!
END
;----------
;USES T513
	SCENE 93 warp3, SCENE, "Warp YT-6"
	ACTOR 1, "Warpgate Guard", gateguard, 4, 30, 70
	MUSIC   Jumpoints.mid
	IF T513, @warp
	IF -E715, @nogo
	1: Welcome to Warp YT-6.  You are properly equipped, the warp will begin in 3 seconds.
	GIVE T513
	WAIT 3.0
	GOTO LINK 25,0,0
END
	@nogo
	1: In order to warp through this warp, you must have at least a Mach 3 Engine Equipped.
	IF E716, @2
	1: You either have no engine or do not have your Mach 3 Engine Equipped.  Please return when you are prepared.
END
	@2
	1: You currently have a Mach *Two* Engine.  You must find a way to upgrade it.
END
	@warp
	1: Warping in 2 seconds..
	WAIT 2.0
	GOTO LINK 25,0,0
END
;--------
;
SCENE 95 Solar, SCENE, "General Store"
MUSIC Shop2.mid
ACTOR	1,	"Susy", act2, 2, 25, 90
OFFER 33,34,35,36,832,833,410,411,412,413,414,415,416,417,418,419,420,421,422,423,424,425,233,234,235,236,237,238,239,240,266,267,268
1: Welcome to the shop.
1: Please take a look around.
END
;-------
SCENE 96 fighterbg, SCENE, "Mechanic"
MUSIC Wellmusic.mid
OFFER2 20,50,22, 20,50,23
	ACTOR 1, "Frank", JoshTownies, 15, 60, 70
1: Welcome.  One second and I'll have you fixed up...
GIVE L1
GIVE H6000
GIVE M6000
1: Please, look at what I have to offer.
END
;----------
;T514-517
SCENE 97 General, SCENE, "Jack's"
MUSIC code.mid
	ACTOR 	1, "Jack", joshTownies,	29, 20, 90
IF ALIVE, @continue
1: ... Your dead.  I cant help you here.
END
@continue
IF T521, @thanks
IF T520, @planets
IF T517, @next
IF T518, @ask
IF T516, @complete
IF T515, @coppers

1: #<km.161> Waterbots, #<km.156> Bounty Hunters, #<km.165> Robotrackers, #<km.168> Ninja Bots,
1: #<km.169> Robohunter v1.0's, #<km.170> Robohunter v2.0's, #<km.164> Dark Angels,
1: #<km.163> Water Spiders, and #<km.162> Seekers.

IF T32+KM161.4+KM156.5+KM165.3+KM168.7+KM170.5+KM169.3+KM164.6+KM163.11+KM162.8, @done
IF T32, @met
1: %1, I have needs of your.. services.
1: As you can see, we've been having some problems with the locals...
1: I would like to hire you to help me.. remedy the situation. 
1: I need you to go above the surface and kill a few of my.. enemies.
1: Here, take this list.  If you need to look at what you need to kill, just use it.
GIVE I96
GIVE T32
1: Thanks, and good luck.
END
	@met
	1: You still havent killed all of the monsters I need.
	1: Please return when you have.
END
	@done
	1: Great, you have helped tremendously.
	1: Unfortuanatly, while you were... not quiet about your doings.
	1: Somehow, the coppers found out about your little.. side jobs.
	TAKE I96
	GIVE S751
	GIVE T515
	1: When you take care of my little problem.  When.  I will pay you.
	1: I will teach you a defensive skill to help you along.  You can now heal youself.
	1: Thank you.
END
	@coppers
	1: Please, remove my little.. problem.
END
	@complete
	1: Excellent work, %1.  Here is your pay, and I have further needs for your.. services.
	GIVE T518
	GIVE G30000
	@ask
	1: Would you like to accept another mission? (YES/NO)
	ASK 999999
	IF NO, @no
	GIVE T517
	1: Good.  You are a good hunter, %1, and you know this.  As you know, I have had my... associates.. secure a portal in this sector.
	1: Goto it, they will let you through now.  On the other side are two planets.  
	1: Each is defended with large fleets, and I need both of these.. removed.  You will be rewarded for your services, 60,000 Gold.
	1: Good luck, Hunter %1.
END
	@no
	GIVE T518
	1: Come back if you reconsider.
END
	@next
	1: I expect you to remove those fleets for me, %1.
END
	@planets
	1: Excellent.  You have done all that I expected of you.
	1: I grant you the key to the universe.
	1: I have not dared to use it, but it is rumored that it will open the warp.
	GIVE T521
	1: Good luck, %1.  And thank you.
END
	@thanks
	1: Thank you.
END
;-----------
; USES T516-517
SCENE 98 cop, SCENE, "Cops"
MUSIC cop.mid
ACTOR 1, "Dick", act, 3, 40, 70
IF ALIVE, @continue
1: ... Your dead.  I cant help you here.
END
@continue
IF T516, @done
IF T515, @hey
1: %1, welcome to the city.
1: I am responsible for keeping the peace.  Report any problems you have.
1: Enjoy your stay down here.
END
@hey
1: You!  Stop right there!
1: Killing innocents.. you will pay for this!
1: Guards!  Guards!
MOVE 1,200,200,1
FIGHT 171, 171, 172
	IF ALIVE, @won1
	TAKE G1000
MOVE 1, 40, 70, 1
1: You fool.. never cross us again!
END
	@won1
	' You fool.. you think you can beat the government? Think again!
	GIVE H200
	SOUND C702.wav
	MUSIC	ab.mid
	FIGHT 171,171,172,172
	IF ALIVE, @won2
	TAKE G1000
	' Bad boys bad boys.. whatcha gonna do? Die!
END
	@won2
	GIVE H200
	SOUND C702.wav
	' Prepare to meet the full wrath of the military!
	MUSIC	ab.mid
	FIGHT 171,171,173,173,172,173
	IF ALIVE, @won3
	TAKE G1000
	' You are not even worth our time.
END
	@won3
	MOVE 1, 75, 75, 1
	GIVE T516
	' You... you have.. destroyed me!
	' How could you of... no.. please, leave my humbled place.
	' Leave us and go!  Our city doesn't need your kind!
	SOUND C702.wav
	GIVE H6000
	GIVE M6000
END
@done
	' Leave!
	' Leave us in peace!
END
;---------------
	SCENE 99 scene10, SCENE, "Warp H-7"
	MUSIC	Jumpoints.mid
	ACTOR	1,	"Warpgate Guard", gateguard, 4, 25, 90
	IF T517, @warp
	1: Noone passes through here without Jack's permission.
	1: Gettoutta here.
END
	@warp
	1: I expected you, %1.  You'll be warping in 1 second...
	WAIT 2.0
	GOTO LINK 28,2,0
END
;----------
SCENE 100 ap2, SCENE, "Kiop I"
	MUSIC evil.mid
	IF T35, @empty
	ACTOR 1, "Officer", act, 3, 25, 90
	1: You!  Leave this area at once!
	1: This is a Government Owned Planet! (YES/NO)
	ASK 99999
	IF NO, @no
	1: Good!
	GOTO LINK 28, 1, 0
	END
	@no
	1: How dare you deny the government?  Protocol 11-5 Activate!  Defence online!
	1: Prepare to die, %1!
	MOVE 1, 200, 200, 1
    MUSIC ab.mid
	FIGHT 186,186,186,185
	IF ALIVE,@won
	MOVE 1, 50, 70, 1
	1: Never deny the wrath of the Government!
END
	@won
	MOVE 1, 40, 60, 1
	ACTOR 3, "Message Pod",		sat1,	1, 45, 60
    GIVE T35
	1: Go! Quickly!  Tell them to prepare!
	WAIT 5.0
	MOVE 3, 40, 60, 1
	WAIT .3
	MOVE 3, 35, 60, 1
	WAIT .3
	MOVE 3, 30, 60, 1
	WAIT .3
	MOVE 3, 25, 60, 1
	WAIT .3
	MOVE 3, 20, 60, 1
	WAIT .3
	MOVE 3, 15, 60, 1
	WAIT .3
	MOVE 3, 10, 60, 1
	WAIT .3
	MOVE 3, 5, 60, 1
	WAIT .3
	MOVE 3, 0, 60, 1
	WAIT .3
	MOVE 3, 200, 200, 1
END
	@empty
	Actor 1, "Computer"
	1: You dock and heal at the now defunct space station.
	GIVE L1
	GIVE M6000
	GIVE H6000
END
;------------
; T520
SCENE 101 Scene11, SCENE, "Kiop IV"
MUSIC LikerianSystem.mid
IF ALIVE, @continue
1: Your dead.  Gettoutta here!
END
@continue
IF T520, @empty
IF T518, @fight
IF T519, @heal
ACTOR 1, "Officer", act, 3, 25, 90
1: Welcome to the pedestrial planet Kiop IV.
1: You are welcome here, but do not land on Kiop I!
GIVE T519
GIVE L1
GIVE H6000
GIVE M6000
END
@fight
ACTOR 1, "Officer", act, 3, 25, 80
1: %1!  You will pay for what you did to Kiop I!
1: The fleet comes!  Prepare!
1: Prepare to meet your destiny, you pirate scum!
MOVE 1, 200, 200, 1
MUSIC b1.mid
ACTOR 2, "Computer"
2: The first wave, incomming!  Preparing shields, loading weapons, prepare yourself!
WAIT 2.0
FIGHT 180,180,181,183,183
IF ALIVE, @next
MOVE 1, 50, 70, 1
1: Foolish one.
END
@next
2: Second wave, coming up on the sensors!  5 seconds ETA!
WAIT 6.0
MUSIC ab.mid
FIGHT 190,191,185,185
IF ALIVE, @yep
MOVE 1, 50, 70, 1
1: Never touch our planet with your scum again!
END
@yep
2: Another wave on the sensors!  10 seconds ETA!
WAIT 10.0
MUSIC bof.mid
FIGHT 180,181,190,190,185
IF ALIVE, @cont
MOVE 1, 50, 70, 1
1: You have paid with your life!
END
@cont
MUSIC ded.mid
2: The final fleet is incoming!  Here we go!
WAIT 5.0
FIGHT 190,190,185,185,185,185,180
IF ALIVE, @won
MOVE 1, 50, 70, 1
1: You have been vanquished.
END
@won
MUSIC Victory.mid
GIVE H6000
GIVE M6000
MOVE 1, 50, 70, 1
GIVE T520
1: Noo... you.. I... we.. no.. please, take anything.  Take my money.
GIVE G25000
1: I will leave now, the planet is yours.
MOVE 1, 200, 200, 1
END
@empty
ACTOR 1, "Computer"
1: No ships on the sensors.. the area is empty.
END
;-----
	SCENE 102 warp4, SCENE, "Warp Point T6-A"
	ACTOR 1, "Warpgate Guard", gateguard, 4, 30, 70
	MUSIC   Jumpoints.mid
IF T525, @ask.
IF T521, @warp
1: This warp gate has been broken for some time.
1: It is rumored that Jack holds the key, but there are many rumors about him.
1: He has his headquarters setup on Sestle.
END
@warp
1: The Key!
1: You have it!  Please, give it to me, and you will warp!
1: However, be warned, once you warp through this, there is no turning back!
@ask
1: Do you wish to warp? (YES/NO)
IF NO, @no
1: Good luck, %1!  Good luck!
WAIT 2.0
GOTO SCENE 84
END
@no
1: I do not blame you.  Return when you are ready.
GIVE T525
END
;----------
SCENE 103 lsit, CUT, "Jack's List"
MUSIC surface.mid
IF I96, @done
GIVE I96
GOTO @done
END
@done
ACTOR 1, "List"
1: Killed thusfar:
1: #<km.161> Waterbots, #<km.156> Bounty Hunters, #<km.165> Robotrackers, #<km.168> Ninja Bots,
1: #<km.169> Robohunter v1.0's, #<km.170> Robohunter v2.0's, #<km.164> Dark Angels,
1: #<km.163> Water Spiders, and #<km.192> Seekers.
END
;------
	