;
; Copyright 1999-2000 (c) Synthetic Reality Co.
; http://www.synthetic-reality.com
; All Rights Reserved
;
; Note to players:  Don't read this until you have finished playing the world, as this
; cannot possibly enhance your experience and will no doubt rob you of small pleasures.
;
;
;
;
;----------------
; CREDITS section

+CREDITS
The Summoner
A world from Markiller aka Dragon King (DK) aka Mark Watkinson
Story by Mark Watkinson
Skins by Josh Worts and Mark Watkinson
Other skins Taken from player skins, and credits left in where present
Other Art by Dan Samuel
Most music by Dan Samuel, with the help of JAMMER(r)
Some music (from Final fantasy) accumulated from other worlds.
	
Programming by Synthetic Reality
Contact us on the web at:
http://www.synthetic-reality.com
Blackmap background fix by Demi as of 1/28/2023
-CREDITS

;--------------
; STORY Section
+STORY
:S 200
:C 255,255,0
|The summoner
:S 75
:C 255,255,255
|~~~
|by Mark Watkinson
|Alias Dragon King (DK) or Markiller
|Skins by Josh Worts and Mark Watkinson
|Music by Jammer and ahadikeen@aol.com
|~~~ 
:S 100
:C 204,153,0
Summoners. Summoners are people with spectacular capabilities to summon any creature forth to do their bidding. Many have spent their lives improving their skills, others have not.
The isle of the summoners however is a deadly one. Filled with many creatures. And secrets.
No-one has ever left the island, though many have tried. Those who have tried speak of a barrier between them and the seemingly never ending sea.
Today is your 16th birthday, but are you monster or summoner?
Summoners are feared for their skills so dont expect to have an easy life...
Monsters can possess the creatures of the island.
:F Arial Italic
:C 255,0,0
Prepare yourself...
-STORY

;---------------------
; TERRAINS Section
;
+TERRAINS
;	arg0	arg1				arg2
;
	0,		"No Hindrance",		0
	1,		"Lava",			20
	2,		"Tall cliff",		0
	3,		"Forest",			1
	4,		"Deep Water",		5
	5,		"Dirt",			0
	6,		"Cliff",			0
	7,		"Rock",			0
	8,		"Healing",			-10
	9,		"Impassable",		0
-TERRAINS



;---------------------
; EQUIP names section
;

+EQUIP
;	arg0	arg1
;	ID		Name

  	0,		"Helmet"
 	1,		"Armor"
 	10,		"Accesory"
 	11,		"Shield"
 	12,		"Ring"
 	13,		"Amulet
-EQUIP

;--------------------
; MAPS section
;
+MAPS

;
; The actual map definitions are in this file, which is created by the New World Wizard:
;
#include maps.txt

-MAPS


;--------------------
;TOKENS SECTION
;
#include Tokens.txt
;---------------------
; ELEMENTS Section
; 
+ELEMENTS
;	arg0	arg1				
;
	0,		"Herbal"		
	1,		"Ice"			
	2,		"Nature"			
	3,		"Earth"			
	4,		"Death"		
	5,		"Flame"		
	6,		"Spirit"		
	7,		"Lightning"	
-ELEMENTS

;-----------------------
; HANDS section
+HANDS
;  
; arg0		arg1		arg2		arg3
;  ID		Name		Range		SoundFX
;
	0,		"Sword",	30,			"sword1.wav"
	1,		"Staff",	20,			"staff.wav"
	2,		"Bow",		100,		"sword8.wav"
	3,		"Music",	50,			"chirp4.wav"
	4,		"Fist",		20,			"fist.wav"
	5,		"Dart",		80,			"dart.wav"
	6,		"Book",		70,			"chant6.wav"
	7,		"Spirit",	90,			"crow1.wav"
-HANDS


+ITEMS

; The actual item definitions, and documentation, are in this file:
#include items.txt
#include Itempets.txt
-ITEMS


+SPELLS

; actual spell definitions, and documentation, are in this file:
#include spells.txt

-SPELLS


+MONSTERS

; actual monster definitions, and documentation, are in this file:
#include monsters.txt

-MONSTERS


+GROUPS

; actual groups, and documentation, are in this file
#include groups.txt

-GROUPS


+LEVELS

; actual character classes, levels, and documentation are in this file
#include levels.txt

-LEVELS



;-------------------
; Individual Scenes (each needs a unique scene number)
;
+SCENES
;--------------
; SCENE 0 must be primary well of souls
SCENE 0		temple, WELL, "Well of Souls", 2, 7
	THEME	1
	ACTOR	1,	"The Ancient summoner", joshMiscellaneous, 10, 0, 60
	SEL		1
	POSE	10,10,11
	MOVE	1,	50, 60
	WAIT	1.0
	' Welcome to the land of the_summoner, traveler.
	' If you are new to this realm listen carefully!
	' Summoners. Summoners are people with spectacular capabilities to summon any creature forth to do their bidding. Many have spent their lives improving their skills, others have not.
	' The isle of the summoners however is a deadly one. Filled with many creatures. And secrets.
	' No-one has ever left the island, though many have tried. Those who have tried speak of a barrier between them and the seemingly never ending sea.
	' Today is your 16th birthday, but are you monster or summoner?
	' The path of a summoner summoning beasts, summoners are feared for their skills so dont expect to have an easy life...
	' The path of a monster possessing the bodies of creatures, monsters are also feared, and many are slain on sight.
	MOVE	1,	45, 60
	' I can help you create a new soul, or restore a treasured one.
	MOVE	1,	30, 70
	' When you are ready, select your soul and then incarnate into the physical world.
	MOVE	1,	40, 75
	' Notice the buttons along the bottom of your screen.  Point to a button to see its name.
	' Press the NEW button to create a new soul, and select its skin and abilities.
	MOVE	1,	25, 70
	' Press the RESTORE button to select an old soul, and resume its struggle.
	MOVE	1,	35, 65
	' Press the INCARNATE button to enter the physical world again.
	MOVE	1,	30, 70
	' Press the MAP button to see what other souls roam the world.
	MOVE	1,	40, 77
	' Press the HAUNT button to spy invisibly over another incarnated soul.
	MOVE	1,	20, 70
	' You may rest here safely, for as long as you like.
