SCENE 605
#include banthing.txt
ACTOR 1, "Borgash Shieldbreaker", dwarf, 1, 25, 90
IF T317, @atlast
IF T315, @sotaa
OFFER 560, 561, 510, 511, 310, 311, 460, 461, 410, 411, 360, 361,
1: Hello there and welcome to me shop of quality weapons, #<g.lad>!
1: Dwarven of course.
END
@sotaa
1: Can't sell ya anything. War be goin' on.
1: Visit the Paladin trainin' temple perhaps.
1: That is, if you haven't already.
END
@atlast
OFFER 560, 561, 510, 511, 310, 311, 460, 461, 410, 411, 360, 361,
1: Hello again.
1: I can sell ya stuff again, #<g.lad>!
1: Hero o Sturmwind.
END


SCENE 606
#include banthing.txt
ACTOR 1, "Bagnar the Defender", dwarf, 2, 25, 95
IF T317, @selling
IF T315, @notselling
1: Interested in high quality armour, #<g.lad>?
1: I'll offer you only me best stuff!
OFFER 910, 911, 856, 811, 812, 262, 263, 661, 662, 612, 613, 212, 213,
END
@notselling
1: War going on, I can't offer anything. Everything's used.
END
@selling
1: Glad you came ta see old dwarf, #<g.lad>.
1: Me be glad to see ya, hero o Sturmwind.
OFFER 910, 911, 856, 811, 812, 262, 263, 661, 662, 612, 613, 212, 213,
END

SCENE 607
#include banthing.txt
ACTOR 1, "Wizard", wolfwizboneddruid, 2, 25, 95
IF T317, @sellagain
IF T315, @notsell
1: I have but a few items for sale but they are worth your time.
1: I think.
OFFER 761, 762, 712, 713, 763, 714,
END
@notsell
1: War going on and stuff, I can't possible offer you my wares at this time.
1: Perhaps later, if we survive!
END
@sellagain
1: Ahh, the hero! I'll offer you my wares once again.
OFFER 761, 762, 712, 713, 763, 714,
END

SCENE 608
#include banthing.txt
ACTOR 1, "Paladin", paladin, 1, 25, 95
IF T317, @warended
IF T316, @war
IF T315, @panic
IF ALIVE, @healme
1: There are many perils out there.
1: Be more careful next time.
GIVE L1
GIVE H5000
GIVE M5000
OFFER 1, 2, 6, 7, 8, 9, 10, 16, 17, 18, 24, 25, 65,
END
@healme
1: Welcome to our temple, traveller.
WAIT 1
GIVE L1
GIVE H5000
GIVE M5000
OFFER 1, 2, 6, 7, 8, 9, 10, 16, 17, 18,
1: The temple has a variety of healing items for sale.
1: Some of the profit will be used to help poor people.
END
@panic
GIVE L1
GIVE H5000
GIVE M5000
OFFER 1, 2, 6, 7, 8, 9, 10, 16, 17, 18, 24, 25, 65,
1: The war is here! Yes! War!
1: Oh, I'm sorry I must seem a bit crazy.
1: You should visit the Paladin training temple if you haven't already!
END
@war
GIVE L1
GIVE H5000
GIVE M5000
OFFER 1, 2, 6, 7, 8, 9, 10, 16, 17, 18, 24, 25, 65,
1: Shouldn't you be in the field?
1: Fighting and stuff?
END
@warended
GIVE L1
GIVE H5000
GIVE M5000
OFFER 1, 2, 6, 7, 8, 9, 10, 16, 17, 18, 24, 25, 65,
1: I'm glad it's over! From what I've heard, you're quite a hero.
1: I would be glad to heal you.
END

SCENE 609
#include banthing.txt
IF T317, @warriohi
IF T315, @sota
ACTOR 1, "Knight", paladin, 2, 25, 95, 13
1: We only sell pets that agree to serve their masters.
1: We are no slave traders.
1: We also hire out Paladins of our order 
1: to use their healing abilities to help adventurers.
OFFER 1120, 1121, 1122, 1107,
END
@sota
ACTOR 1, "Knight", paladin, 2, 25, 95, 13
1: I have no time to hire you any pets or mercenaries!
1: Every man and creature I had are helping in the city's defense!
END
@warriohi
ACTOR 1, "Knight", paladin, 2, 25, 95, 13
1: I would be glad to hire you pets or mercenaries.
1: You, after all, played a saviour's role in the war.
OFFER 1120, 1121, 1122, 1107,
END

