SCENE 765
#include banthing.txt
ACTOR 1, "Plant o Wisdom", maneater, 1, 25, 90
IF ALIVE, @elossa
1: You have fallen. Let me resurrect you.
WAIT 2
GIVE L1
GIVE H5000
GIVE M5000
END
@elossa
GIVE L1
GIVE H5000
GIVE M5000
1: Greetings adventurer.
1: One more that has found the Secret Gardens, ehh?
1: It has been many years..
1: Oh well, I can heal you.
1: And resurrect you should you fall.
END

SCENE 1705
#include banthing.txt
ACTOR 1, "Boneripper", madratogre, 1, 25, 95, 23
IF T710, @gots
IF C6, @testing
1: Urrm, gurff!
WAIT 2
N: Obviously you're not welcome.
END
@testing
1: Urrmm gurrfffgggll!
H: Murgfflll!
1: Urgg murrgg me gonna test you!
H: Urmf Boneripper. You Da Un Serving Thanq?
1: Urmm gurff yup.
1: Beats up these monsters, gets weapon and shield, hurrm?
H: Urrm gurf!
WAIT 2
N: Prepare.
WAIT 3
THEME 53
FIGHT 395, 395, 395
IF WON, @clawie
THEME 70
1: Murf, pathetic.
END
@clawie
THEME 71
1: Urrm, impressive. Here goes, takes.
WAIT 2
HOST_GIVE T710
HOST_GIVE I1260
HOST_GIVE I1261
N: received %I1260 and %I1261!
END
@gots
1: Gots stuff already, gets out.
H: Gurff murgl.
END

SCENE 1550
#include banthing.txt
IF T715, @sta
ACTOR 1, "", statue, 1, 45, 100
N: An ancient figure stands before you.
WAIT 2
N: On a closer look, it seems to be missing something..
WAIT 2
N: Its other ruby eye is missing.
END
@eventActorClick1
IF T715, @tele
IF I1277, @gem
END
@gem
IF C1, @gem2
IF C2, @gem2
IF C4, @gem2
IF C6, @gem2
IF C18, @gem2
IF C19, @gem2
IF C22, @gem2
IF C30, @gem2
H: Let's see.. Missing a ruby eye..
H: And I seem to have an item that would fit.
GOTO @ques
END
@gem2
H: Lets see.. It be missing a ruby eye
H: I seems to has it.
GOTO @ques
END
@ques
WAIT 2
MENU "Do nothing=@ok", "Place the ruby in the other eye socket=@passage"
END
@ok
N: You decide not to place the ruby eye.
END
@passage
N: You place the ruby eye to the empty eye socket.
HOST_TAKE I1277
WAIT 1
N: Lost %I1277
WAIT 2
SEL 1
POSE 2
WAIT 2
HOST_GIVE T715
N: You have opened a passage deeper to the Secret Garden.
WAIT 2
N: Right clicking the statue will result in teleporting to the other side.
END
@sta
ACTOR 1, "", statue, 2, 45, 100
N: Right clicking the statue will result in teleporting to the other side.
END
@tele
GOTO LINK 64, 0
END

;this getting boring to add these comments.