END

;--------------
; SCENE 1 must be primary CAMP scene
;
SCENE 1
	THEME
;	MUSIC   (no music in camp scene, just theme)
#include steal.txt
#include proxbeta.txt
#include class1.txt
; Check is this is a PK Attack (uses CAMP scene, not FIGHT scene, oddly enough)

	COMPARE #<num.isPKAttack>, 1
	IF= @pk
	COMPARE #<num.isPKAttack>, 2
	IF= @pk	
;Desert
COMPARE #<num.mapNum>, 11
	IF=	@inDesert
COMPARE #<num.mapNum>, 12
	IF=	@inDesert
GOTO @notdesert
@Indesert
GOTO @lifecheck
@indesert1
GOTO SCENE 56
@lifecheck
IF ALIVE @indesert1
@notdesert
COMPARE #<num.hostClass> "35"
IF= @live
IF> @monstercamp
IF alive @live
;Death!
ACTOR	1,	"Ghost", joshMiscellaneous, 2, 25, 90
MUSIC  lost.mid
1: Death is not for the living.
1: You are dead but it is not your time.
1: I can transport you back to the soul brother, he will resurect you, is that what you want?
ASK 30
IF Qyes @warp
H: Not yet I want to explore the world between life and death.
1: So be it
SEL 1
MOVE 1, -10, -10, 1 
END
@warp
H: Being dead stinks.
1: Tell me about it....
1: Well see you when it is your time.
GOTO LINK 1, 3, 1
END
@monstercamp
If ALIVE @live
ACTOR	1,	"Ghost", joshMiscellaneous, 2, 25, 90
MUSIC  lost.mid
1: Another Dead monster?
1: There are a lot of you guys arround lately, well back to the fires of hell with ya!
WAIT 2
GOTO LINK 18, 1, 1
@live
SET thirst, "0"
COUNTDOWN 0
SET leave, "0"
#include hunt.txt
	END

;
; It *is* a PK Attack, so we set up some special rules to make it 'honorable'
;
@pk
MUSIC  battle.mid
	; Set map flags: 32768 (no nasty spells) + 8192 (no tickets) + 4096 (no Heal)
	FLAGS	45056
	LOCK 1
	N: PK Attack! 
	N: Locked Camp!
	N: No Healing, Stunning, or Tickets!
	END
@eventPkAttackDone
	LOCK 0
	FLAGS 0
	END
#include scene2.txt

;--------------
; SCENE 3 (Healing)
;
SCENE 3		aztec
#Include prtychk.txt
#include steal.txt
#include banning.txt
	THEME	0
;	MUSIC	waltz2.mid
	ACTOR	1,	"Soul Brother", joshRoyalty, 5, 25, 90
	POSE	5, 5, 13
	SEL		1
	MOVE	1,	15, 80
COMPARE #<num.hostClass> "35"
IF> @monster
IF= @skip1
	IF T1000 @cheatres
	IF ALIVE, @skip1
	' You have lost your footing in this realm and died, wait while I resurrect you.
	WAIT    4.0
	SOUND	"thunder1.wav"
	WAIT	1.0
@skip1
	MOVE	1,	10, 75
	GIVE	L1
	GIVE	H5000
	GIVE	M5000	
	' Blessings upon you, young Summoner.
	' You are always welcome here, to rest and recover...
	' Do you need a ticket home?
ASK 5
IF Qyes @tic
1: Ok well I have a lot to sell
OFFER 1, 2, 3, 4, 7, 12, 13, 14, 15, 16, 18, 19, 24, 27, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38
STRCMP #<str.soul>, "6EC0F0C7"
IF= @offeradmin
END

@offeradmin
IF T578+T577+T579 @gotadminalready
1: Welcome Markiller!
1: Im afraid I didn't notice it was you at first!
1: Are you here to recieve the admin weapons?
@askadminweapons
ASK 30
IF YES @getadminweapons
IF NO @gotadminalready
GOTO @askadminweapons
@getadminweapons
HOST_GIVE T578
1: Ok, here they are.
HOST_GIVE I870
HOST_GIVE I871
HOST_GIVE T577
HOST_GIVE I872
HOST_GIVE I873
HOST_GIVE T579
;Need to give item IDs when done, also remember hacker protection
@gotadminalready
COMPARE #<num.hostClass> "35"
IF> @monster2
END

@tic
	OFFER 99
END
@cheatres
	IF ALIVE, @skip2
	TAKE G1000000
	' You have lost your footing in this realm and died, wait while I ressurect you.
	WAIT    4.0
	SOUND	"thunder1.wav"
	WAIT	1.0
@skip2
	MOVE	1,	10, 75
	GIVE	L1
	GIVE	H5000
	GIVE	M5000	
	' Curses upon you, Summoner.
	' You are a cheater, and are not welcome here, Buy what you must and begone!
OFFER 1, 2, 3, 4, 7, 12, 13, 14, 15, 16, 18, 19, 24, 27, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38
END

@monster
STRCMP #<str.soul>, "6EC0F0C7"
IF= @offeradmin
@monster2
1: Oh my goodness, leave here you fiend!
1: You are not wanted here evil one!
1: I will bannish you back to the depths of hell!
1: Chio....
1: Malio...
1: Sialo!
GOTO LINK 18, 1, 1
END

;--------------
; SCENE 4 Generic Casino
;
SCENE 4		aztec
#Include prtychk.txt
#include steal.txt
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Barker", joshRoyalty, 2, 25, 90
	SEL		1
	MOVE	1,	15, 80
	GAME	1
	' Try your luck!
	' Our slots pay the most!