SCENE 610
#include banthing.txt
ACTOR 1, "Loremaster Larrac", paladin, 1, 25, 95
IF T317, @sotaohi
IF T315, @normal
1: The paladins of Sturmwind have long known
1: the secrets of raising one's abilities.
OFFER 912, 913, 914, 915, 916,
END
@normal
1: Can't sell you anything at the moment.
1: I'm out of stock, everything's used to strengthen our armies.
END
@sotaohi
1: Everything has returned to normal. 
1: And you are to thank. I'll offer my wares to you once again.
OFFER 912, 913, 914, 915, 916,
END

SCENE 611
#include banthing.txt
ACTOR 1, "Crusader", paladin, 2, 25, 95
IF T318, @gotr
IF T317, @warstop
IF T316, @waron
IF T315, @help
IF T313, @t313
IF T312, @t312
IF T311, @t311
IF C10, @train
1: You are not a paladin. I have no business with you.
1: I can only train Paladins.
END
@train
1: Well met, #<g.brother> Paladin!
1: If you have not yet trained here,
1: I can teach you some useful skills!
1: Really useful during your journeys!
H: I have not trained yet.
1: Good, let's start with something simple.
1: Concentrate and learn..
N: You have to spend some time to learn the spell.
N: Just wait.
WAIT 20
1: There you go! Got it?
HOST_GIVE S205
N: Learned Cleansing Aura!
H: I think so.
1: Come back later for more training.
HOST_GIVE T311
END
@t311
1: Welcome back, #<g.brother>.
1: Ready to continue your studies?
H: Yes, I am eager to learn more.
1: Very well, we shall begin.
1: I'll tell you about the history of the Paladins.
1: Listen carefully, for I'll teach you the spell
1: only AFTER the lesson.
WAIT 5
1: No one really knows our origin. We paladins are just
1: a group of heroes following a certain code of honor.
1: We follow the law and see to it that everyone else does too.
1: We are not allowed to own a great deal of money.
1: Well, adventuring paladins like you are.
1: We give most of the money to poor.
1: Sturmwind was established when many paladins found
1: themselves here after their adventures.
1: The first ten paladins of Sturmwind serve as a judge,
1: we bring criminals etc. to be judged by them.
1: We are not allowed to fight unfair.
1: Unfair includes magic, ranged weapons and others that
1: let you shoot your opponent from afar.
1: We dislike battle mages and archers.
1: Well, you've earned your price. Just a moment.
WAIT 8
1: There, that should do it. Got it?
HOST_GIVE S206
HOST_GIVE T312
N: Learned Sacred Valor!
H: Yes, I'll return later to study more.
1: Until that time, then, bye!
END
@t312
1: Welcome back, brother!
1: You are becoming rather famous.
1: Stories of your travels are told by younger paladins.
1: But you still are not a fully capable Paladin.
1: This last lesson is not as simple as those two before.
1: You have to prove your courage by fighting against monsters.
1: Are you prepared?
ASK 300
IF Qyes, @trial
1: Very well, return later, when you are ready to take the test.
END
@trial
1: Very well, you shall be tested.
1: Prepare yourself, #<g.brother>!
WAIT 3
MOVE 1, -50, 100, 1
WAIT 3
THEME 53
FIGHT 170, 172
IF WON, @another
THEME 70
END
THEME 71
@another
N: You hear a distant voice:
WAIT 2
N: "The test is not over yet. Brace yourself!
WAIT 2
THEME 53
FIGHT 171, 172
THEME 70
IF WON, @last 
END
@last
THEME 71
N: Prepare yourself for the final test!
WAIT 2
THEME 52
FIGHT 173, 172, 172
IF WON, @grats
THEME 70
END
@grats
THEME 71
MOVE 1, 25, 90, 1
WAIT 5
1: Very well done! 
1: You are now a fully trained paladin, #<g.sir> %1!
1: I have been given the permission to teach you
1: Lay on Hands, our most powerful healing spell.
1: Just a moment, please.
WAIT 7
1: There you go.
N: Learned Lay on Hands!
HOST_GIVE S207
HOST_GIVE T313
HOST_GIVE T320
1: There is nothing more I can teach you.
1: You'll perhaps get quests later.
1: We paladins are almost always busy helping the weaker.
1: Return once in a while to see if there are any deeds
1: that need to be done.
END
@t313
1: Hello, #<g.sir> %1.
1: There are no deeds available for you at the moment.
1: You may return later and see if there are any deeds available.
END
@waron
1: No time to waste! Go to the battlefield!
1: Every man counts!
END
@warstop
1: Thank you! I heard you helped us quite a lot!
1: Here is your reward, 250 000 gold! That should be enough.
HOST_GIVE G250000
HOST_GIVE T318
HOST_TAKE T316
HOST_TAKE T330
HOST_TAKE T331
HOST_TAKE T332
END
@help
ACTOR 2, "Paladin of Order", army3foot, 4, 55, 95
ACTOR 3, "Paladin of Order", army3foot, 4, 45, 100
FACE 2, 0
1: Sturm, go barricade house doors and protect the civilians!
2: Yes my lord.
MOVE 2, 110, 130
WAIT 7
FACE 3, 0
3: What do you require of me, sire?
1: Franz, I need you to go gather all men cabable of wielding a sword!
1: They are needed in Sturmwind's defence!
3: Yes sire.
MOVE 3, 130, 110
WAIT 7
1: *mumble mumble*
H: What the Hell is going on!?
1: Oh, you startled me! Do not say bad words in our temple!
H: Oh, sc.. Fine! What's going on?
1: What's going on? The lesser nobles of neighbouring countries!
1: They have gone mad! They want the dwarves' mines 
1: because of their rich ore veins!
1: We did not expect them to really attack us so we are a bit.. 1: Unprepared..
H: Can I do anything to help?
1: Well, now that you asked.. Yes. You can.
1: We are short on fighters. We need a bigger army.
1: I have sent many men to gather forces already. 
1: Such is not your task.
1: You will assist in the war, in the more tougher battles.
1: You should go to the road to Khulkist.
1: Enemy groups will try to reach the centre of our city ASAP.
1: You must go there and help our warriors win those battles
1: and stop the enemy from reaching the centre.
1: I hope you understand what needs to be done.
1: If you manage to cut down the enemy commander, return here.
1: The army will surely scatter after that.
HOST_GIVE T316
END
@gotr
1: Thanks again for helping us out in the war, %1.
IF T313, @t313
IF T312, @t312
IF T311, @t311
IF C10-T312, @train
END

