SCENE 80 forest
ACTOR 1, "Luke Skywalker", myactors, 24, 25, 100
IF T104, @t104
IF T103, @defended
IF T102, @t102
IF T101, @killedhim
IF T100, @t100
1: Greetings friend, you must be %1.
1: I've heard alot about you.
1: I expect good things will happen now that you're here
H: (should I be worried?)
1: Why are you looking at me like that?
1: Nevermind that, there is more urgent buisiness to be dealt with.
1: There has been someone seen around here that must look like me.
1: He's been spotted several times lurking around but nobody knows him.
1: We believe he is spying for the empire, and would appreciate your help in finding him.

1: Try to seek him out.  Keep your eyes peeled, and be safe.
@t100
1: Get going.  There's no telling what he's up to.
HOST_GIVE T100
END
@killedhim
H: I found the spy!
1: Very good, where is he?
H: Umm... I killed him... 
1: Oh,
WAIT 2.0
1: Did he attack you or something?
H: Yes, I had to kill him.
1: Oh, I just wish we could've interrogated him.
1: I bet he was here trying to steal the plans to the Death Star.
1: I think it would be best if you stayed around here for awhile.
1: This should help you out... it's a %I8
HOST_GIVE T102
IF T65,@shard1
HOST_GIVE I8
@shard1
@t102
1: I've got a feeling something bad is about to happen.
END
@defended
1: It seems the empire tried to make a sneak attack on us.
1: That means that they know where we are.
1: In any case...
1: Well done %1 !
1: Please take this %I8, it's my last.
HOST_GIVE T104
IF T65,@shard2
HOST_GIVE I8
@shard2
@t104
1: You should seek out Yoda on the planet Dagobah.
1: Continue your journey my friend, we are safe for now.
END

SCENE 81, forest
IF T101, @done
FIGHT 61
IF WON, @winner
END
@winner
HOST_GIVE T101
H: Was I supposed to kill him?
H: Now that I think about it, didn't he say "Find him", and "Seek him out"?
H: .........
@done
END

SCENE 82, alderaangate
IF T103, @done2
H: What's that noise?
WAIT 2.0
H: Stormtroopers!!
FIGHT 5
IF WON, @next11
END
@next11
FIGHT 5
IF WON, @next12
END
@next12
H: Ahh.. they just keep coming!
WAIT 2.0
FIGHT 5,5
IF WON, @next13
END
@next13
FIGHT 5,5
IF WON, @next14
END
@next14
H: I can't give up! I must defeat them all!
WAIT 3.0
FIGHT 5,5,5
IF WON, @gotem
END
@gotem
HOST_GIVE T103
@done2
END

SCENE 83 dagobah
ACTOR 1,"Yoda", myactors, 1, 25, 100
IF T109, @t109
IF T108, @t108
IT T107, @t107
IF T106, @t106
IF T105, @t105
1: Greetings young %1.
H: Hello Master Yoda.
1: To my home what brings you ?
H: I thought you could help me with something.
1: Help you I can!
H: What can we do to defeat the empire?
1: Tell you I could ...but,....
H: What is it?
1: Sooooooooooo hungry am I!

1: Find me some food maybe you could?
H: What do you eat?
1: Food!
H: YES, I know that! What kind of food do you want?
1: Good is Scurrier!  Fresh, Juicy, Scurrier bring me.
H: That's disgusting.
HOST_GIVE T105
@t105
1: Hurry please, starving am I!
H: Whatever...
END
@t106
1: What is that smell?
H: I've got the Scurrier you asked for.
1: Hmmmm, No.
H: What do you mean no?
1: Fresh and Juicy it is not!
H: (Stupid little)
1: Said something did you?
HOST_GIVE T107
@t107
H: I'll be back with a fresh and juicy one.
END
@t108
H: I've returned with your dinner.
1: Wonderful one this is, yeeees.
1: Thank you for helping me I do.
IF T65,@shard3
1: Please take this %I8.
HOST_GIVE I8
@shard3
HOST_GIVE T109
1: Hunting for ways to crush the empire you are.
1: Their powers are not so great, weaknesses they have.
1: Seek these weaknesses you must!
@t109
1: On Endor the answers you will find. Go.
END