END




;---------
; general armor shop

SCENE 5 bwEuroStreet
#Include prtychk.txt
#include steal.txt
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Daniel", joshTownsFolk, 17, 25, 90
	SEL		1
	MOVE	1,	15, 80
	OFFER2	0,99,10,0,99,11,0,99,20,0,99,21
	' Finest armor in Evergreen!
END

;---------
; general weapons shop

SCENE 6 bwEuroStreet
#Include prtychk.txt
#include steal.txt
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Josh", joshTownsfolk, 9, 25, 90
	POSE	9,10
	SEL		1
	MOVE	1,	15, 80
	OFFER2	0,99,12,0,99,13,0,99,14,0,99,15
	' Finest weapons in Evergreen!
END

;---------
; general baubles shop

SCENE 7 bwEuroStreet
#Include prtychk.txt
#include steal.txt
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Michelle", joshTownsFolk, 24, 25, 90
	POSE	24,25
	SEL		1
	MOVE	1,	15, 80
	OFFER2	0,99,22,0,99,23
	' Finest rings and amulets in Evergreen!
END


;---------
; item/potion shop
;
SCENE 8 bwEuroStreet
#Include prtychk.txt
#include steal.txt
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Charley", joshTownsFolk, 9, 25, 90
	POSE	9,10
	SEL		1
	MOVE	1,	15, 80
	OFFER2	0,99,0

	' Note our new items for sale.
END

;---------
; seed shop
;
SCENE 9 bwHangar
#Include prtychk.txt
#include steal.txt
	THEME	0
	MUSIC	waltz2.mid
	ACTOR	1,	"Abe", joshRoyalty, 11, 25, 90
	POSE	11,4
	SEL		1
	MOVE	1,	15, 80
	OFFER	8,20,21,22,23,25
	' Please persue my wares for the experienced adventurer.
END

;Quest1 : "First summon"
;At home
SCENE 10 Schoolhouse
#Include prtychk.txt
#include steal.txt
#include class1.txt
ACTOR 1, "Dad", joshTownsfolk, 1, 25, 90
POSE 1, 7
ACTOR 2, "Mom", joshTownsfolk, 2, 20, 85
POSE 2, 3
COMPARE #<num.hostClass> "35"
IF> @monster
IF= @monster
IF ALIVE @alive
	1: OH NO!
	2: /a sobs
	1: My #<g.son> you are dead!
	2: Dead...
MOVE 2, -20, 90
WAIT 1
1: Wait come back dear!
MOVE 1, -20, 90
If -T42 @endhome
WAIT 2
ACTOR 1, "Grandfather", joshMiscellaneous, 10, 25, 90
MOVE 1, 25, 90, 1
POSE 10, 11
If T45 @helloagainGdad
H: WHAT???
1: Hello %1
1: I am your grandfather!
H: Of course, so you really do haunt this place then?
1: Yep, well Im not here without reason!
H: Really?
1: Yep, you know the tower, where no-one can get in?
H: yes, the one in the mountains
1: Thats the one, I know how to fight the dragon!
H: Really, how do you know that?
1: Because thats how I died!
H: GULP
1: The spell is 'teletrans' Say it at the tower entrance
1: well Ill be here if you want me.
GIVE T45
END
@helloagainGdad
H: Hello again grandad!
1: Hello %1
If T47 @endhome2
1: Well give that dragon one for me!
END
@endhome2
1: I see you killed the dragon, thats good :)
@endhome
END
@alive
IF T61-T62 @desertwarn
IF T53-T54 @Tsiaed
IF T42-T43 @mountains
If T41-T42 @AboutGfather
If T1 @birthday
If T2-T3 @forest
If T2+T3+T4-T5 @Welldone
If T2+T3+T4+T5-T21 @Oldman
If T24+T25-T26 @cursecure
If T21+T22-T23-T24-T25 @cursewarn
If T31-T32 @Statuewarn
If T24+T27-T28 @Goseeoldman
IF T81-T84 @UltimateSummons2
IF T68-T84 @UltimateSummons
 2: Hello #<g.son>.
 1: Why arnt you out-a-questing you %3?
 2: Danniel!
 1: Sorry....
 2: /a smiles
END
@UltimateSummons
1: %1 my #<g.son>, I believe you are ready!
H: Ready, for what?
1: The ultimate summons!
1: I can summon them, and they are strong, however I cannot controll them.
1: So are you ready?
ASK 20
If Qyes @fightUSummons
1: Well come back when you are ready!
GIVE T81
END

@UltimateSummons2
1: Are you ready to try agaonst the Ultimate Summons again?
ASK 20
If Qyes @fightUSummons
1: Well come back when you are ready!
END

@fightUSummons
H: I am ready
1: Yes you are ready
GIVE T82
FIGHT 601, 602
if alive @winUSummons
GIVE T83
1: On no #<g.son>!
1: You lost!
2: My #<g.son>!
END

@winUSummons
1: YOU did it!
2: Congratulations #<g.son>!
GIVE T84
GIVE T1601
GIVE T1602
END