SCENE 612
#include banthing.txt
ACTOR 1, "Fighting Instructor", paladin, 2, 25, 90
IF T317, @trainnowar
IF T315, @trainwar
@warri
IF T320, @finished
1: Let's see, what have we here..?
IF C1, @warlord
IF C3, @knight
IF C4, @assa
IF C6, @ogre
IF C9, @ranger
IF C15, @blackelf
IF C10, @hey
IF C32, @plague
1: It seems you are not a class I can train.
1: Oh, what the heck. You need to finish your training
1: in order to worship gods. So, here you go.
HOST_GIVE T320
N: received a token!
WAIT 2
N: You may choose a deity now!
END
@warlord
1: Welcome, Mighty Warlord.
H: I thanks thee manthing. I sees you is not weak with the arm either.
1: No I am not. You're quite perspective for a Skaven.
H: Now, I heard that all kinds of hand classes can train here.
1: That's true but I still don't know what I could help you with.
H: Tests I with battle and gives me something, hrrm?
1: Ahh, that would work. Prepare yourself, then!
H: I am ready.
MOVE 1, -50, 100, 1
THEME 53
WAIT 2
FIGHT 390, 391, 392
IF WON, @warre
THEME 70
END
@warre
THEME 71
MOVE 1, 25, 90
WAIT 5
1: Impressive! Now, what could your reward be.. Let's see.
1: This should be perfect for as mighty person as you!
HOST_GIVE I1191
HOST_GIVE T320
N: received Ragebearer shield!
END
@plague
1: No, you cannot train here, %C32.
END
@knight
1: Welcome #<g.sir> Knight. 
1: Even though you Knights do not believe in the excistence of Gods,
1: atleast you have sense of Honor.
H: In that you're quite wrong, sire. We do believe in Gods.
H: Our holy mission is to sip from the Grail and then serve our 
H: Goddess as Grail Knights.
1: Oh, forgive me, I seem to have mistaken.
1: Now, since this IS a fighter academy, there's something I can teach you, I'm sure.
1: I know. I shall test your might. Should you be powerful enough,
1: I'll give you the Excalibur, a mighty weapon indeed.
H: Excalibur?
1: Yeah, you up for it?
H: You bet!
1: Just a moment.. Prepare for battle!
MOVE 1, -50, 100, 1
WAIT 3
THEME 53
FIGHT 395, 396, 397,
IF WON, @knaitti
THEME 70
END
@knaitti
THEME 71
MOVE 1, 25, 90
WAIT 5
1: Well done, you have defeated those who opposed you.
1: I am proud to give you the Excalibur!
WAIT 3
N: You got the Excalibur!
HOST_GIVE T320
HOST_GIVE I1192
END
@assa
1: Skaven Assassin, is it?
1: I personally think all who need shadows to win,
1: are cowards.
H: But it is goodie to sink you dagger to you enemy without the idiot even noticing..
1: You are without honor, #<g.sir>.
H: I cares not for humans' measly sense of "honor".
H: I cares about surviving.
1: Hmm, let's see. I'm not quite sure what I can teach you..
1: Oh, what the heck. You need to finish your training
1: in order to worship gods. So, here you go.
HOST_GIVE T320
N: received a token!
WAIT 2
N: You may choose a deity now!
END
@ogre
1: Uhh, welcome to the Academy, %1.
1: I see that you're a.. Rat Ogre.
1: I'm not quite sure what I could do to furthern your training.
1: Oh, what the heck. You need to finish your training
1: in order to worship gods. So, here you go.
HOST_GIVE T320
N: received a token!
WAIT 2
N: You may choose a deity now!
END
@ranger
1: Interesting, woodland folk.
1: Hmm, I can't really think of a suitable reward for you..
1: Ahh, I know! Should you master the trial I have for you,
1: You get to choose a summon pet spell from several different.
1: These pets are more powerful than normal pets.
1: But you can only choose one.
1: Now, are you ready for the trial?
ASK 100
IF Qyes, @rangtri
1: Come back when you're ready to take the trial.
END
@rangtri
1: Good, everything's prepared!
WAIT 3
MOVE 1, -50, 100, 1
THEME 53
FIGHT 371, 371, 372
IF WON, @rangwin
THEME 70
END
@rangwin
THEME 71
MOVE 1, 25, 90
WAIT 7
1: Very well done indeed!
1: Just a minute..
WAIT 4
1: Now you get to choose the summon.
WAIT 2
GOTO @ranqpalkinto
END
@ranqpalkinto
MENU "Raging Tiger=@tigru","Night Gnoll=@gnoll","Mana Hawk=@hawk","Hell Hound=@hellhound",
	GOTO @ranqpalkinto