SCENE 84 dagobah
IF T108, @ended
IF T107, @goagain
IF T106, @killed1
H: Hunting for Scurrier...this is a load of
H: There's one!
WAIT 2.0
FIGHT 22
IF WON, @beat1
END
@beat1
HOST_GIVE T106
H: Now to get this back to Master Yoda.
@killed1
END
@goagain
H: Where am I going to find a fresh and juicy Scurrier?
H: I am so sick of this nasty, swampy, little planet!
H: AHHHHHHHHHHHHHHHHHHHHHHH!!!
H: Uh, oh....I think I shouldn't have yelled!
WAIT 2.0
FIGHT 22
IF WON, @scur2
END
@scur2
FIGHT 22, 22
IF WON, @scur3
END
@scur3
FIGHT 22, 22, 22
IF WON, @scur4
END
@scur4
FIGHT 22, 22, 22, 22
IF WON, @scur5
END
@scur5
FIGHT 22, 22, 22, 22, 22
IF WON, @complete
END
@complete
H: Whew, that was tough! Gotta keep my voice down.
H: Wow, this one seems to be pretty juicy.
H: Hope Master Yoda will like it.
HOST_GIVE T108
@ended
END

SCENE 85 ewokvillage
ACTOR 1, "Leia Organa", myactors, 4, 25, 100
IF T112, @t112
IF T111, @t111
IF T110, @t110
1: Hello %1, it's a good thing you're here.
1: We've located the Death Stars sheild generator here on this small planet.
1: If we can manage to disable this thing we might one day be able to destroy that abomination.
HOST_GIVE T110
@t110
1: Please, help us to penetrate the defenses around the sheild generator.
END
@t111
MUSIC ewokwon.mid
1: You've done a fine job %1.
1: I don't think we could have pulled it off without you.
IF T65,@shard4
1: I'd like you to accept this %I8 as a reward, please.
HOST_GIVE I8
@shard4
HOST_GIVE T112
1: If you could help us out, our forces on Hoth have requested aid in expectation of a strike by the empire.
@t112
MUSIC ewokwon.mid
1: Please help the rebels stationed at Hoth's rebel base.
END

SCENE 86 shieldgen
IF T111, @itstoast
H: Maybe this won't be so hard...
WAIT 2.0
SOUND blaster2.wav
H: On second thought, maybe it will be!
WAIT 2.0
FIGHT 5,27,-25
IF WON, @fight2
END
@fight2
FIGHT 5,5,27,27,28,-25,-25,-25
IF WON, @fight3
END
@fight3
FIGHT 5,5,5,27,27,28,28,-25,-25,-25
IF WON, @fight4
END
@fight4
FIGHT 5,5,5,5,5,27,27,28,28,-25,-25,-25,-25,-25
IF WON, @fightover
END
@fightover
H: That's it! We've won!
H: Blow that thing back where it came from guys!
HOST_GIVE T111
@itstoast
END

SCENE 87 commandcenter
ACTOR 1, "Luke Skywalker", myactors, 24, 25, 100
IF T115, @t115
IF T114, @t114
IF T113, @t113
1: %1,! You got here just in time.
1: The empire has begun their attack on this outpost.
1: Take up your position at the front lines ASAP!
HOST_GIVE T113
@t113
1: Do whatever it takes to stop them!
END
@t114
1: We've done it! We sent them running like Womprats!
1: Great work %1
HOST_GIVE T115
IF T65,@shard5
HOST_GIVE I8
1: Here's a %I8 I found during the battle.
1: Take it, you've earned it
@shard5
@t115
1: Could you check in on the rebel outpost at Yavin IV?
1: We haven't heard from them and I fear the worst...
END

SCENE 88 hothgate
IF T114, @atatdead
H: I've got a bad feeling about this.
H: It's quiet, too quiet....
WAIT 2.0
H: There, I see them!
H: Get ready everyone!
FIGHT 32,-62,-62
IF WON, @atat2
END
@atat2
FIGHT 32,32,-62,-62,-62,-62
IF WON, @atat3
END
@atat3
FIGHT 32,32,32,-62,-62,-62,-62,-62,-62
IF WON, @atat4
END
@atat4
H: Oh no....
WAIT 3.0
FIGHT 32,32,32,32,32,-62,-62,-62,-62,-62,-62,-62
IF WON, @beatemall
END
@beatemall
HOST_GIVE T114
SOUND cheering.wav
H: Yeaaaaah!
@atatdead
END

SCENE 89 falcon
ACTOR 1, "Han Solo", myactors, 3, 29, 96
IF T118, @t118
IF T117, @deadties
IF T116, @gotmission
1: Hey %1, good to see you here!
1: We need all the help we can get.
1: The empire is staging an attack on this outpost as we speak.
1: We don't have the forces here to mount a good defense, 
1: Our only option is to take them on now while they are busy making preperations
1: You know, catch them off guard!
H: Say no more, ready when you are.
HOST_GIVE T116
@gotmission
1: Good, than we go to the staging area now.
END
@deadties
1: You did pretty good out there kid.
IF T65,@shard6
1: Luke gave me this, you'd probably get more use out of it than I do.
1: He said it's a %I8, whatever...
HOST_GIVE I8
@shard6
HOST_GIVE T118
@t118
1: We've got things back under control around here pal.
1: You outta head to Naboo and see if they are having any troubles.
END