@desertwarn
H: Im going into the desert in search of the white dragon!
2: Oh no, the DESERT!
1: %1 be warned, water is scarce in the desert, I suggest you take PLENTY to drink.
H: Ok dad, I will
GIVE T62
END
@Tsiaed
H: Dad who am I?
1: You are %1
H: No my real name, is it #<g.Saied>?
1: !!
2: Oh dear.
1: Yes #<g.son>, your real name is #<g.Saied>
1: We heared the legend, and we didnt want you out risking your life.
2: So we changed your name to %1
1: We thought it may stop you from compleating the legend
H: Its destiny
2: Yes
1: #<g.son>, go compleate your destiny.
GIVE T54
END
@AboutGfather
1: Hello #<g.son>
H: hello Dad
1: Did I tell you about your grandfather?
1: He was a GREAT summoner
1: However one day he set out to the mountains, and never returned.
H: Thats sad.
2: I stll hear him at night!!!
1: Shhhh dear
2: But its true!
1: Your mother thinks that your grandfather still haunts the house.
H: Hmmmmm
GIVE T42
@mountains
H: Dad Im off to the mountains!
2: Oh no, dont go there #<g.son>!
2: Dont make the same mistake as your grandfather!!!
1: And becides the temple there is INACESSABLE, but if you MUST go, then go.
GIVE T43
END
@Cursewarn
H: Hello Dad, Mum
1: Hello #<g.son>!
H: I spoke with that old man.
1: And?
H: He told me of a dragon in the caves.
N: You notice fear in their eyes.
WAIT 2
MUSIC "Dragon's Cave.mid"
H: What is it?
1: the curse!
2: the curse of the red dragon!
1: You mustn't go there #<g.son>, or you will be cursed!
H: But I must, curse or no curse, i will deafeat the dragon and the curse!
N: Clearly unhappy your mother leaves
MOVE 2, -10, 90
WAIT 5
1: #<g.son> please be careful, and by the way, you wont get far without a rope and pick axe.
GIVE T23
END
@Cursecure
MUSIC "Dragon's Cave.mid"
H: Father I am cursed!
1: I warned you of the dragons curse, you must act swiftly #<g.son>!
H: But how will I cure the curse?
1: Only with the banishment spell, but I do not know it.
2: I do!
H: Really, Quickly what is it?
2: 'Cursemenot'
1: #<g.son> you must goto the the cave and bannish the spirit.
H: I will!
GIVE T26
END
@Goseeoldman
H: I cured the curse!
2: Thank goodness!
1: You should go back to the old man and let him know.
H: Yes I will do that.
END
@birthday
1: Happy birthday #<g.son>!
2: Yes happy birthday!
1: Today you are sixteen and...
2: 16 so soon...
1: Yes dont interupt Shelia you %3!
2: Sorry.
N: Awkward silence
WAIT 2.0
1: Anyway #<g.son> as I was saying, today you are sixteen and today you are to leave home and begin your journey to become a better summoner!
H: But...
1: Dont you interupt either %1 my #<g.son> you %3!
1: Where was I...
1: Ahh yes today you become a summoner!
1: You will learn to summon POWERFUL monsters and cast spells an stuff just like I did!
H: /a yawns
H: exciting stuff...
1: Yes, rather.
1: To learn a summon kill a monster, and then check out your 'new spells'. Learn the spell and summon the BEAST!
1: Oh and take some time to visit the training town to the east, thats where all new adventurers start out!
1: Well any way here are your gifts.
TAKE T1
GIVE T2
GIVE I250
GIVE I300
GIVE I350
GIVE I400
GIVE I450
GIVE I500
GIVE I550
GIVE I600
GIVE I650
GIVE I800
N: Recieved Chemise
N: Recieved Leather Shield
N: Recieved A set of weapons
H: Thanks dad.
1: Yes well...
@forest
2: Tell #<g.him> about the forest Danniel!
1: Yes Shelia I was comming to that.
1: #<g.son> there is a forrest near-by you must travel through...
2: But be careful it is filled with goblins!
1: Hence the name Goblin Forest
H: Thats a little corny....
1: What? Anyway you must go there for your first summon, The first stepping stone towards summoning the strongest of creatures!
1: Also watch out for those thieving goblins- they're everywhere.
2:Good luck #<g.son>!
Give T3
END
@Welldone
1: #<g.son>, you have got your first summon!
2: Well done %1!
1: #<g.son>, I want to give you this knowlege, it is a great and powerful dragon summon!
GIVE T5
GIVE T1201
1: Now continue the quest my #<g.son>, I believe you will go far!
@Oldman
2: /a looks out of window
2:That strange old man is still out there.
1: Yes very strange...
GIVE T21
END
@Statuewarn
H: Im off to the north-eastern island!
2: Oh yes, you need a holiday 
H: But...
1: You havent the time for a holiday, what about the quest for the old man?
H: But...
1: Stop slacking off you %3!
H: But the old man HAS TOLD me to fo there, thats where the blue gem is!
1: Oh really........., well anyhow, wile you are there check out that old statue in the forest.
H: What statue?
1: On the island, rumour has it that it has something to do with that blue dragon.
H: ok thanks as always for the tips dad.
GIVE T32
END

@monster
ACTOR 1, "Danniel", joshTownsfolk, 1, 25, 90
POSE 1, 7
ACTOR 2, "Shelia", joshTownsfolk, 2, 20, 85
POSE 2, 3
2: Help a MONSTER!
1: DIE BEAST!
MOVE 2, -20, 90
2: BE careful dear!
@dadattack
1: /a attacks you
HOST_TAKE H100
1: AHHHHHHH!
END

;Quest 2 "Saving the goblin"
;In goblin forest saving the goblin
SCENE 11 lane
#Include prtychk.txt
#include steal.txt
#include class1.txt
ACTOR 1, "Goblin", josh26, 1, 25, 90
POSE 1, 2
IF T11-T12 @Tryagain
IF T11+T12-T13 @thanks
IF T11+T12+T13-T14 @reward
IF T11+T12+T13+T14 @done
1: HELP me there coming to eat me!
H: Who?
1: THEM!
GIVE T11
SEL 1
MOVE 1, -10, -10, 1
Fight 6, 6, 6, -1
If ALIVE @Goblinsave
1: Ahhh theyve got me.
1: Your useless %1 you %3 come back when u can actually SAVE me.
END
@Tryagain
1:AHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH!
1: SAVE ME THEN!
SEL 1
MOVE 1, -10, -10, 1
Fight 6, 6, 6, -1
If ALIVE @Goblinsave
1: Ahhh they've got me.
1: Your useless %1 you %3 come back when u can actually SAVE me.
END
@GoblinSave
MOVE 1, 25, 90, 1
GIVE T12
@thanks
1:Well thanks a lot.
GIVE T13
H:your welcome.
1: Well c ya
END