END
@tigru
1: A good choice, here you go.
WAIT 3
HOST_GIVE S232
HOST_GIVE T320
N: You learned Call Raging Tiger!
END
@gnoll
1: A good choice, here you go.
WAIT 3
HOST_GIVE S230
HOST_GIVE T320
N: You learned Call Night Gnoll!
END
@hawk
1: A good choice, here you go.
WAIT 3
HOST_GIVE S231
HOST_GIVE T320
N: You learned Call Mana Hawk!
END
@hellhound
1: A good choice, here you go.
WAIT 3
HOST_GIVE S233
HOST_GIVE T320
N: You learned Call Hell Hound!
END
@blackelf
1: Hmm, of all the classes I get to train you.
1: Miserable Chaos Elf.
1: Some say you all are tainted by chaos.
1: That the Alliance would be better off without you.
H: Maybe so but we don't need them either.
WAIT 3
1: Anyways, I have been instructed to train you.
1: So, it's a simple deal. You will fight against some monsters.
1: If you win, I'll teach you the ultimate use of your weapon.
1: So you get the ultimate mastery shield.
1: In addition, I'll give you a powerful weapon called the Beast.
;1190, the Beast... 159, ultimate mastery
1: Sound good?
ASK 100
IF Qyes, @fine
1: Come back when you have the courage..
END
@fine
1: Fine. This fight will not be the most easy of battles..
1: I couldn't care less if you die.
1: Prepare yourself, the battle is about to begin..
WAIT 4
MOVE 1, -50, 100, 1
THEME 53
FIGHT 199, 199, 198
IF WON, @blargh
THEME 70
END
@blargh
THEME 71
MOVE 1, 25, 90
WAIT 7
1: Hmm, fine. I quess you have deserved these..
HOST_GIVE T320
HOST_GIVE I159
HOST_GIVE I1190
END
@hey
1: Hello fellow Paladin.
1: I'm sorry but I cannot train you.
1: You should visit the Paladin training temple.
END
@finished
1: You have already finished your training.
1: I cannot teach you more.
END
@trainwar
1: Even at times of war the academy trains people.
1: After all, at times such as this it is important
1: everybody knows what to do.
GOTO @warri
END
@trainnowar
1: War has ended.
1: The academy still trains those who need to learn.
GOTO @warri
END

