SCENE 401 1ArmoredArmadillo
#include all.txt
ACTOR 1,"Dr Cain",DrCain,1,20,100
POSE 1,2,3
IF T401,@t401
1: %1, good you are here, I need your help with something.
1: Our excavation team was working in this area before the firestorm happened.
1: I have not been fortunate enough to find any survivors here.
1: There was a transmission to our old headquarters right before the firestorm from this site!
1: I believe it must have been something pretty important since they sent word of it.
1: I have pinpointed the transmission to this exact location, where there has been a cave-in.
1: I brought along some explosives but I don't have enough to do the job.
1: If you can get me 5 Mega Weapons Packs I can get the entrance to the cave opened up.
1: Just say "Yes" whenever you have collected them %1, and I'll take care of the rest.
ASK 300.0
IF YES,@yes
END
@yes
IF I14,@take1
1: I'm afraid I can't do anything without 5 Mega Weapons Packs %1, come back when you get them for me.
END
@take1
HOST_TAKE I14
IF I14,@take2
1: It's going to take 5 of them %1, not one of them!  Come back when you have all 5 I need.
HOST_GIVE I14
END
@take2
HOST_TAKE I14
IF I14,@take3
1: It's going to take 5 of them %1, not two of them!  Come back when you have all 5 I need.
HOST_GIVE I14
HOST_GIVE I14
END
@take3
HOST_TAKE I14
IF I14,@take4
1: It's going to take 5 of them %1, not three of them!  Come back when you have all 5 I need.
HOST_GIVE I14
HOST_GIVE I14
HOST_GIVE I14
END
@take4
HOST_TAKE I14
IF I14,@take5
1: It's going to take 5 of them %1, not four of them!  Come back when you have all 5 I need.
HOST_GIVE I14
HOST_GIVE I14
HOST_GIVE I14
HOST_GIVE I14
END
@take5
HOST_TAKE I14
1: Yes, this will do... Wait here %1, I'll use the plasma in these with what I already had to blow open the cave.
MOVE 1,-25,100
WAIT 5.0
SOUND boom2
WAIT 5.0
MOVE 1,20,100
1: Success!  I found what they were trying to inform me of before the firestorm!
1: This is amazing %1!  This is a portion of a recorded history of your ancestor!
1: From Dr. Lights wisdom you were born %1, with this you will be able to see with your own eyes that wisdom.
1: This document accounts for the reason that robots were created with the ability to think, and why they were turned into fighting machines.
1: Perhaps we can even gain some kind of clue as to why the firestorm happened the way it did.
1: We must keep our eyes open for more of these %1, they could hold the key to understanding what we are up against.
1: Here, you take it.  You can watch it by using the Dr. Light hologram capsule.
HOST_GIVE T401
HOST_TAKE I14
HOST_TAKE I14
HOST_TAKE I14
HOST_TAKE I14
HOST_TAKE I14
@t401
1: Good luck, %1, don't give up on our fight for survival!
END
;
;
;
SCENE 402 1LaunchOctopus
#include all.txt
IF T402,@t402
ACTOR 1,"Sunken Robot",mmm-mmxwaterspider,1,30,50
POSE 1,4,1
WAIT 3.0
H: Something is wrong with this robot...  It seems to have shorted out from being submerged.
H: I wonder how long it's been down here?
H: If only I could somehow give it a jolt to access it's memory and find out how it got here...
END
@eventActorSpell1
COMPARE #<spell.id>,"700"
IF=,@good2go
H: Nope, that didn't seem to help...
END
@good2go
SOUND boom2
H: Great, it worked, now I can access this poor guy's memory cache...
WAIT 2.0
H: WHAT?!
H: How in the world did you get ahold of this data?
H: It's a historic recoring!  I wonder what's on it, maybe I'll check on it later at Dr. Light's capsule.
HOST_GIVE T402
@t402
END
;
;
;
SCENE 403 2BubbleCrab
#include all.txt
ACTOR 1,"Sunken Submarine",mmm-mmxsub,1,30,105
IF T403,@t403
H: What's this sub doing down here?  I should investigate.
H: The hatch is rusted shut.  How am I going to get in there?
END
@eventActorSpell1
COMPARE #<spell.id>,"501"
IF=,@good2go
H: Nope, that didn't seem to help...
END
@good2go
SOUND MandrillAttack
H: I think I can pry the hatch open now. I wonder what's inside...
WAIT 3.0
H: Jackpot!
H: A historic recoring was sealed in a chamber inside!  I'll check on it later at the capsule.
HOST_GIVE T403
@t403
END
;
;
;
SCENE 404 2MorphMoth
#include all.txt
IF T404,@t404
ACTOR 1,"Smart Frog",mmm-mmx2frog,1,20,100
POSE 1,4,1
WAIT 2.0
1: What do YOU want?
WAIT 2.0
MENU "YOU... for lunch!=@lunch","You Can TALK?=@talk"
END
@lunch
1: Well if that's the case...
MOVE 1,-25,100,3
END
@talk
1: ...is it THAT obvious?
WAIT 2.0
MENU "Of course, I meant nothing by it...=@nothing","What do you mean?=@mean"
END
@mean
1: No reason to stay here and chat with a moron like you.  Can't even understand simple sarcasm.
MOVE 1,-25,100
END
@nothing
1: So what are you doing here?
WAIT 2.0
MENU "I'm looking for something=@looking","You wouldn't understand=@understand"
END
@looking
1: Oh I see, simply doing what you are told... stupid robot...
MOVE 1,-25,100
END
@understand
1: YOU presume to know more than I?!  I demand that you tell me right now!
WAIT 2.0
MENU "Well, if you must know...=@well","You're just a stupid frog!=@stupid"
END
@stupid
1: Oh why YOU!
MOVE 1,-25,100,1
FIGHT2 48
END
@well
1: Yes, please tell me what you are doing here.
WAIT 2.0
MENU "Looking for something rare... you probably haven't seen it=@rare","I'm not telling...=@notell"
END
@notell
1: I grow tired of this game... good day.
MOVE 1,-25,100
END
@rare
1: Oh I know of many rare things in this area!
1: For instance, have a look at this... it's a googleajigger.
N: It has a peice of the historical records!
WAIT 2.0
MENU "That's not a googleajigger, it's a recording!=@recording","You call THAT rare?=@that"
END
@recording
1: OOOH how precious it must be... well then, goodbye.
MOVE 1,-25,100
END
@that
1: It's not rare?  I must be mistaken...  
1: No matter, here you may have it since it's worthless.
HOST_GIVE T404
N: You got the historical record!
@t404
END 
;
;
;
SCENE 405 3BlastHornet
#include all.txt
IF T405,@t405
ACTOR 1,"",mmm-mmx3butterlift,6,20,0
H: I'd better take a look around.. I'm sensing something out of the ordinary here.
END
@eventActorAttack1
SEL 1
POSE 3
MOVE 1,20,100,5
1: Eeeeeeeeeeeeeeeeee!
WAIT 1.0
SEL 1
POSE 1
1: Eee Eeeee Eeeee! (It's trying to say something...)
1: Eeee Eeeeeee.
MOVE 1,-25,100
H: That was extremely odd... OH!
H: He left behind a historical record!  Wonder how he got ahold of that?
HOST_GIVE T405
@t405
END
;
;
;
SCENE 406 3NeonTiger
#include all.txt
IF T406,@t406
ACTOR 1,"",mmm-mmx3sparks,1,120,40
H: What in the world is THAT?
MOVE 1,-25,40
END
@eventActorSpell1
COMPARE #<spell.id>,"102"
IF=,@goodgo
@eventActorAttack1
H: Nope, that didn't stop it...
END
@goodgo
SOUND MandrillAttack
MOVE 1,50,100,4
WAIT 1.0
H: Bingo!
WAIT 1.0
H: This thing... it had a historic record!  Some things just cannot be explained in this world...
HOST_GIVE T406
@t406
END
;
;
;
SCENE 407 4CyberPeacock
#include all.txt
IF T407,@t407
WAIT 2.0
H: I'm picking up precious metals on my sensors.
H: Who should I call to help me look in the ground for whatever it is? 
@again
H: Who could I have help?   (No capital letters)
ASK 30.0
IF Qzero,@zero
IF Qdrcain,@cain
IF Qdr^cain,@cain
IF Qrush,@rush
H: I don't think that's going to be very helpful...
GOTO @again
END
@zero
ACTOR 1,"Zero",AlliesZeroHero,1,-25,100
MOVE 1,80,90
1: I'll see what I can do %1, but I'm not making any guarantees...
GOTO @again
END
@cain
ACTOR 2,"Dr Cain",DrCain,1,-25,100
MOVE 2,50,80
2: You want an old scientist like me to help you dig?  At least call it an "archeological dig" for scientific purposes...
GOTO @again
END
@rush
ACTOR 3,"Rush",AlliesRush,1,-25,100
MOVE 3,25,100
3: (sniff sniff sniff)
3: (sniff sniff sniff)
3: (sniff sniff sniff)
WAIT 2.0
SOUND RobowolfPain
SEL 3
POSE 4
H: You did it Rush!  Now lets see... YES!
H: It's a historical record!  I couldn't have found it without you Rush.
SOUND RobowolfPain
SEL 3
POSE 1
HOST_GIVE T407
@t407
END
;
;
;
SCENE 408 4SlashBeast
#include all.txt
IF T408,@t408
H: Oh no!  This doesn't look good!
FIGHT 138,139,140,141,142,142
IF WON,@won
SOUND death
MIDI dead
END
@won
H: YEA!  One of those guys was carrying a historic record!
H: Gotta check this out ASAP!
HOST_GIVE T408
@t408
END
;
;
;
SCENE 409 5AxleTheRed
#include all.txt
IF T409,@t409
ACTOR 1,"Zero",AlliesZeroHero,1,-25,100
MOVE 1,20,90
WAIT 1.5
SET canpascod,"%R8999"
ADD canpascod,"1000"
1: %1!  Look what I found!  It's an old canister with some sort of passcode lock on it.
1: Wanna try to guess the code?  It seems to be a four digit code.
1: Go ahead %1, take a crack at it and I'll listen to the mechanism inside to see if I can tell how close you are.
1: Enter a four digit code...  (ex.  1234)
@ask
ASK 30.0
COMPARE #<lastAsk>,#<canpascod>
IF=,@gotit
IF>,@less
IF<,@greater
END
@gotit
SOUND click
1: Alright! You got it %1!  Look there is something inside!
H: It's a historical record!
1: You go ahead and hold onto it %1.
HOST_GIVE T409
END
@greater
1: I think it's a higher than #<lastask> %1, keep trying!
GOTO @ask
END
@less
1: I think it's lower than #<lastAsk> %1, keep trying!
GOTO @ask
END
@t409
END
;
;
;
SCENE 410 5Mattrex
#include all.txt
IF T410,@t410
ACTOR 1,"Dr Cain",DrCain,1,20,100
POSE 1,2,3
1: You've come a long way %1, I just want you to know that you've done well.
1: I found something here a bit ago... but... I forgot where I put it!
1: Help me remember?
END
@eventActorAttack1
IF T410,@t410
1: OH! I remember now!  It was another historical record.
1: I put it here somewhere... oh yes, here it is.
1: I hope this helps you to understand your roots and why you are fighting for humans everywhere.
H: Thank you Dr Cain.
HOST_GIVE T410
@t410
END
;
;
;