@reward
1:Ive done some thinking and well Ive decided to tell you somthin for saving me.
1:Ive decided to tell you how to reach the MYSTERIOUS goblin village.
H:How?
1:you simply say 'goblingoblingoblin'!
1:/a dissapeared!
SET SS11, 1
GIVE T14
@done
MOVE 1, -10 -10, 1
ASK 20
If Qgoblingoblingoblin @Go
END
@go
GIVE T15
GOTO LINK 3, 0
END

;Serenia equipment shop
SCENE 12 bwEuroStreet
#Include prtychk.txt
#include steal.txt
MUSIC	waltz2.mid
	ACTOR	1,	"George", joshTownsFolk, 17, 25, 90
	POSE 17
	SEL		1
	MOVE	1,	15, 80
COMPARE #<num.hostClass> "35"
IF> @monster
IF= @monster
	1: Get your basic equipment here, ideal for starting any new adventure!
	1: Right click me for armour or weapons
END
@eventactorclick1
COMPARE #<num.hostClass> "35"
IF> @monster
IF= @monster
MENU "Armour=@armour", "Weapons=@weapons"
END
@armour
	OFFER2 0,10,10, 0,10,11, 0,10,21, 0,10,22, 0,10,23
END
@weapons
	OFFER2 0,10,12, 0,10,13, 0,10,14, 0,10,15, 0,10,16, 0,10,17, 0,10,18, 0,10,19,
END

@monster
1: Back fiend, i have no goods for your kind.
H: Grrr
END

;GoblinVille equipment
SCENE 13 bwEuroStreet
#Include prtychk.txt
#include steal.txt
MUSIC	waltz2.mid
	ACTOR 1, "Terrence the Goblin", josh26, 1, 25, 90
	POSE 1,2
	SEL 1
	1: Ive got so much cash and nothin to spend it on!
	1: Wanna buy sumthin?
	ASK 1000
	IF Qyes @buy
	1: Fine later
	MOVE 1, -10, 90, 0
	WAIT 5
	N: You feel lighter
	TAKE G1000
	H: Hey come back here you thieving goblin
	1: Heh NO chance
	N: You lost 1000 GP
	END
@buy
1: Take your pick
	1: Right click me for armour or weapons
END
@eventactorclick1
COMPARE #<num.hostClass> "35"
IF> @monster
IF= @monster
MENU "Armour=@armour", "Weapons=@weapons"
END
@armour
	OFFER2 0,20,10, 0,20,11, 0,20,21, 0,20,22, 0,20,23
END
@weapons
	OFFER2 0,20,12, 0,20,13, 0,20,14, 0,20,15, 0,20,16, 0,20,17, 0,20,18, 0,20,19,
	END

;GoblinVille libary
SCENE 14 bgLibrary
#Include prtychk.txt
#include steal.txt
	ACTOR 1, "Jhonny the Goblin", josh26, 1, 25, 90
	POSE 1,2
	SEL 1
	1:Top'O'the mornin' to ya!
	1:This be the libary'O'goblin villege!
	1:Take ya time to read the books may I recomend; 
	1: 1.'Goblin population by D.Creacing'
	1: 2.'Rich poverty by I.M.Loaded'
	1: Right click me and choose a book!
END
@eventActorClick1
	MENU "Goblin population by D.Creacing=@book1", "Rich poverty by I.M.Loaded=@book2"
END
@book1
	N:You read the book 'Goblin population by D.Creacing'
	H:Goblin population 10000 years ago to today;
	H: 10000 years ago:  682951
	H: 5000 years ago: 1682034
	H: 4000 years ago: 2103847
	H: 3000 years ago: 3982546
	H: 2000 years ago: 5628729
	H: 1000 years ago: 6482956 
      H: (Human arival)
	H:  500 years ago: 1312455
	H:  250 years ago:  502461
	H:  100 years ago:  110230
	H:   10 years ago:   14314
	H:    Present day:    3763
	H: The popualtion rapidly declined as humans arrived and began to kill off the peacful goblins.
	H: The goblins were forced from thir homes, and their villages dominated by humans.
	H: Now only one village remains hidden in goblin forest, only accesable by a teleportation spell.
	1: I hope ya enjoyed the book'o'population. 
	GIVE T17
END
@book2
	N: You read the book 'Rich poverty by I.M.Loaded'
	H: Goblins are thieves, there is no doubt about it, they will steal from ABSOLUTLY anyone.
	H: However as goblins grow richer the don't get any happier.
	H: In fact they remain in the poverty induced upon them by humans.
	H: The cannot spend their monney, as no human will trust them.
	H: So they grow richer and remain in poverty.
	H: Ironic innit?
	GIVE T18
END

;GoblinKing
SCENE 15 bwthrone
#Include prtychk.txt
#include steal.txt
	ACTOR 1, "Goblin King", GobKing, 1, 25, 90
	POSE 1,2,3
	SEL 1
IF T13+T14+T15-T16 @Thanks
IF T13+T14+T15+T16 @hello again
IF -T14 @cheat
	1: Hmmm there is something wrong e-mail markiller007@hotmail.com if u see this.
END
@thanks
	1: Hello there %1, I must thank you for helping my friend in the forest.
	1: He would have died if not for yourself, here take this and begone!
	GIVE T16
	GIVE G10000
	N: You recieved 10000GP!
END
@hello again
	1:Hello again, I did reward you for saving that goblin right?
	ASK 30
	IF Qno @liar
	1:Yes of course I did well goodbye.
END
@liar
	1: You liar I DID.
	TAKE G10000
	1:But I take it back, begone.
END
@cheat
	TAKE G1000000
	GIVE T1000
	1: There is NO WAY you should be here without having saved my goblin friend, thus you will find I have marked this charactor as a cheat
	1: there are MANY disadvantages so have fun, and NEVER mod my world again OK!