SCENE 613
#include banthing.txt
ACTOR 1, "Elf Ranger", elf, 1, 25, 90
IF T921, @don
IF T922, @check
1: Hello and well met.
1: No, I do not have any quests for you that require
1: slaying Dwarves. They are an important part of the city's defense.
1: But I *do* have another important task.
IF V99, @skell
1: But you are too low level to even try completing it.
END
@skell
1: You DO know of the dungeon called Cleft of the Dead?
1: And you know that we elves hate everything that's dead and moves.
1: Dead spirits, skeletons.. They need to be removed.
1: They are unnatural.
1: What I would have you do.. Is to go in the Cleft of the Dead..
1: And kill some of these creatures for me.
1: Kill 10 Skeleton Elites and 5 Frost Spirits for me.
HOST_GIVE T922
1: You might consider taking a few friends with you.
1: However, you have to make the killing blow to get the kill.
GOTO @check
END
@check
IF KM444.10, @enuff
1: You have not killed enough of Skeleton Elites yet.
END

@enuff
IF KM447.5, @enuff2
1: You have not killed enough of Frost Spirits yet.
END

@enuff2
1: You have already killed them? Very well done!
1: Here, take this %I242 as a reward!
HOST_GIVE T921
HOST_GIVE I242
N: received %I242.
END
@don
1: Hello and well met.
1: No, I do not have any quests for you that require
1: slaying Dwarves. They are an important part of the city's defense.
1: But I *do* have another important task.
1: Ahh, but you have already completed it.
1: Thanks again.
END

END

SCENE 614
#include banthing.txt
ACTOR 1, "Dwarf Warrior", dwarf, 2, 25, 100
1: Ah har har, hello and well met me friend, hero of war.
1: This be the dwarven miners' and smiths' guild.
1: Here ye get mighty items o' destruction forged.
1: Ye just needs lots o' gold and some rare items.
1: It's a good deal still,  #<g.lad>..
1: These items are very rare and powerful.
1: Many o' them have the power o' elements..
END

SCENE 505
#include banthing.txt
IF T330, @nothing
THEME 53
N: You haven't even got the time to draw breath!
WAIT 2
FIGHT 190,190,190,191,191,-192,-192,-193
IF WON, @ekavoitto
THEME 70
END
@ekavoitto
THEME 71
HOST_GIVE T330
H: The 1st tide has been turned..
H: My help is still needed.
END
@nothing
H: There's nothing here but corpses..
END

SCENE 506
#include banthing.txt
IF T331, @nothing2
THEME 53
N: You haven't even got the time to draw breath!
WAIT 2
FIGHT 190,190,190,190,191,191,191,191,-192,-192,-193,-193,
IF WON, @tokavoitto
THEME 70
END
@tokavoitto
THEME 71
H: Second battle has been won.
H: There is still more to do.
HOST_GIVE T331
END
@nothing2
H: Bah, only vultures circling around.
END

SCENE 507
#include banthing.txt
IF T332, @nothing3
THEME 53
N: You haven't even got the time to draw breath!
WAIT 2
FIGHT 190,190,190,191,191,191,195,195,-194,-193,-192,-193,-192,-192
IF WON, @kolmasvoitto
THEME 70
END
@kolmasvoitto
THEME 71
HOST_GIVE T332
H: I think I see the commander..
H: The bastard won't live long..
END
@nothing3
H: Nothing living left here..
END