END

;GoblinVille accesories
SCENE 16 bwEuroStreet
#Include prtychk.txt
#include steal.txt
MUSIC	waltz2.mid
	ACTOR 1, "Horrace the Goblin", josh26, 1, 25, 90
	POSE 1,2
	SEL 1
COMPARE #<num.hostclass>, 35
IF> @monsteracess
IF= @monsteracess
	1: Ive got so much cash and nothin to spend it on!
	1: Wanna buy sumthin?
	OFFER 701, 702, 706
	1: Horses, rope and picks- thats all we have!
	END
@monsteracess
1: Sorry, I dont have anything to sell monsters.
END

;Cave scenes
;Machette scene
SCENE 17 bgWaterCave2
#Include prtychk.txt
#include steal.txt
MUSIC "Dragons cave.mid"
IF I704 @done
COMPARE #<num.hostClass>, 35
IF> @done
IF= @done
H: Nothing here
H: Oh wait, a rusty old machette.
H: How usefull.....
H: /a Sighs
GIVE I704 
@done
END

;Treasure scene 1(500)
SCENE 18 cave7
#Include prtychk.txt
#include steal.txt
ACTOR 1 "Chest", chest, 1, 25, 90
IF T500 @done
H: There is a chest here.
END
@Eventactorclick1
MENU "Examine=@examine", "Pick up=@pick", "Open=@open"
END
@Examine
H: Definatly a chest.
END
@Pick
H: I can't carry it!
END
@Open
IF T500 @done
N: You find %I256
GIVE I256
GIVE T500
@done
POSE 2
END

;Treasure scene 2(501)
SCENE 19 cave7
#Include prtychk.txt
#include steal.txt
ACTOR 1 "Chest", chest, 1, 25, 90
IF T501 @done
H: Hmmm a chest
END
@Eventactorclick1
MENU "Examine=@examine", "Pick up=@pick", "Open=@open"
END
@Examine
H: Looks like a chest
END
@Pick
H: Too heavy, maybe I should open it?
END
@Open
IF T501 @done
N: You find 10000GP
GIVE T501
GIVE G10000
@done
POSE 2
END

;Treasure scene 3(502)
SCENE 20 cave7
#Include prtychk.txt
#include steal.txt
#include class1.txt
ACTOR 1 "Chest", chest, 1, 25, 90
IF T502 @done
H: Another dead end... but wait there is a chest.
END
@Eventactorclick1
MENU "Examine=@examine", "Pick up=@pick", "Open=@open"
END
@Examine
H: Its red with a gold trim, very fancy.
END
@Pick
H: Wouldn't it be better to open it?
END
@Open
IF T502 @done
POSE 2
H: A Monster!
FIGHT 16
IF ALIVE @alive
H: Ouch
END
@alive
GIVE T502
H: It left this %I914 behind.... 
GIVE I914
@done
POSE 2
END

;Main quest
;The Old man scene
Scene 21 bgeurostreet
#Include prtychk.txt
#include steal.txt
Actor 1 "Old Man", joshTownsfolk, 21, 25, 90
POSE 21, 22, 22
COMPARE #<num.hostClass> "35"
IF> @monster
IF= @monster
#include class1.txt
IF T25 @dragon
IF T21+T22+T24-T25-T27 @victory
IF T21-T22 @start
IF T24+T27-T28 @Free
IF T24+T27+T28-T31 @Blue
IF T36+T37+T38-T39 @BGem
IF T36+T37+T38+T39-T41 @Orange
IF T46+T47-T48 @Ogem
IF T48-T61 @White
IF T48-T51 @history
IF T67-T68 @Wwon
If alive @alive
IF -T71 @alive
Actor 1 "Old Man", joshTownsfolk, 36, 25, 90
IF T77-T78 @GSHELP!
IF T71-T72 @OMdeaddead
IF T72-T79 @OMAvengedead
IF T79-T91 @GSwondead
IF T91 @GSEnddead
@alive
IF T68-T71 @Gsummon
IF T71-T72 @OMdead
IF T72-T79 @OMAvenge
IF T79-T91 @GSwon
IF T91 @GSEnd
1:Hurry get the gem!
END

@monster
1: You are not wanted here evil one, and I have nothing for you
WAIT 5
1: What, still here?
1: /a runs
MOVE 1, -20, 90
END

@GSEnddead
1: Well Im just relaxing now
1: You should be out earning all the summons!
H: Hey good idea
GIVE T1501
GIVE T1500
END

@GSEnd
Actor 1 "Old Man", joshTownsfolk, 21, -25, -90
END

@Gsummon
Actor 1 "Old Man", joshTownsfolk, 21, 25, 90
POSE 21, 22
1: I know where the grand summoner is!
H: Where, I must kill him!
WAIT 1
Actor 2 "???", Levathian3, 1, 20, 90
SEL 2
POSE 1, 4
2: Here!
2: DIE OLD MAN!
POSE 2
WAIT 1
POSE 1, 4
SEL 1
POSE 35
1: AHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH!!!!!!!!!!!!
WAIT 1
2: MWWAHAHAHAHAHAHAHAHAHA!
Actor 2 "???", Levathian3, 1, -20, -90
Actor 1 "Old Man", joshTownsfolk, 21, -25, -90
H: NOOOOOOO!
H: The gems, hmm just one black one
GIVE I43
GIVE T71
@OMdead
Actor 1 "Old Man", joshTownsfolk, 21, -25, -90
H: The old man, he is dead.....
H: How Am I going to find out where the Grand summoner is now?
END

@OMAvenge
Actor 1 "Old Man", joshTownsfolk, 21, -25, -90
H: I MUST hurry to the Grand summoner, and avenge the fdeath of the old man!
END

@GSwon
Actor 1 "Old Man", joshTownsfolk, 21, -25, -90
H: the Grand Summoner is dead, now I must tell the old man!
END

@OMdeaddead
Actor 1 "Old Man", joshTownsfolk, 36, 25, 90
1: %1!
H: Your still here, quickly I need to know where the grand summoner is so I can avengy your death!
1: That %3 is gonna pay big time.....
1: He is in the castle to the north, on the island!
1: You will need a ship to reach him
H: He will die
GIVE T72
END

@OMAvengedead
Actor 1 "Old Man", joshTownsfolk, 36, 25, 90
1: Is he dead?
H: No, but I will avenge you!
END

@GSHELP!
Actor 1 "Old Man", joshTownsfolk, 36, 25, 90
H: I killed the grand summoner, but he still lives!
1: Well kill him again!
1: Wait a minute....The gems let me see them
H: /a shows the old man the gems
1: They have merged, maybe this has some power against him, this black gem!
H: I see, I will try it!
END
 
@GSwondead
Actor 1 "Old Man", joshTownsfolk, 36, 25, 90
1: Is he.....
H: Yes, the grand summoner is dead, and the bariers have fallen!
1: Oh good, now I can settle in the afterlife
GIVE T91
GIVE T1501
GIVE T1500
END


@Start
1: Adventurers wanted!
H: Im an adventurer, and I've been lookin for something more interesting to do!
1: Wanna get rich quick?
H: Sure, how?
1: Well There is a cave DEEP in the goblin forest, All I want is a small red gem found inside that cave.
H: Oh yeah, what do I get?
1: There are all kinds of stuff down there, including the dragons pile of gold!
H: Dragon!?!
1: Oh yeah, I forgot to mention, a dragon is gaurding the gem, well good luck, and a safe return...
GIVE T22
END
@Victory
1: Well done you have defeated the Dragon!
H: yep.
1: Well my Gem please.
H: I dont have it...
1: Oh my YOU ARE CURSED!
H: WHAT?
1: You must free yourself of the curse, or the SPIRIT of the dragon will never leave you alone!
1: Someone must know how to get rid of the curse, if you speak with the right person they will help you!
1: Oh my!!
GIVE T25
@Dragon
FIGHT 202
1: Its coming back!
GOTO @dragon
END
@Free
1: I see you are at last free of the curse, well done!
H: Thanks.... concidering it was your falt I got into that mess....
1: Yes well... My gem?
N: Give him the red gem?
ASK 30
IF Qyes @thanks
1: WHY NOT DAMNIT!!!!
1: Fine get out of here, come back when YOU wanna give it me and get my help!
END
@thanks
N: You give him the gem
TAKE I39
1: Thanks.
GIVE T28
@Blue
1: Next, the blue gemstone
H: Blue gem?
1: Yes, its somewhere in the north-east.
H: Really?
1: yes if you get a ship from the harbour, Im sure you will find it.
1: Go there, bring me the gem, and as always, find anything else and you can keep it!
1: Oh and and watch out for the blue dragon guarding the gem.
H: BLUE DRAGON!?!
H: Well, Ok.
GIVE T31
END
@BGem
H: I have slain the dragon, and have the BLUE gem!
1: Hurry give it to me!
H: Should I give it him?
ASK 30
If Qyes @giveBgem
1: BAH come back when you are willing to give me the gem, and want to know where to get the next one! 
END
@giveBgem
H: here, take it.
1: Thanks
TAKE I40
Give T39
@Orange
1: Ive GOT it!
H: What?
1: The ORANGE dragon!
1: Its in a tower in the mountains!
H: Ok
GIVE T41
END
@Ogem
H: I have slain the orange dragon!
1: And my gem?
H: Give him the gem?
ASK 30
IF Qyes @Oyes
IF Qno @Ono
END
@Ono
1: Mumble grumble
END
@Oyes
H: Ok here you go
1: Good!
TAKE I41
GIVE T48
@White
1: Well I have found the location of the white gem.
H: Where?
1: Deep in the desert to the north
H: Ok, Ill get right on it
1: Thankyou
GIVE T61
@History
H: Why are you sending me to get all the gems?
1: I cannot say, but I know someone who can.
1: Visit the historian in interia.
GIVE T51
GIVE T52
END
@Wwon
H: I have beaten the white dragon, and collected the gem.
1: Good, quickly hand me the last gem!
H: Here!
GIVE T68
TAKE I42
@Gsummon
1: Now you must wait, I am searching for the location gf the GRAND SUMMONER!
1: Please return soon.
END

;The Red Dragon scene!
Scene 22 cave6
#Include prtychk.txt
#include steal.txt
MUSIC "Dragon's Cave.mid"
COMPAGE #<num.hostclass>, 35
IF> @monster
IF= @monster
#include class1.txt
IF T22-T24 @fight
IF T25 @cursed
END

@fight
ACTOR 1 "Red gem", Redgem, 1, 25, 90
POSE 1, 2, 3
H: The red gem!
WAIT 10
ACTOR 1 "Red Dragon", josh42, 1, 25, 90
POSE 1, 2, 3
1: GRRRRRRRRROOOOOOOOOOAAAAAAAAAARRRRRRRRRRRRR!!!!!!
H: The Dragon!
WAIT 2
MOVE 1, -20, 90, 1
FIGHT 202
IF ALIVE @won
WAIT 5
MOVE 1, 25, 90, 1
1: GROOOAR!
END

@won
H: I won, WHEW.
H: There is a %I188 here, Ill take it
H: But no red gem? Strange.
H: Ill go see the old man.
GIVE T1202
GIVE T24
GIVE I188
END;

@cursed
ASK 30
If QCursemenot @cured
FIGHT 202
GOTO @cursed
END
@cured
FX 9
Weather 9
H: The spirit is being freed!
Wait 5
ACTOR 1 "Red gem", Redgem, 1, 25, 90
POSE 1, 2, 3
H: The red gem!
WAIT 2
N: You take the red gem
MOVE 1, -50, 90, 1
FX 0
Weather 0
H: The curse is gone!
GIVE T1202
TAKE T25
GIVE T27
GIVE I39
END