SCENE 508
#include banthing.txt
IF T333, @nothing4
THEME 62
N: You haven't even got the time to draw breath!
WAIT 2
FIGHT 191,191,191,191,195,195,195,196,-194,-193,-193,-192,-192,-192
IF WON, @vikavoitto
THEME 70
END
@vikavoitto
THEME 71
HOST_GIVE T317
HOST_GIVE T333
H: The battle is won..
H: I should return to the Paladin training temple.
END
@nothing4
H: I really should return for my reward.
H: The Paladin training temple, remember?
END

SCENE 509
#include banthing.txt
ACTOR 1, "Knight of Paladine", aurilite, 4, 25, 90
ACTOR 2, "Knight of Paladine", aurilite, 3, 50, 75
IF T340, @greet
IF T320, @check
IF T313, @check
1: I'm sorry. You must finish your class training
1: before picking a deity.
END

@check
IF T340, @wellmet
IF T341, @sor
IF T342, @sor
1: What are you doing in this holy temple, devoted to Paladine?
1: Are you here to serve Paladine, God of Order?
IF -V80, @tooyoung
1: If you are, be warned. You might change class.
1: And that might affect your spell elements.
WAIT 2
N: Note that after changing classes there's no way back.
WAIT 2
N: You might not be able to use some of the spells you have now.
WAIT 2
N: You might not be able to use those spells you got from class training!
WAIT 2
1: So, here to serve?
ASK 300
IF Qyes, @paladi
1: Then I have to ask you to leave.
END
@paladi
1: Let's see if you can follow him into the light.
WAIT 4
IF -V80, @tooyoung
IF C1, @nou
IF C2, @nou
IF C3, @kop
;done
;kop=knight of paladine
IF C4, @nou
IF C5, @radiant
IF C6, @nou
IF C7, @bringer
;done
IF C8, @arch
;done
IF C10, @pala
;done
IF C9, @rangur
;done
IF C15, @dh
;demonhunter
IF C32, @plague
IF C30, @alke
1: It seems not. Get out, you spawn of.. Whatever.
END

@alke
1: You may not serve Paladine, goblin.
1: Find Talos' temple, I'm sure you can serve him..
END

@plague
1: You're a plague carrier. You have no place here.
END
@wellmet
1: Well met, #<g.sir> %1.
1: There are no tasks for you at the moment.
1: Return later and maybe there will be something.
END


@sor
1: I'm sorry, you have chosen to follow another god.
END


@nou
1: You are too villainous to follow Paladine.
1: Do not defile this temple with your presence anymore.
END


@kop
1: Well met, #<g.sir> Knight!
1: If you decide to follow Paladine, you'll become more Paladin-like.
1: The opposite of Dread Guards.
1: I must ask you again, do you wish to follow Paladine?
ASK 300
IF Qyes, @kop2
1: Well, I'm sorry you have decided not to.
END


@radiant
1: Well met, Planar being.
1: Do you truly wish to serve Paladine and become a Radiant Guard?
ASK 300
IF Qyes, @radiant2
1: Well, I'm sorry you have decided not to.
END


@bringer
1: Well met, #<g.sir> mage.
1: If you decide to serve Paladine, you'll become a Lightbringer.
1: Do you wish to serve Paladine in Light?
ASK 300
IF Qyes, @bringer2
1: Well, I'm sorry you have decided not to.
END


@arch
1: Well met, #<g.sir> mage.
1: Do you wish to serve Paladine and become a Arch Mage?
ASK 300
IF Qyes, @arch2
1: Well, I'm sorry you have decided not to.
END


@pala
1: Well met, #<g.sir> Paladin.
1: Do you wish to follow Paladine and stay as an icon of virtue?
ASK 300
IF Qyes, @pala2
1: Well, I'm sorry you have decided not to.
END


@rangur
1: Hello, #<g.sir> Ranger.
1: Do you wish to serve Paladine and stay as a Ranger?
ASK 300
IF Qyes, @rangur2
1: Well, I'm sorry you have decided not to.
END