@monster
IF T104+T105-T106-T107 @RedDragonBattle
IF T104+T105+T106-T108 @RedDragonDefeated
IF T104+T105+T106+T108-T109-T110 @REDSummonerBattle
IF T104+T105+T106+T108+T109-T111 @GemToSatin
IF T104+T105+T107-T112 @TellSatinLostDrag
IF T104+T105+T106+T108+T110-T112 @TellSatinLostSum
H: Nothing here...
END

@RedDragonBattle
ACTOR 1 "Red gem", Redgem, 1, 25, 90
POSE 1, 2, 3
H: There is the gem, ITS MINE NOW!
WAIT 1
ACTOR 2 "Red Dragon", josh42, 1, -30, 90
POSE 1, 2, 3
MOVE 2, 30, 90
2: GRRRRRRRRROOOOOOOOOOAAAAAAAAAARRRRRRRRRRRRR!!!!!!
H: Im here to kill you dragon!
2: You wont defeat me you deamon!
WAIT 1
MOVE 2, -30, 90, 1
#include running.txt
FIGHT 202
#include eat.txt
IF ALIVE @WONRedDragonBattle
HOST_GIVE T107
MOVE 2, 25, 90, 1
2: GROOOAR!
H: I have been defeated!
ACTOR 3 "Summoner", Summoner, 1, 130, 90
SEL 3
POSE 1, 4
MOVE 3, 70, 90
3: You are mine dragon!
2: Summoner, you dont stand a chance!
3: Just watch me!
MOVE 3, 30, 90
WAIT 5
SEL 2
POSE 2
2: GROAR!
POSE 1, 2, 3
SEL 3
POSE 3
3: AHHH!
WAIT 1
SEL 3
POSE 2
3: DIE!
WAIT 1
2: NOOOO!!!
MOVE 2, -30, 90, 1
SEL 3
POSE 1, 4
3: The red dragon is dead, and the gem is mine!
MOVE 1, -30, 90, 1
MOVE 3, -30, 90
H: Damnit, the summoner has the red gem!
END

@WONRedDragonBattle
HOST_GIVE T106
HOST_GIVE I39
H: I have defeated the red dragon!
H: Now to take the gem back to satin!
MOVE 1, -30, 90, 1
END

@RedDragonDefeated
H: I have already defeated the red dragon
H: Now I must return to satin to utilise the red gems power!
END

@REDSummonerBattle
COMPARE #<num.hostclass>, "53"
IF> @RedDragonDefeated
IF< @RedDragonDefeated
ACTOR 3 "Summoner", Summoner, 1, -30, 90
H: Now To wait for the summoner, and defeat him!
MOVE 3, 30, 90
3: Beast, the time is now
3: I am here for the gem fiend!
H: GROOOAR!!
MOVE 3, -30, 90, 1
FIGHT 186, 201
IF ALIVE @WONREDSummonerBattle
HOST_GIVE T110
HOST_TAKE I39
MOVE 3, 30, 90
3: DIE DEAOMON!
H: AHHHHHHHH!
3: I believe that is mine evil one
3: /a Takes the Red Gem
MOVE 3, -30, 90
H: I am defeated!
H: I must return to satin immediatly to inform him of my loss
END

@WONREDSummonerBattle
HOST_GIVE T109
MOVE 3, 30, 90, 1
SEL 3
POSE 3
3: No, I refuse to die here!
H: Too late summoner, your hide is mine!
POSE 1, 4
3: Never
3: /a uses ticket home
MOVE 3, -30, 90, 1
H: That %3 fled! Satin will be most displeased, But I have the Gem!
END

@GemToSatin
9: There is nothing more to do here
9: I have the red gem, but the summoner escaped
9: Now I must return the gem to satin
END

@TellSatinLostDrag
H: There is nothing left here now
H: I must inform satin of my failure immediatly
END

@TellSatinLostSum
H: I was defeated here by the summoner
H: I must inform satin of my loss immediatly!
END

SCENE 300
#Include prtychk.txt
COMPARE #<num.peopleInScene>, 2
IF< @END
IF> @END
SET hostGPsteal, #<num.hostGP>
TAKE G#<stealGP>
HOST_TAKE G1000000
HOST_GIVE G#<stealGP>
HOST_GIVE G#<hostGPsteal>
@END
END

SCENE 400
#Include prtychk.txt
COMPARE #<num.peopleInScene>, 2
IF< @END
IF> @END
TAKE H#<MurderHP>
HOST_GIVE H#<MurderHP>
SET hostGPsteal, #<num.hostGP>
TAKE G#<stealGP>
HOST_TAKE G1000000
HOST_GIVE G#<hostGPsteal>
HOST_GIVE G#<stealGP>
N: Monster %1 attempted player murder!
@END
END

#include fabarian.txt
;23 to 26, 66
#include Interia.txt
;27 to 30
#include Glandor.txt
;31 to 36
#include Kroxville.txt
;37 to 42, 45, 54, 72
#include Quest2.txt
;43, 44
#include Quest3.txt
;46, 47
#include historian.txt
;48, 49
#include forget.txt
;200
#include quest4.txt
;50, 55 to 57
#include Tunnels.txt
;51
#include quest5.txt
;52
#include monstorian.txt
;53
#include Training.txt
;58 to 65
#include Ultimate.txt
;67 to 70
#include Herbs.txt
;71
#include Class.txt
;73
#include hell.txt
;74 to 82
#include monstermorph.txt
#include Quest21.txt
;83
#include void.txt
;101
; Here is the last line of the SCENES section of the quest file.
-SCENES



; Now we are at the extreme end of the file
; I have used 83 scenes so far and Scene 200 and SCENE 300 and SCENE 400
; Note: You should add a comment to the end of the file, since otherwise an old bug might rise
; up and smite you!