@dh
1: Well met, #<g.sir> Chaos Elf..
1: What is your business in here..
1: Have you perhaps come to join the forces of Goodness?
ASK 300
IF Qyes, @dh2
H: Haha, *I* would serve Paladine?
H: Never, foolish old man!
1: Leave this temple at once, Defiler!
H: I will, for now. I'll come for your head soon..
END


@dh2
1: You have done the right decision.
1: Maybe there is hope for your kind still.
1: You will now become a Demon Hunter.
1: Select MAP or STATS to prevent freezing.
1: The game will kick you out of the scene as soon as
1: you've received all spells etc to prevent freezing.
1: You will receive %S251, %S250 and %S255.
1: You will also receive %I1230 and %I1231.
WAIT 4
SET num.hostClass, 28
HOST_GIVE S251
HOST_TAKE S250
HOST_GIVE S255
HOST_GIVE T340
HOST_GIVE I1230
HOST_GIVE I1231
GOTO EXIT
END


@rangur2
1: Good choice #<g.sir> %1.
1: Your class will not change but you will receive useful stuff.
1: Just a moment.
1: Select MAP or STATS to prevent freezing.
1: The game will kick you out of the scene as soon as
1: you've received all spells etc to prevent freezing.
1: You will receive %S254, %S255, %I1233 and %I1232.
WAIT 4
HOST_GIVE I1232
HOST_GIVE I1233
HOST_GIVE T340
HOST_GIVE S254
HOST_GIVE S255
GOTO EXIT
END


@pala2
1: You have done the right choice, #<g.sir> %1.
1: You won't be class changed because you already are an icon of virtue.
1: Instead, I will give you a couple of useful items and spells
1: with which to fight evil.
1: Select MAP or STATS to prevent freezing.
1: The game will kick you out of the scene as soon as
1: you've received all spells etc to prevent freezing.
1: You will receive %S254, %I1235 and %I1234.
WAIT 4
HOST_GIVE I1234
HOST_GIVE I1235
HOST_GIVE T340
HOST_GIVE S254
GOTO EXIT
END


@kop2
1: You have done a good decision, #<g.sir> %1.
1: Come, change to Knight of Paladine!
1: Select MAP or STATS to prevent freezing.
1: The game will kick you out of the scene as soon as
1: you've received all spells etc to prevent freezing.
1: You will receive %S256, %I1236 and %I1237.
WAIT 4
SET num.hostClass, 20
HOST_GIVE I1236
HOST_GIVE I1237
HOST_GIVE T340
HOST_GIVE S256
GOTO EXIT
END


@arch2
1: Good choice, #<g.sir> %1.
1: You will now become an Arch Mage.
1: Select MAP or STATS to prevent freezing.
1: The game will kick you out of the scene as soon as
1: you've received all spells etc to prevent freezing.
1: You will receive %S257, %I1238 and %I1239.
WAIT 4
SET num.hostClass, 25
HOST_GIVE S257
HOST_GIVE I1238
HOST_GIVE I1239
HOST_GIVE T340
GOTO EXIT
END


@bringer2
1: Good choice, #<g.sir> %1.
1: You will now become a Lightbringer.
1: Select MAP or STATS to prevent freezing.
1: The game will kick you out of the scene as soon as
1: you've received all spells etc to prevent freezing.
1: You will receive %S257, %S258, %I1238 and %I1239.
WAIT 4
SET num.hostClass, 27
HOST_GIVE S257
HOST_GIVE S258
HOST_GIVE I1238
HOST_GIVE I1239
HOST_GIVE T340
GOTO EXIT
END


@radiant2
1: Good choice, #<g.sir> %1.
1: You will now become a Radiant Guardian, a beacon of light
1: in these dark and troubling times.
1: Select MAP or STATS to prevent freezing.
1: The game will kick you out of the scene as soon as
1: you've received all spells etc to prevent freezing.
1: You will receive %S256, %S259, %I1237 and %I1239.
WAIT 4
SET num.hostClass, 23
HOST_GIVE S256
HOST_GIVE S259
HOST_GIVE I1237
HOST_GIVE I1239
HOST_GIVE T340
GOTO EXIT
END

@greet
1: Welcome back, %1.
1: May Paladine guide your steps..
END

@tooyoung
1: You are not experienced enough.
1: Come back once you're level 80 or higher.
END

;go away!!!

